Wie zählt man eindeutige Werte basierend auf mehreren Kriterien in Excel?

In diesem Artikel werde ich Ihnen anhand einiger Beispiele zeigen, wie Sie eindeutige Werte basierend auf einem oder mehreren Kriterien in einem Arbeitsblatt zählen können. Die folgenden detaillierten Schritte könnten Ihnen helfen.

Einzigartige Werte basierend auf einem Kriterium zählen

Einzigartige Werte basierend auf zwei gegebenen Daten zählen

Einzigartige Werte basierend auf zwei Kriterien zählen

Einzigartige Werte basierend auf drei Kriterien zählen

Einzigartige Werte basierend auf einem Kriterium zählen

Angenommen, ich habe den folgenden Datenbereich und möchte nun die einzigartigen Produkte zählen, die Tom verkauft hat.

Bitte geben Sie diese Formel in eine leere Zelle ein, wo Sie das Ergebnis erhalten möchten, zum Beispiel G2:

=SUMME(WENN("Tom"=$C$2:$C$20; 1/(ZÄHLENWENNS($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20)); 0)) und drücken Sie dann gleichzeitig die Tasten Umschalt + Strg + Eingabe, um das richtige Ergebnis zu erhalten, siehe Screenshot:

Hinweis: In der obigen Formel ist „Tom“ das Namenskriterium, nach dem Sie zählen möchten, C2:C20 sind die Zellen, die das Namenskriterium enthalten, A2:A20 sind die Zellen, aus denen Sie die eindeutigen Werte zählen möchten.

Einzigartige Werte basierend auf zwei gegebenen Daten zählen

Um die eindeutigen Werte zwischen zwei gegebenen Daten zu berechnen, zum Beispiel möchte ich die eindeutigen Produkte zwischen dem Datumsbereich 01.09.2016 und 30.09.2016 zählen, bitte wenden Sie diese Formel an:

=SUMME(WENN($D$2:$D$20<=DATUM(2016; 9; 30)*($D$2:$D$20>=DATUM(2016; 9; 1)); 1/ZÄHLENWENNS( $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATUM(2016; 9; 30);$D$2:$D$20; ">="&DATUM(2016; 9; 1))); 0) und drücken Sie dann gleichzeitig die Tasten Umschalt + Strg + Eingabe, um das eindeutige Ergebnis zu erhalten, siehe Screenshot:

Hinweis: In der obigen Formel sind die Daten 01.09.2016 und 30.09.2016 das Start- und Enddatum, auf das Sie zählen möchten, D2:D20 sind die Zellen, die das Datums-Kriterium enthalten, A2:A20 sind die Zellen, aus denen Sie die eindeutigen Werte zählen möchten.

Einzigartige Werte basierend auf zwei Kriterien zählen

Wenn Sie die eindeutigen Produkte zählen möchten, die Tom im September verkauft hat, kann Ihnen die folgende Formel helfen.

Bitte geben Sie diese Formel in eine leere Zelle zur Ausgabe des Ergebnisses ein, zum Beispiel H2.

=SUMME(WENN(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATUM(2016; 9; 30)*($D$2:$D$20>=DATUM(2016; 9; 1))); 1/ZÄHLENWENNS($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATUM(2016; 9; 30);$D$2:$D$20; ">="&DATUM(2016; 9; 1))); 0) und drücken Sie dann gleichzeitig die Tasten Umschalt + Strg + Eingabe, um das eindeutige Ergebnis zu erhalten, siehe Screenshot:

Hinweise:

1. In der obigen Formel ist „Tom“ das Namenskriterium, 01.09.2016 und 30.09.2016 sind die beiden Daten, auf die Sie zählen möchten, C2:C20 sind die Zellen, die das Namenskriterium enthalten, und D2:D20 sind die Zellen, die das Datum enthalten, A2:A20 ist der Zellbereich, aus dem Sie die eindeutigen Werte zählen möchten.

2. Wenn Sie ein „oder“-Kriterium verwenden müssen, um die eindeutigen Werte zu zählen, zum Beispiel die Produkte berechnen, die von Tom verkauft wurden oder in der Südregion, wenden Sie bitte diese Formel an:

=SUMME(--(HÄUFIGKEIT(WENN(("Tom"=$C$2:$C$20)+("Süd"=$B$2:$B$20); ZÄHLENWENN($A$2:$A$20; "<"&$A$2:$A$20); ""); ZÄHLENWENN($A$2:$A$20; "<"&$A$2:$A$20))>0)) und denken Sie daran, gleichzeitig die Tasten Umschalt + Strg + Eingabe zu drücken, um das eindeutige Ergebnis zu erhalten, siehe Screenshot:

Einzigartige Werte basierend auf drei Kriterien zählen

Um die eindeutigen Produkte mit drei Kriterien zu zählen, könnte die Formel komplexer sein. Angenommen, wir berechnen die eindeutigen Produkte, die von Tom im September und in der Nordregion verkauft wurden. Bitte gehen Sie wie folgt vor:

Geben Sie diese Formel in eine leere Zelle zur Ausgabe des Ergebnisses ein, zum Beispiel I2:

=SUMME(WENN(("Tom"=$C$2:$C$20)*($D$2:$D$20<=DATUM(2016; 9; 30))*($D$2:$D$20>=DATUM(2016; 9; 1))*("Nord"=$B$2:$B$20); 1/ZÄHLENWENNS($C$2:$C$20; "Tom"; $A$2:$A$20; $A$2:$A$20; $D$2:$D$20; "<="&DATUM(2016; 9; 30); $D$2:$D$20; ">="&DATUM(2016; 9; 1); $B$2:$B$20; "Nord")); 0) und drücken Sie dann gleichzeitig die Tasten Umschalt + Strg + Eingabe, um das eindeutige Ergebnis zu erhalten, siehe Screenshot: