Mehrere Elemente in Excel-Dropdown-Liste auswählen – vollständiger Leitfaden

Excel-Dropdown-Listen sind ein hervorragendes Werkzeug, um Datenkonsistenz zu gewährleisten und die Dateneingabe zu vereinfachen. Standardmäßig erlauben sie jedoch nur die Auswahl eines einzelnen Elements. Was aber, wenn Sie mehrere Elemente aus derselben Dropdown-Liste auswählen möchten? In diesem umfassenden Leitfaden stellen wir Methoden vor, mit denen Sie Mehrfachauswahlen in Excel-Dropdown-Listen ermöglichen, Duplikate verwalten, benutzerdefinierte Trennzeichen festlegen und den Geltungsbereich dieser Listen präzise definieren können.

• Verwendung von VBA-Code
• Verwendung von Kutools für Excel mit wenigen Klicks

• Doppelte Elemente zulassen
• Vorhandene Elemente entfernen
• Benutzerdefiniertes Trennzeichen festlegen
• Eine Begrenzter Bereich festlegen
• Ausführung in einem geschützten Arbeitsblatt

Mehrfachauswahl in Dropdown-Liste aktivieren

Dieser Abschnitt stellt zwei Methoden vor, mit denen Sie Mehrfachauswahlen in Dropdown-Listen in Excel aktivieren können.

Verwenden von VBA-Code

Um Mehrfachauswahlen in einer Dropdown-Liste zu ermöglichen, nutzen Sie „Visual Basic for Applications“ (VBA) in Excel. Mit einem passenden Skript lässt sich das Verhalten der Dropdown-Liste so anpassen, dass mehrere Optionen gleichzeitig ausgewählt werden können. Gehen Sie dazu wie folgt vor.

Schritt 1: Öffnen des Tabellenblatt-(Code)-Editors

1. Öffnen Sie das Arbeitsblatt, das die Dropdown-Liste enthält, für die Sie die Mehrfachauswahl aktivieren möchten.
2. Klicken Sie mit der rechten Maustaste auf die Blattregisterkarte und wählen Sie im Kontextmenü „Code anzeigen“.
   

Schritt 2: Verwenden von VBA-Code

Kopieren Sie nun den folgenden VBA-Code und fügen Sie ihn in das geöffnete Tabellenblatt-(Code)-Fenster ein.

VBA-Code: Aktivieren mehrfacher Auswahlmöglichkeiten in Excel-Dropdown-Listen.

Private Sub Worksheet_Change(ByVal Target As Range)
'Updated by Extendoffice 20240118
    Dim xRng As Range
    Dim xValue1 As String
    Dim xValue2 As String
    Dim delimiter As String
    Dim TargetRange As Range

    Set TargetRange = Me.UsedRange ' Users can change target range here
    delimiter = ", " ' Users can change the delimiter here

    If Target.Count > 1 Or Intersect(Target, TargetRange) Is Nothing Then Exit Sub
    On Error Resume Next
    Set xRng = TargetRange.SpecialCells(xlCellTypeAllValidation)
    If xRng Is Nothing Then Exit Sub
    Application.EnableEvents = False

    xValue2 = Target.Value
    Application.Undo
    xValue1 = Target.Value
    Target.Value = xValue2
    If xValue1 <> "" And xValue2 <> "" Then
        If Not (xValue1 = xValue2 Or _
                InStr(1, xValue1, delimiter & xValue2) > 0 Or _
                InStr(1, xValue1, xValue2 & delimiter) > 0) Then
            Target.Value = xValue1 & delimiter & xValue2
        Else
            Target.Value = xValue1
        End If
    End If

    Application.EnableEvents = True
    On Error GoTo 0
End Sub

Ergebnis

Wenn Sie zum Arbeitsblatt zurückkehren, ermöglicht Ihnen die Dropdown-Liste, mehrere Optionen auszuwählen – siehe folgende Demo:

Mit Kutools für Excel in wenigen Klicks

Wenn Sie sich mit VBA nicht wohl fühlen, bietet sich als einfachere Alternative die Funktion „Dropdown-Liste mit mehreren Auswahlmöglichkeiten erstellen“ von Kutools für Excel an. Dieses benutzerfreundliche Tool vereinfacht die Aktivierung von Mehrfachauswahlen in Dropdown-Listen, ermöglicht die Anpassung des Trennzeichens und sorgt für eine problemlose Verwaltung von Duplikaten – ganz nach Ihren individuellen Anforderungen.

Nach der Installation von Kutools für Excel wechseln Sie zur Registerkarte „Kutools“, wählen Sie „Dropdown-Liste“ > „Dropdown-Liste mit mehreren Auswahlmöglichkeiten erstellen“ und konfigurieren Sie diese anschließend wie folgt.

1. Geben Sie den Bereich an, der die Dropdown-Liste enthält, aus der Sie mehrere Elemente auswählen möchten.
2. Geben Sie das Trennzeichen für die Anzahl der ausgewählten Elemente in der Dropdown-Listen-Zelle an.
3. Klicken Sie auf „OK“, um die Einrichtung abzuschließen.
   

