Wie exportiert man einzelne oder alle Diagramme aus Excel-Arbeitsblättern in PowerPoint?

Manchmal müssen Sie möglicherweise ein Diagramm oder alle Diagramme aus Excel in PowerPoint für einen bestimmten Zweck exportieren. Dieser Artikel behandelt, wie Sie dies erreichen können.

Exportieren Sie ein einzelnes Diagramm oder alle Diagramme aus dem Excel-Arbeitsblatt in PowerPoint mit VBA-Code.

Exportieren Sie ein einzelnes Diagramm oder alle Diagramme aus dem Excel-Arbeitsblatt in PowerPoint mit VBA-Code.

Dieser Abschnitt stellt VBA-Codes vor, um ein einzelnes Diagramm oder alle Diagramme aus der Arbeitsmappe in PowerPoint zu exportieren. Bitte gehen Sie wie folgt vor.

1. Drücken Sie gleichzeitig die Tasten Alt + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie im Fenster Microsoft Visual Basic for Applications auf Extras > Verweise, wie im folgenden Screenshot gezeigt.

3. Scrollen Sie im Dialogfeld Verweise – VBAProject nach unten, um die Option Microsoft PowerPoint Object Library zu finden und auszuwählen, und klicken Sie dann auf die Schaltfläche OK. Siehe Screenshot:

4. Klicken Sie dann auf Einfügen > Modul.

5. Wenn Sie ein einzelnes Diagramm in PowerPoint exportieren möchten, wählen Sie bitte das Diagramm im Arbeitsblatt aus, kehren Sie dann zum Fenster Microsoft Visual Basic for Applications zurück, kopieren Sie den folgenden VBA-Code und fügen Sie ihn in das Modulfenster ein.

VBA-Code: Einzelnes Diagramm aus Excel-Arbeitsblatt in PowerPoint exportieren

Sub SingleActiveChartToPowerPoint_EarlyBinding1()
'Updated by Extendoffice 2017/9/15
  Dim pptApp As PowerPoint.Application
  Dim pptPres As PowerPoint.Presentation
  Dim pptSlide As PowerPoint.Slide
  Dim pptShape As PowerPoint.Shape
  Dim pptShpRng As PowerPoint.ShapeRange
  Dim xActiveSlideNow As Long
  On Error Resume Next
  If ActiveChart Is Nothing Then
    MsgBox "Select a chart and try again!", vbExclamation, "KuTools For Excel"
    Exit Sub
  End If
  Set pptApp = GetObject(, "PowerPoint.Application")
  If pptApp Is Nothing Then
    Set pptApp = CreateObject("PowerPoint.Application")
    Set pptPres = pptApp.Presentations.Add
    Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
  Else
    If pptApp.Presentations.Count > 0 Then
      Set pptPres = pptApp.ActivePresentation
      If pptPres.Slides.Count > 0 Then
        xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
        Set pptSlide = pptPres.Slides(xActiveSlideNow)
      Else
        Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
      End If
    Else
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    End If
  End If
  ActiveChart.ChartArea.Copy
  With pptSlide
    .Shapes.Paste
    Set pptShape = .Shapes(.Shapes.Count)
    Set pptShpRng = .Shapes.Range(pptShape.Name)
  End With
  With pptShpRng
    .Align msoAlignCenters, True
    .Align msoAlignMiddles, True
  End With
  pptShpRng.Select
End Sub

Wenn Sie alle Diagramme aus der Arbeitsmappe exportieren möchten, kopieren Sie den folgenden VBA-Code und fügen Sie ihn in das Modulfenster ein.

VBA-Code: Alle Diagramme aus Excel-Arbeitsblättern in PowerPoint exportieren

