Wie kann man Text in Excel finden und ersetzen und dabei die Formatierung beibehalten?

Die Funktion 'Suchen und Ersetzen' ist leistungsstark und hilfreich, wenn wir einen bestimmten Wert finden und durch einen anderen ersetzen müssen. Wenn es jedoch einen Zellbereich gibt und einige der Zellen unterschiedliche Formatierungswerte enthalten, wird die Verwendung von 'Suchen und Ersetzen', um Werte zu finden und zu ersetzen, die Formatierung der Werte in den Zellen wie im folgenden Screenshot gezeigt zerstören. Wie können wir die Formatierung der Werte in jeder Zelle beim Suchen und Ersetzen in Excel beibehalten?

Text suchen und ersetzen mit Makrocode unter Beibehaltung der Formatierung

Text suchen und ersetzen mit Makrocode unter Beibehaltung der Formatierung

Es gibt keine andere Methode außer dem Makrocode, der Ihnen helfen kann, Text zu finden und zu ersetzen und dabei die Formatierung beizubehalten.

1. Drücken Sie die Tasten Alt + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf Einfügen > Modul und fügen Sie den folgenden Code in das Skript ein.

VBA: Text suchen und ersetzen unter Beibehaltung der Formatierung

Sub CharactersReplace(Rng As Range, FindText As String, ReplaceText As String, Optional MatchCase As Boolean = False)
  'UpdatebyExtendoffice20160711
    Dim I As Long
    Dim xLenFind As Long
    Dim xLenRep As Long
    Dim K As Long
    Dim xValue As String
    Dim M As Long
    Dim xCell As Range
    xLenFind = Len(FindText)
    xLenRep = Len(ReplaceText)
    If Not MatchCase Then M = 1
    For Each xCell In Rng
        If VarType(xCell) = vbString Then
            xValue = xCell.Value
            K = 0
            For I = 1 To Len(xValue)
              If StrComp(Mid$(xValue, I, xLenFind), FindText, M) = 0 Then
                xCell.Characters(I + K, xLenFind).Insert ReplaceText
                K = K + xLenRep - xLenFind
              End If
            Next
        End If
    Next
End Sub

Sub Test_CharactersReplace()
    Dim xRg As Range
    Dim xTxt As String
    Dim xCell As Range
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Select a range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    Call CharactersReplace(xRg, "KK", "Kutools", True)
End Sub

Tipp: Im Code ist KK die Zeichenfolge, die Sie finden möchten, und Kutools ist die Zeichenfolge, durch die Sie ersetzen möchten. Sie können diese nach Bedarf ändern.

3. Drücken Sie F5 , woraufhin ein Dialogfeld erscheint, in dem Sie einen Bereich auswählen können, in dem Sie suchen und ersetzen möchten, siehe Screenshot:

4. Klicken Sie auf OK, und die spezifische Zeichenfolge in den ausgewählten Zellen wird durch eine andere ersetzt, wobei die Formatierung beibehalten wird.