Ergebnis

Sobald Sie auf eine Zelle mit einer Dropdown-Liste im begrenzten Bereich klicken, erscheint daneben ein Listenfeld. Fügen Sie Elemente ganz einfach per Klick auf die „+“-Schaltfläche hinzu oder entfernen Sie unerwünschte Einträge mit der „–“-Schaltfläche. Siehe folgende Demo:

Weitere Vorgänge für Mehrfachauswahl-Dropdown-Liste

Dieser Abschnitt fasst verschiedene Szenarien zusammen, die erforderlich sein können, um Mehrfachauswahlen in der Dropdown-Liste der Datenüberprüfung zu aktivieren.

Doppelte Elemente in Dropdown-Liste zulassen

Duplikate können problematisch sein, wenn Mehrfachauswahlen in einer Dropdown-Liste zulässig sind. Der oben genannte VBA-Code verhindert doppelte Einträge in der Dropdown-Liste. Falls Sie Duplikate beibehalten möchten, verwenden Sie den VBA-Code in diesem Abschnitt.

VBA-Code: Duplikate in Datenüberprüfungs-Dropdown-Liste zulassen

Private Sub Worksheet_Change(ByVal Target As Range)
'Updated by Extendoffice 20240118
    Dim xRng As Range
    Dim xValue1 As String
    Dim xValue2 As String
    Dim delimiter As String
    Dim TargetRange As Range

    Set TargetRange = Me.UsedRange ' Users can change target range here
    delimiter = ", " ' Users can change the delimiter here

    If Target.Count > 1 Or Intersect(Target, TargetRange) Is Nothing Then Exit Sub
    On Error Resume Next
    Set xRng = TargetRange.SpecialCells(xlCellTypeAllValidation)
    If xRng Is Nothing Then Exit Sub
    Application.EnableEvents = False

    xValue2 = Target.Value
    Application.Undo
    xValue1 = Target.Value
    Target.Value = xValue2
    If xValue1 <> "" And xValue2 <> "" Then
        Target.Value = xValue1 & delimiter & xValue2
    End If

    Application.EnableEvents = True
    On Error GoTo 0
End Sub

Ergebnis

Sie können nun mehrere Elemente aus der Dropdown-Liste im aktuellen Arbeitsblatt auswählen. Um ein Element in einer Dropdown-Liste-Zelle erneut auszuwählen, klicken Sie einfach nochmals darauf in der Liste. Siehe Screenshot:

Vorhandene Elemente aus Dropdown-Liste entfernen

Nachdem Sie mehrere Elemente aus einer Dropdown-Liste ausgewählt haben, kann es vorkommen, dass Sie ein bereits ausgewähltes Element wieder aus der Zelle entfernen möchten. In diesem Abschnitt finden Sie einen weiteren VBA-Code, der Ihnen genau dabei hilft.

VBA-Code: Vorhandene Elemente aus der Dropdown-Liste-Zelle entfernen

Private Sub Worksheet_Change(ByVal Target As Range)
    'Updated by Extendoffice 20240118
    Dim xRngDV As Range
    Dim TargetRange As Range
    Dim oldValue As String
    Dim newValue As String
    Dim delimiter As String
    Dim allValues As Variant
    Dim valueExists As Boolean
    Dim i As Long
    Dim cleanedValue As String

    Set TargetRange = Me.UsedRange ' Set your specific range here
    delimiter = ", " ' Set your desired delimiter here

    If Target.CountLarge > 1 Then Exit Sub

    ' Check if the change is within the specific range
    If Intersect(Target, TargetRange) Is Nothing Then Exit Sub

    On Error Resume Next
    Set xRngDV = Target.SpecialCells(xlCellTypeAllValidation)
    If xRngDV Is Nothing Or Target.Value = "" Then
        ' Skip if there's no data validation or if the cell is cleared
        Application.EnableEvents = True
        Exit Sub
    End If
    On Error GoTo 0

    If Not Intersect(Target, xRngDV) Is Nothing Then
        Application.EnableEvents = False
        newValue = Target.Value
        Application.Undo
        oldValue = Target.Value
        Target.Value = newValue

        ' Split the old value by delimiter and check if new value already exists
        allValues = Split(oldValue, delimiter)
        valueExists = False
        For i = LBound(allValues) To UBound(allValues)
            If Trim(allValues(i)) = newValue Then
                valueExists = True
                Exit For
            End If
        Next i

        ' Add or remove value based on its existence
        If valueExists Then
            ' Remove the value
            cleanedValue = ""
            For i = LBound(allValues) To UBound(allValues)
                If Trim(allValues(i)) <> newValue Then
                    If cleanedValue <> "" Then cleanedValue = cleanedValue & delimiter
                    cleanedValue = cleanedValue & Trim(allValues(i))
                End If
            Next i
            Target.Value = cleanedValue
        Else
            ' Add the value
            If oldValue <> "" Then
                Target.Value = oldValue & delimiter & newValue
            Else
                Target.Value = newValue
            End If
        End If

        Application.EnableEvents = True
    End If