Option Explicit
'Updated by Extendoffice 2017/9/15
Dim pptApp As PowerPoint.Application
Dim pptPres As PowerPoint.Presentation
Dim pptSlide As PowerPoint.Slide
Dim pptSlideCount As Integer
Sub ChartsToPowerPoint()
    Dim xSheet As Worksheet
    Dim xChartsCount As Integer
    Dim xChart As Object
    Dim xActiveSlideNow As Integer
    On Error Resume Next
    For Each xSheet In ActiveWorkbook.Worksheets
        xChartsCount = xChartsCount + xSheet.ChartObjects.Count
    Next xSheet
    If xChartsCount = 0 Then
        MsgBox "Sorry, there are no charts to export!", vbCritical, "Ops"
        Exit Sub
    End If
    Set pptApp = GetObject(, "PowerPoint.Application")
    If pptApp Is Nothing Then
      Set pptApp = CreateObject("PowerPoint.Application")
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    Else
        If pptApp.Presentations.Count > 0 Then
          Set pptPres = pptApp.ActivePresentation
          If pptPres.Slides.Count > 0 Then
            xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
            Set pptSlide = pptPres.Slides(xActiveSlideNow)
          Else
            Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
          End If
        Else
          Set pptPres = pptApp.Presentations.Add
          Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
        End If
    End If
    For Each xSheet In ActiveWorkbook.Worksheets
        For Each xChart In xSheet.ChartObjects
            Call pptFormat(xChart.Chart)
        Next xChart
    Next xSheet
    For Each xChart In ActiveWorkbook.Charts
        Call pptFormat(xChart)
    Next xChart
    
    Set pptSlide = Nothing
    Set pptPres = Nothing
    Set pptApp = Nothing
    MsgBox "The charts were copied successfully to the new presentation!", vbInformation, "KuTools For Excel"
End Sub
Private Sub pptFormat(xChart As Chart)
    Dim xCharTiTle As String
    Dim I As Integer
    On Error Resume Next
    xCharTiTle = xChart.ChartTitle.Text
    xChart.ChartArea.Copy
    pptSlideCount = pptPres.Slides.Count
    Set pptSlide = pptPres.Slides.Add(pptSlideCount + 1, ppLayoutBlank)
    pptSlide.Select
    pptSlide.Shapes.PasteSpecial ppPasteJPG
    If xCharTiTle <> "" Then
        pptSlide.Shapes.AddTextbox msoTextOrientationHorizontal, 12.5, 20, 694.75, 55.25
    End If
    For I = 1 To pptSlide.Shapes.Count
        With pptSlide.Shapes(I)
            Select Case .Type
                Case msoPicture:
                    .Top = 87.84976
                    .left = 33.98417
                    .Height = 422.7964
                    .Width = 646.5262
                Case msoTextBox:
                    With .TextFrame.TextRange
                        .ParagraphFormat.Alignment = ppAlignCenter
                        .Text = xCharTiTle
                        .Font.Name = "Tahoma (Headings)"
                        .Font.Size = 28
                        .Font.Bold = msoTrue
                    End With
                End Select
        End With
    Next I
End Sub

6. Drücken Sie die Taste F5 oder klicken Sie auf die Schaltfläche Ausführen, um den Code auszuführen. Dann wird eine neue PowerPoint-Präsentation mit dem ausgewählten Diagramm oder allen Diagrammen geöffnet. Außerdem erhalten Sie ein Kutools for Excel-Dialogfeld, wie im folgenden Screenshot gezeigt. Klicken Sie bitte auf die Schaltfläche OK.

Entfesseln Sie die Magie von Excel mit Kutools AI

• Intelligente Ausführung: Führen Sie Zellenoperationen durch, analysieren Sie Daten und erstellen Sie Diagramme – alles angetrieben durch einfache Befehle.
• Benutzerdefinierte Formeln: Erstellen Sie maßgeschneiderte Formeln, um Ihre Arbeitsabläufe zu optimieren.
• VBA-Codierung: Schreiben und implementieren Sie VBA-Code mühelos.
• Formelinterpretation: Verstehen Sie komplexe Formeln mit Leichtigkeit.
• Textübersetzung: Überwinden Sie Sprachbarrieren in Ihren Tabellen.

Erweitern Sie Ihre Excel-Fähigkeiten mit KI-gestützten Tools. Laden Sie jetzt herunter und erleben Sie eine Effizienz wie nie zuvor!

Verwandte Artikel:

• Wie speichert man mehrere/alle Blätter als separate CSV- oder Textdateien in Excel?
• Wie speichert man die Auswahl oder die gesamte Arbeitsmappe als PDF in Excel?