Wie druckt man ein Arbeitsblatt mit Validierungskreisen in Excel?

In bestimmten Fällen markieren wir möglicherweise einige ungültige Daten, um sie hervorzuheben. Wenn Sie jedoch das Arbeitsblatt mit den Validierungskreisen drucken möchten, werden die Kreise nicht gedruckt. Haben Sie jemals dieses Problem in Excel erlebt? Heute zeige ich Ihnen einige schnelle Tricks, um dieses Problem zu lösen.

Arbeitsblatt mit Validierungskreisen drucken, indem Sie sie als Bild einfügen

Arbeitsblatt mit Validierungskreisen drucken, indem Sie VBA-Code verwenden

Arbeitsblatt mit Validierungskreisen drucken, indem Sie sie als Bild einfügen

In Excel können wir die Validierungskreise nicht direkt drucken, aber wir können den Datenbereich mit den Validierungskreisen kopieren und als Bild einfügen und dann drucken.

1. Wählen Sie den Datenbereich aus, für den Sie die Kreise drucken möchten.

2. Drücken Sie die Tasten Strg + C auf der Tastatur, um ihn zu kopieren, und gehen Sie dann zu einem neuen Arbeitsblatt, klicken Sie auf eine Zelle, und klicken Sie mit der rechten Maustaste, wählen Sie Inhalte einfügen > Bild, siehe Screenshot:

3. Und dann wurde Ihre Auswahl als Bild eingefügt, und jetzt, wenn Sie das neue Arbeitsblatt drucken, werden die Kreise erfolgreich gedruckt.

Arbeitsblatt mit Validierungskreisen drucken, indem Sie VBA-Code verwenden

Wenn Sie den Datenbereich nicht als Bild einfügen möchten, kann Ihnen der folgende VBA-Code ebenfalls helfen.

1. Halten Sie nach dem Festlegen der Datenvalidierung die Tasten Alt + F11 in Excel gedrückt, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie dann auf Einfügen > Modul, und fügen Sie das folgende Makro im Modulfenster ein.

VBA-Code: Rote Kreise zu ungültigen Daten hinzufügen

Sub AddValidationCirclesForPrinting()
'Update 20140724
Dim Rng As Range
Dim WorkRng As Range
Dim xCount As Integer
Dim xShape As Shape
On Error Resume Next
Set WorkRng = Application.ActiveSheet.Cells.SpecialCells(xlCellTypeAllValidation)
If WorkRng Is Nothing Then
    Exit Sub
End If
xCount = 0
For Each Rng In WorkRng
   If Not Rng.Validation.Value Then
       Set xShape = Application.ActiveSheet.Shapes.AddShape(msoShapeOval, Rng.Left - 2, Rng.Top - 2, Rng.Width + 4, Rng.Height + 4)
       xShape.Fill.Visible = msoFalse
       xShape.Line.ForeColor.SchemeColor = 10
       xShape.Line.Weight = 1.25
       xCount = xCount + 1
       xShape.Name = "InvalidData_" & xCount
   End If
Next
Exit Sub
End Sub

3. Drücken Sie dann die Taste F5, um diesen Code auszuführen, und die ungültigen Daten wurden mit dem roten Oval umkreist, siehe Screenshot:

4. Wenn Sie dieses Arbeitsblatt mit den roten Kreisen drucken, werden die Kreise ebenfalls gedruckt.

Hinweis:

Mit diesem VBA-Code werden die Kreise nicht durch die Excel-Funktion „Validierungskreise löschen“ entfernt. Wenn Sie die Kreise löschen möchten, wenden Sie bitte den folgenden Code an.

VBA-Code: Validierungskreise im Arbeitsblatt entfernen

Sub RemoveValidationCircles()
'Update 20140724
Dim xShape As Shape
For Each xShape In Application.ActiveSheet.Shapes
    If xShape.Name Like "InvalidData_*" Then
        xShape.Delete
    End If
Next
End Sub

Verwandter Artikel:

Wie kreist man ungültige Daten in Excel ein?