End Sub

Ergebnis

Mit diesem VBA-Code können Sie mehrere Elemente aus einer Dropdown-Liste auswählen – und jedes bereits gewählte Element ganz einfach wieder entfernen. Wählen Sie dazu nach der Mehrfachauswahl das betreffende Element erneut aus der Liste aus, um es zu löschen.

Benutzerdefiniertes Trennzeichen festlegen

Im obigen VBA-Code ist das Trennzeichen standardmäßig auf Komma eingestellt. Sie können diese Variable ganz einfach anpassen und durch jedes beliebige Zeichen ersetzen, das Sie als Trennzeichen für Ihre Dropdown-Listen-Auswahlen nutzen möchten. So geht’s:

Wie Sie sehen, enthalten alle oben genannten VBA-Codes die folgende Zeile:

delimiter = ", "

Sie ersetzen einfach das Komma durch Ihr gewünschtes Trennzeichen. Möchten Sie die Elemente beispielsweise durch ein Semikolon trennen, passen Sie die Zeile wie folgt an:

delimiter = "; "

delimiter = vbNewLine

Festlegen eines Begrenzter Bereich

Die oben genannten VBA-Codes gelten für alle Dropdown-Listen im aktuellen Arbeitsblatt. Wenn Sie möchten, dass die VBA-Codes nur auf einen bestimmten Bereich von Dropdown-Listen angewendet werden, können Sie diesen Bereich im obigen VBA-Code wie folgt festlegen.

Wie Sie sehen, enthalten alle oben genannten VBA-Codes die folgende Zeile:

Set TargetRange = Me.UsedRange

Sie müssen die Zeile lediglich wie folgt ändern:

Set TargetRange = Me.Range("C2:C10")

Ausführung in einem geschützten Arbeitsblatt

Stellen Sie sich vor, Sie haben ein Arbeitsblatt mit dem Passwort „123“ geschützt und die Dropdown-Liste-Zellen vor Aktivierung des Schutzes als „nicht gesperrt“ markiert, damit die Mehrfachauswahl auch nach dem Schutz weiterhin funktioniert. In diesem Fall versagen jedoch die oben genannten VBA-Codes. Daher wird in diesem Abschnitt ein spezielles VBA-Skript vorgestellt, das gezielt für die Mehrfachauswahl in einem geschützten Arbeitsblatt entwickelt wurde.

VBA-Code: Aktivieren der Mehrfachauswahl in Dropdown-Liste ohne Duplikate

Private Sub Worksheet_Change(ByVal Target As Range)
    'Updated by Extendoffice 20240118
    Dim xRng As Range
    Dim xValue1 As String
    Dim xValue2 As String
    Dim delimiter As String
    Dim TargetRange As Range
    Dim isProtected As Boolean
    Dim pswd As Variant

    Set TargetRange = Me.UsedRange ' Set your specific range here
    delimiter = ", " ' Users can change the delimiter here

    If Target.Count > 1 Or Intersect(Target, TargetRange) Is Nothing Then Exit Sub
    
    ' Check if sheet is protected
    isProtected = Me.ProtectContents
    If isProtected Then
        ' If protected, temporarily unprotect. Adjust or remove the password as needed.
        pswd = "yourPassword" ' Change or remove this as needed
        Me.Unprotect Password:=pswd
    End If

    On Error Resume Next
    Set xRng = TargetRange.SpecialCells(xlCellTypeAllValidation)
    If xRng Is Nothing Then
        If isProtected Then Me.Protect Password:=pswd
        Exit Sub
    End If
    Application.EnableEvents = False

    xValue2 = Target.Value
    Application.Undo
    xValue1 = Target.Value
    Target.Value = xValue2
    If xValue1 <> "" And xValue2 <> "" Then
        If Not (xValue1 = xValue2 Or _
                InStr(1, xValue1, delimiter & xValue2) > 0 Or _
                InStr(1, xValue1, xValue2 & delimiter) > 0) Then
            Target.Value = xValue1 & delimiter & xValue2
        Else
            Target.Value = xValue1
        End If
    End If

    Application.EnableEvents = True
    On Error GoTo 0

    ' Re-protect the sheet if it was protected
    If isProtected Then
        Me.Protect Password:=pswd
    End If
End Sub

Durch die Aktivierung der Mehrfachauswahl in Excel-Dropdown-Listen können Sie die Funktionalität und Flexibilität Ihrer Arbeitsblätter erheblich steigern. Egal, ob Sie mit VBA vertraut sind oder eine einfachere Lösung wie Kutools bevorzugen – Sie können Ihre standardmäßigen Dropdown-Listen jetzt in dynamische Werkzeuge mit Mehrfachauswahl verwandeln. Damit sind Sie bestens gerüstet, um lebendigere und benutzerfreundlichere Excel-Dokumente zu erstellen. Für alle, die tiefer in die Möglichkeiten von Excel eintauchen möchten, bietet unsere Website eine Fülle weiterer Tutorials.Entdecken Sie hier weitere Excel-Tipps und -Tricks.

Verwandte Artikel