Excel COUNTIFS-Funktion - Zellen mit mehreren Kriterien zählen - UND-Logik und ODER-Logik

Syntax der COUNTIFS-Funktion in Excel

• Syntax der COUNTIFS-Funktion
• Wichtige Hinweise

Zählen von Zellen, die mehrere angegebene Kriterien mit COUNTIFS in UND-Logik erfüllen

• COUNTIFS zum Zählen von Zellen, die mehrere angegebene Kriterien in einem Bereich erfüllen
• COUNTIFS zum Zählen von Zellen, die mehrere angegebene Kriterien in unterschiedlichen Bereichen erfüllen

Zählen von Zellen, die mehrere angegebene Kriterien in ODER-Logik erfüllen

• Addieren von COUNTIF- oder COUNTIFS-Ergebnissen, um Zellen zu zählen, die eines der angegebenen Kriterien erfüllen
• COUNTIFS mit einer Array-Konstante, um Zellen zu zählen, die eines der angegebenen Kriterien erfüllen

Syntax der COUNTIFS-Funktion in Excel

Als eine der statistischen Funktionen in Excel zählt COUNTIFS Zellen, die ein oder mehrere angegebene Kriterien in einem oder mehreren Bereichen erfüllen.

Syntax der COUNTIFS-Funktion

Die Syntax der COUNTIFS-Funktion enthält folgende Argumente:

• "Kriterien_Bereich1" (erforderlich) bezieht sich auf den ersten Zellbereich, in dem "Kriterien1" angewendet werden sollen.
• "Kriterien1" (erforderlich) bezieht sich auf die Bedingung, um festzulegen, welche Zellen in "Kriterien_Bereich1" gezählt werden sollen.
• "Kriterien_Bereich2", "Kriterien2" (optional) beziehen sich auf zusätzliche Bereiche und deren zugehörige Kriterien. Es sind bis zu 127 Paare von Bereich und Kriterien erlaubt.

Die COUNTIF-Funktion gibt einen numerischen Wert zurück – die Anzahl der Zellen, die ein oder mehrere angegebene Kriterien in den zugehörigen Bereichen erfüllen.

Wichtige Hinweise

