Wie sendet man jedes Blatt an verschiedene E-Mail-Adressen aus Excel?

Wenn Sie eine Excel-Arbeitsmappe mit mehreren Arbeitsblättern haben, wobei in jeder Zelle S1 eine E-Mail-Adresse steht, möchten Sie vielleicht jedes Blatt als separaten Anhang an den jeweiligen Empfänger senden. Diese Aufgabe kann mühsam sein, wenn sie manuell durchgeführt wird, insbesondere bei der Bearbeitung einer großen Anzahl von Blättern. In diesem Tutorial zeigen wir Ihnen, wie Sie VBA-Code verwenden können, um jedes Arbeitsblatt aus Ihrer Excel-Datei automatisch als Anhang an die in Zelle S1 jedes Blatts angegebene E-Mail-Adresse zu senden.

Senden Sie jedes Blatt an verschiedene E-Mail-Adressen aus Excel mit VBA-Code

Der folgende VBA-Code ermöglicht es Ihnen, jedes Arbeitsblatt als Anhang an den entsprechenden Empfänger zu senden, der in Zelle S1 aufgelistet ist. Bitte folgen Sie diesen Schritten:

1. Drücken Sie gleichzeitig die Tasten Alt + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie dann auf Einfügen > Modul und kopieren Sie den folgenden VBA-Code in das Fenster.

VBA-Code: Senden Sie jedes Blatt als Anhang an verschiedene E-Mail-Adressen

Sub Mail_Every_Worksheet()
'Updateby ExtendOffice
  Dim xWs As Worksheet
  Dim xWb As Workbook
  Dim xFileExt As String
  Dim xFileFormatNum As Long
  Dim xTempFilePath As String
  Dim xFileName As String
  Dim xOlApp As Object
  Dim xMailObj As Object
  On Error Resume Next
  With Application
      .ScreenUpdating = False
      .EnableEvents = False
  End With
  xTempFilePath = Environ$("temp") & "\"
  If Val(Application.Version) < 12 Then
    xFileExt = ".xls": xFileFormatNum = -4143
  Else
    xFileExt = ".xlsm": xFileFormatNum = 52
  End If
  Set xOlApp = CreateObject("Outlook.Application")
  For Each xWs In ThisWorkbook.Worksheets
    If xWs.Range("S1").Value Like "?*@?*.?*" Then
      xWs.Copy
      Set xWb = ActiveWorkbook
      xFileName = xWs.Name & " of " _
                   & VBA.Left(ThisWorkbook.Name, VBA.InStr(ThisWorkbook.Name, ".") - 1) & " "
      Set xMailObj = xOlApp.CreateItem(0)
      xWb.Sheets.Item(1).Range("S1").Value = ""
      With xWb
        .SaveAs xTempFilePath & xFileName & xFileExt, FileFormat:=xFileFormatNum
        With xMailObj
        'specify the CC, BCC, Subject, Body below
            .To = xWs.Range("S1").Value
            .CC = ""
            .BCC = ""
            .Subject = "This is the Subject line"
            .Body = "Hi there"
            .Attachments.Add xWb.FullName
            .Display
        End With
        .Close SaveChanges:=False
      End With
      Set xMailObj = Nothing
      Kill xTempFilePath & xFileName & xFileExt
    End If
  Next
  Set xOlApp = Nothing
  With Application
      .ScreenUpdating = True
      .EnableEvents = True
  End With
End Sub

3. Drücken Sie dann die F5-Taste, um diesen Code auszuführen, und jedes Blatt wird automatisch als Anhang in das neue Nachrichtenfenster eingefügt, siehe Screenshot:

4. Klicken Sie abschließend auf die Schaltfläche Senden, um jede E-Mail einzeln zu versenden.

Kutools für Excel: Personalisierte E-Mails mit einem Klick ganz einfach versenden!

Müde davon, Kunden-E-Mails einzeln zu versenden? Mit der Funktion „E-Mail senden“ von Kutools für Excel wird die Kommunikation schneller und professioneller! Erstellen Sie einfach ein Excel-Arbeitsblatt mit Namen, E-Mail-Adressen, Registrierungscodes und fügen Sie Platzhalter ein – das System generiert automatisch personalisierte E-Mails und versendet Hunderte mit nur einem Klick. Keine wiederholende Arbeit mehr!

• 💡 Dynamische Platzhalter (z. B. Name, Registrierungscode) füllen personalisierte Inhalte für jeden Empfänger automatisch aus und sorgen dafür, dass jede E-Mail individuell gestaltet wirkt.
• 📎 Personalisierte Dateien anhängen für eine präzise Zustellung
• 📤 Nahtlose Integration mit Outlook für sicheres und zuverlässiges Versenden
• 📝 E-Mail-Vorlagen speichern und wiederverwenden für maximale Effizienz
• 🎨 Was-du-siehst-ist-was-du-bekommst-Editor, der leicht zu bedienen ist
• 🖋 Nutzt Ihre Outlook-Signatur – kein zusätzliches Setup erforderlich, einfach senden!
• Kutools für Excel jetzt herunterladen!