• Die Anzahl der Zeilen und Spalten jedes zusätzlichen Bereichs sollte der von "Kriterien_Bereich1" entsprechen. Die Bereiche können gleich sein, nebeneinander liegen oder nicht benachbart sein.
•  
• In der COUNTIFS-Formel in Excel kann ein Sternchen (*) eine beliebige Anzahl von Zeichen übereinstimmen, während das Fragezeichen (?) ein einzelnes Zeichen übereinstimmt. Wenn Sie Zellen mit dem tatsächlichen Platzhalterzeichen - Sternchen (*) oder Fragezeichen (?) zählen müssen, setzen Sie ein Tilde (~) vor das Platzhalterzeichen. Zum Beispiel ~*, ~?.
• Anführungszeichen (") sind erforderlich, um nicht-numerische Kriterien einzuschließen, während numerische Kriterien ohne Anführungszeichen (") in Ordnung sind. Zum Beispiel 80, ">=80", "a", "india".
• Die COUNTIFS-Funktion unterscheidet keine Groß- und Kleinschreibung. Daher macht es keinen Unterschied für das Ergebnis der Formel, ob die Zeichenfolge "India" oder "INDIA" verwendet wird.
• Um eine Zellreferenz in der COUNTIFS-Funktion mit "Vergleichsoperatoren" zu verwenden, müssen Sie die Operatoren in Anführungszeichen (") setzen und ein kaufmännisches Und (&) dazwischen einfügen. Zum Beispiel ">"&B2.
• Die Reihenfolge der Vergleichsoperatoren ist wichtig: = kann nur allein oder nach > oder <.

Zählen von Zellen, die mehrere angegebene Kriterien mit COUNTIFS in UND-Logik erfüllen

Standardmäßig wertet die COUNTIFS-Funktion mehrere Kriterien mit "UND"-"Logik" aus. Das Ergebnis der COUNTIFS-Formel zeigt die Anzahl der Zellen, die alle angegebenen Kriterien erfüllen. Hier sind einige Beispiele zur Verwendung der COUNTIFS-Funktion, um Zellen in UND-Logik zu zählen.

COUNTIFS zum Zählen von Zellen, die mehrere angegebene Kriterien in einem Bereich erfüllen

√ Hinweis: Leere Zellen bedeuten, dass die Noten irgendwie nicht ordnungsgemäß erfasst wurden. Eine Note von 0 bedeutet, dass der Schüler den Test nicht abgelegt hat.

Um die Anzahl der Schüler zu zählen, deren Englischnote zwischen 60 und 90 liegt (einschließlich 60 und 90), haben wir hier zwei Möglichkeiten aufgelistet.

• Sie können eine COUNTIFS-Formel verwenden:

  =COUNTIFS(C2:C8,">=60",C2:C8,"<=90")

  Das Ergebnis ist "5"
•  
• Oder, wenn SieKutools für Excelinstalliert haben, können Sie zur Registerkarte "Kutools" gehen, "Auswählen" finden und im Dropdown-Menü auf "Bestimmte Zellen auswählen" klicken. Richten Sie es wie im Screenshot unten gezeigt ein:
  

Kutools für Excel - Verleihen Sie Excel mit über 300 essenziellen Tools einen echten Schub. Nutzen Sie dauerhaft kostenlose KI-Funktionen! Holen Sie es sich jetzt

☞ Weitere Ansätze zur Aufgabenbewältigung: Wie zählt man die Anzahl der Zellen zwischen zwei Werten oder Daten in Excel?

Um die Anzahl der gültigen Noten zu zählen (die Zellen sind nicht 0 oder leer), haben wir hier auch zwei Möglichkeiten aufgelistet.

• Sie können die folgende Formel verwenden:

  =COUNTIFS(C2:D8,"<>0",C2:D8,"<>")

  Das Ergebnis ist "12"
  √ Hinweis: "<>" in Excel bedeutet ungleich. "<>0" bedeutet ungleich 0; Und "<>" bedeutet ungleich leer, oder wir können sagen, sind nicht leer.
•  
• Mit "Kutools für Excel" installiert, können Sie auch zur Registerkarte "Kutools" gehen, "Auswählen" finden und im Dropdown-Menü auf "Bestimmte Zellen auswählen" klicken. Richten Sie es wie im Screenshot unten gezeigt ein:
  
  √ Hinweis: Kutools zählt standardmäßig keine leeren Zellen, daher können Sie unter "Spezifischer Typ" einfach die Kriterien als “"Ungleich 0"” festlegen.

  Kutools für Excel - Verleihen Sie Excel mit über 300 essenziellen Tools einen echten Schub. Nutzen Sie dauerhaft kostenlose KI-Funktionen! Holen Sie es sich jetzt

COUNTIFS zum Zählen von Zellen, die mehrere angegebene Kriterien in unterschiedlichen Bereichen erfüllen

• Um die Anzahl der Schüler zu zählen, die "aus Ländern, die mit dem Buchstaben 'a' enden" und "ihre Namen mit 'J' beginnen", verwenden Sie die Formel:

  =COUNTIFS(A2:A8,"j*", B2:B8,"*a")

  Das Ergebnis ist "2"
  √ Hinweis: Das Platzhalterzeichen "Sternchen (*)" stimmt mit einer beliebigen Anzahl von Zeichen überein.
•  
• Um die Anzahl der Schüler zu zählen, deren "Englisch- und Mathenoten beide über (nicht gleich) den Noten von Eddie (Werte in C4 und D4) liegen", verwenden Sie eine der folgenden Formeln:

  =COUNTIFS(C2:C8,">60",D2:D8,">80")

  =COUNTIFS(C2:C8,">"&C4,D2:D8,">"&D4

  Das Ergebnis ist "3"
•  
• Um die Anzahl der Schüler zu zählen, die "aus Indien (der Wert in B2)" und "mit der Note A (der Wert in E2)" stammen, verwenden Sie eine der folgenden Formeln:

  =COUNTIFS(B2:B8,"india",E2:E8,"a")

  =COUNTIFS(B2:B8,B2,E2:E8,E2)

  Das Ergebnis ist "2"

Zählen von Zellen, die mehrere angegebene Kriterien in ODER-Logik erfüllen

Zellen zu zählen, die mehrere angegebene Kriterien in "ODER-Logik" erfüllen, bedeutet, die Gesamtzahl der Zellen zu zählen, die Kriterium1, Kriterium2 und weitere Kriterien erfüllen, mit anderen Worten, die Zellen zu zählen, die eines der (mindestens eines) Kriterien erfüllen. Um dies zu tun, haben wir 2 Methoden unten aufgeführt:

Addieren von COUNTIF- oder COUNTIFS-Ergebnissen, um Zellen zu zählen, die eines der angegebenen Kriterien erfüllen

Durch das Addieren der Anzahl der Zellen, die mindestens ein Kriterium erfüllen, das Sie angegeben haben, lässt sich leicht die Gesamtzahl der Zellen generieren. Was Sie also tun müssen, ist, mehrere COUNTIF(S)-Formeln zu schreiben, wie Sie sie benötigen, und dann arithmetische Operationen durchzuführen.

• Um die Anzahl der Schüler zu zählen, die "aus Indien (Wert in B2)" oder "England (Wert in B3)" stammen, verwenden Sie eine der folgenden Formeln:

  =COUNTIF(B2:B8,"india")+COUNTIF(B2:B8,"england")

  =COUNTIF(B2:B8,B2)+COUNTIF(B2:B8,B3)

  Das Ergebnis ist "4"
  √ Hinweis: Sie können "Kutools für Excel" verwenden, wenn Sie das professionelle Add-In installiert haben: "Kutools" > "Auswählen" > "Bestimmte Zellen auswählen", wählen Sie "ODER" unter "Spezifischer Typ".
•  
• Um die Anzahl der Schüler mit "Englisch- oder Mathenote über 80 (einschließlich 80)" zu zählen, verwenden Sie eine der folgenden Formeln:

  =COUNTIF(C2:C8,">=80")+COUNTIF(D2:D8,">=80")-COUNTIFS(C2:C8,">=80", D2:D8,">=80")

  Das Ergebnis ist "5"
  √ Hinweis: COUNTIFS(C2:C8;">=80"; D2:D8;">=80") hier zu subtrahieren dient dazu, Duplikate zu entfernen, also die Schüler mit Englisch- und Mathenoten beide über 80.

COUNTIFS mit einer Array-Konstante, um Zellen zu zählen, die eines der angegebenen Kriterien erfüllen

Während das Addieren von COUNTIF- oder COUNTIFS-Ergebnissen in der Formatierung zu groß sein kann, können wir die Verwendung von SUMME und COUNTIFS-Funktionen mit einer Array-Konstante kombinieren, um die Anzahl der unterschiedlichen Zellen zu zählen, die die zugehörigen Kriterien erfüllen. Überprüfen Sie die Beispiele unten:

• Um die Anzahl der Schüler zu zählen, die "aus Indien oder England" stammen, verwenden Sie die Formel (ein Bereich):

  =SUM(COUNTIF(B2:B8,{"india","england"}))

  Das Ergebnis ist "4"
•  
• Um die Anzahl der Schüler zu zählen, die "aus Indien oder Amerika mit der Note A, B oder C" stammen, verwenden Sie die Formel:

  =SUM(COUNTIFS(B2:B8,{"india","america"},E2:E8,{"a";"b";"c"}))

  Das Ergebnis ist "4"
  √ Hinweis: Sie müssen im zweiten Array-Konstanten Semikolons (;) verwenden. Für Fälle mit mehr Kriterien sollten Sie eine "SUMMENPRODUKT"-Formel in Betracht ziehen.