KutoolsforOffice — Eine Lösung, fünf leistungsstarke Tools.Mehr erreichen mit weniger Aufwand.März-Aktion: 20 % Rabatt

Eindeutige und unterschiedliche Werte einfach zählen – 7 Beispiele

AutorXiaoyang Änderungsdatum

Normalerweise sind in Excel eindeutige Werte solche, die ohne jegliche Duplikate nur einmal in der Liste vorkommen, während unterschiedliche Werte sämtliche Unterschiedlicher Wert umfassen (eindeutige Werte + erste Duplikatvorkommen). Bei der Arbeit mit einem großen Datensatz müssen Sie möglicherweise die Anzahl der eindeutigen und unterschiedlichen Werte innerhalb einer Zellenliste zählen, wie im folgenden Screenshot dargestellt. In diesem Tutorial werden einige schnelle Methoden zum Zählen eindeutiger und unterschiedlicher Werte in Excel vorgestellt.

Eindeutige Werte oder unterschiedliche Werte in einer Liste zählen

Anzahl der eindeutigen Werte in einem Bereich in Excel

Einzigartige Anzahl zählen Werte (eindeutige und erste Duplikatvorkommen) in Excel

Beispieldatei herunterladen

Eindeutige unterschiedliche Werte zählen

Anzahl der eindeutigen Werte in einem Bereich in Excel

In diesem Abschnitt werden einige Formelbeispiele vorgestellt, mit denen sich die Anzahl eindeutiger Werte in einer Liste ermitteln lässt – einschließlich der Aufteilung nach Text und Zahl.

Anzahl der eindeutigen Werte in einem Bereich mit Formeln

Angenommen, ich habe eine Namensliste, die einige doppelte Namen enthält. Nun möchte ich nur die Anzahl der eindeutigen Namen ermitteln (die im Screenshot gelb markiert sind):

Beispieldaten

Um dieses Problem zu lösen, kann die folgende Arrayformel helfen:

Schritt 1: Formel eingeben

Geben Sie die folgende Formel in eine leere Zelle ein, in der das Ergebnis ausgegeben werden soll, oder kopieren Sie sie dorthin:

=SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))
Hinweis: In der obigen Formel ist „A2:A12“ die Datenliste, für die Sie eindeutige Werte zählen möchten.

Schritt 2: Drücken Sie die Tasten Strg + Umschalt + Enter, um das korrekte Ergebnis zu erhalten:

Eindeutige Werte mit Formel zählen

Hinweise:

  1. Wenn Ihre Zellenliste andere Datentypen wie Zahlen, boolesche Werte oder Fehlerwerte enthält, liefert die obige Formel die Anzahl der eindeutigen Werte – unabhängig vom jeweiligen Datentyp.
  2. Enthält die Datenliste leere Zellen, schließt diese Formel sie automatisch aus.
  3. Um ausschließlich die eindeutigen Textwerte zu zählen, falls andere Datentypen vorhanden sind, wenden Sie bitte die folgende Arrayformel an und drücken Sie anschließend die Tasten „Strg“ + „Umschalttaste“ + „Enter“, um das Ergebnis zu erhalten:
    =SUM(IF(ISTEXT(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))
  4. Um ausschließlich eindeutige Zahlen aus einer Zellenliste zu zählen, die beliebige Datentypen enthält, verwenden Sie bitte die folgende Arrayformel und drücken Sie anschließend die Tasten „Strg“ + „Umschalttaste“ + „Enter“, um das Ergebnis zu erhalten:
    =SUM(IF(ISNUMBER(A2:A12)*COUNTIF(A2:A12,A2:A12)=1,1,0))

Anzahl der eindeutigen Werte in einem Bereich mit wenigen Klicks durch Kutools für Excel

Es kann mühsam sein, sich die Formeln zu merken, wenn Sie sie das nächste Mal anwenden möchten. Mit „Kutools für Excel“ hingegen erhalten Sie das Ergebnis im Handumdrehen: Wählen Sie einfach unter  „Formelhelfer“ die Option „Anzahl der eindeutigen Werte in einem Bereich“ – und schon sind Sie fertig! Sehen Sie selbst in der folgenden Demo:

  1. Klicken Sie auf eine Zelle, um das Ergebnis auszugeben;
  2. Aktivieren Sie diese Funktion, indem Sie auf „Kutools“ > „Formelhelfer“ > „Formelhelfer“ > „Statistik“ > „Anzahl der eindeutigen Werte in einem Bereich“ klicken;
  3. Wählen Sie die gewünschte Datenliste aus und klicken Sie auf „OK“.
    Eindeutige Werte mit Kutools zählen
Tipps:
  1. Um diese Funktion nutzen zu können, müssen Sie Kutools für Excel herunterladen und installieren.
  2. Die Funktion „Formelhelfer“ bietet über 40 häufig genutzte Formeln – darunter „Eindeutige Werte extrahieren“, „Zellen mit eindeutigen Werten aus einem Bereich extrahieren (einschließlich der ersten Duplikate)“, „Anzahl der durch Kommas getrennten Werte in einer Zelle“, „Summe basierend auf identischem Text“ und viele weitere.

Anzahl der eindeutigen Werte in einem Bereich in Excel 365/2021 mit Formeln

Wenn Sie Excel 365 oder Excel 2021 verwenden, steht Ihnen die neue EINDEUTIG-Funktion zur Verfügung – mit ihr erstellen Sie einfachere Formeln, um die Anzahl der eindeutigen Werte in einem Bereich eines Datensatzes zu ermitteln.

Geben Sie beispielsweise zur Ermittlung der Anzahl eindeutiger Namen im Bereich A2:A12 die folgende Formel ein:

Schritt 1: Kopieren oder geben Sie die folgende Formel ein

=IFERROR(ROWS(UNIQUE(A2:A12,,TRUE)), 0)
Hinweis: In dieser Formel ist „A2:A12“ die Datenliste, für die Sie Anzahl der eindeutigen Werte in einem Bereich möchten.

Schritt 2: Drücken Sie die Eingabetaste, um das Ergebnis zu erhalten:

Eindeutige Werte in Excel 365/2021 mit Formel zählen

Tipps:

  1. Enthält die Datenliste verschiedene Datentypen wie Text, Zahlen, boolesche Werte oder Fehlerwerte, ermittelt diese Formel die Anzahl der eindeutigen Werte – unabhängig vom jeweiligen Datentyp.
  2. Die obige Formel berücksichtigt Anzahl der eindeutigen Werte in einem Bereich einschließlich leerer Zellen. Wenn Sie leere Zellen ausschließen möchten, wenden Sie bitte die folgende Formel an und drücken Sie lediglich die „Enter“-Taste:
    =SUM(IF(COUNTIF(A2:A12,A2:A12)=1,1,0))

Einzigartige Anzahl zählen Werte (eindeutige und erste Duplikatvorkommen) in Excel

Um die unterschiedlichen Werte (eindeutige Werte und erste Vorkommen von Duplikaten) in einer Zellenliste zu zählen, stelle ich hier weitere Formeln vor, mit denen Sie diese Aufgabe mühelos meistern.

Einzigartige Anzahl zählen Werte mit Formeln

In Excel können Sie eine der folgenden Formeln verwenden, um die Anzahl unterschiedlicher Werte zu ermitteln.

Schritt 1: Geben Sie eine der folgenden Formeln ein

Formel 1: Drücken Sie nach der Eingabe der Formel die „Enter“-Taste.

=SUMPRODUCT(1/COUNTIF(A2:A12,A2:A12))

Formel 2: Drücken Sie nach der Eingabe der Formel gleichzeitig die Tasten „Strg“ + „Umschalt“ + „Enter“.

=SUM(1/COUNTIF(A2:A12,A2:A12))
Hinweis: In diesen Formeln  ist „A2:A12“ die Datenliste, für die Sie Unterschiedlicher Wert zählen möchten.

Ergebnis:

Unterschiedliche Werte mit Formel zählen

Tipps:

  1. Enthält die Datenliste weitere Datentypen wie Zahlen, boolesche Werte oder Fehlerwerte, gibt diese Formel alle unterschiedlichen Werte unabhängig von ihrem jeweiligen Datentyp zurück.
  2. Bei Verwendung der obigen Formel erhalten Sie den Fehlerwert #DIV/0, wenn die Datenliste leere Zellen enthält. Um diesen Fehler zu beheben und leere Zellen zu ignorieren, sollten Sie eine der folgenden Formeln anwenden:
    Formel 1: Nach Eingabe der Formel drücken Sie die „Enter“-Taste.
    =SUMPRODUCT((A2:A12<>"")/COUNTIF(A2:A12,A2:A12&""))
    Formel 2: Nach Eingabe der Formel drücken Sie die Tasten „Strg“ + „Umschalttaste“ + „Enter“.
    =SUM(IF(A2:A12<>"",1/COUNTIF(A2:A12, A2:A12), 0))

    Unterschiedliche Werte mit Formel zählen, leere Zellen ausschließen

  3. Um ausschließlich die Anzahl unterschiedlicher Textwerte innerhalb einer Datenliste zu ermitteln, wenden Sie bitte die folgende Arrayformel an und drücken Sie die Tasten „Strg“ + „Umschalttaste“ + „Enter“, um das Ergebnis zu erhalten:
    =SUM(IF(ISTEXT(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))
  4. Um ausschließlich unterschiedliche numerische Werte zu zählen, verwenden Sie bitte die folgende Arrayformel und drücken Sie die Tasten „Strg“ + „Umschalttaste“ + „Enter“, um das Ergebnis zu erhalten:
    =SUM(IF(ISNUMBER(A2:A12),1/COUNTIF(A2:A12, A2:A12),""))

Einzigartige Anzahl zählen Werte mit wenigen Klicks durch Kutools für Excel

Wenn Sie die Formeln in Ihrer Arbeitsmappe häufig verwenden müssen, kann es mühsam sein, sich diese alle zu merken. Mit „Kutools für Excel“ und der Option „Zelle mit eindeutigen Werten zählen (inklusive des ersten Duplikats)“ im „Formelhelfer“ erhalten Sie das gewünschte Ergebnis jedoch mit nur wenigen Klicks. Sehen Sie selbst in der folgenden Demo:

  1. Klicken Sie auf eine Zelle, um das Ergebnis auszugeben;
  2. Aktivieren Sie diese Funktion, indem Sie auf „Kutools“ > „Formelhelfer“ > „Statistik“ > „Zelle mit eindeutigen Werten zählen (inklusive des ersten Duplikats)“ klicken;
  3. Wählen Sie die gewünschte Datenliste aus und klicken Sie auf „OK“.
    Unterschiedliche Werte mit Kutools zählen
Tipps:
  1. Um diese Funktion nutzen zu können, müssen Sie Kutools für Excel herunterladen und installieren.
  2. Die Funktion „Formelhelfer“ bietet über 40 häufig genutzte Formeln – darunter „Eindeutige Werte extrahieren“, „Zellen mit eindeutigen Werten aus einem Bereich extrahieren (einschließlich der ersten Duplikate)“, „Anzahl der durch Kommas getrennten Werte in einer Zelle“, „Summe basierend auf identischem Text“ und viele weitere.

Einzigartige Anzahl zählen Werte mit PivotTable

In Excel hilft Ihnen eine PivotTable ebenfalls dabei, die Anzahl unterschiedlicher Werte aus einer Datenliste zu ermitteln. Gehen Sie dazu wie folgt vor:

Schritt 1: Erstellen Sie eine PivotTable

  1. Wählen Sie die Datenliste aus und klicken Sie im Menüband auf „Einfügen“ > „PivotTable“, siehe Screenshot:
    Eine PivotTable für ausgewählte Daten erstellen
  2. Im sich öffnenden Dialogfeld „PivotTable aus Tabelle oder Bereich erstellen“:
    (1). Wählen Sie ein neues Arbeitsblatt oder ein vorhandenes Arbeitsblatt, auf dem die PivotTable platziert werden soll;
    (2). Aktivieren Sie dann das Kontrollkästchen „Diese Daten dem Datenmodell hinzufügen“.
    (3). Klicken Sie anschließend auf die Schaltfläche „OK“.
    Optionen im Dialogfeld „PivotTable aus Tabelle oder Bereich“ festlegen

Schritt 2: Ordnen Sie das Feld an und wählen Sie die Option „Unterschiedliche Anzahl“

  1. Der Bereich „PivotTable-Felder“ wird angezeigt. Ziehen Sie das Feld „Namen“ in den Bereich „Werte“ – siehe folgende Demo:
    Das Feld für die PivotTable anordnen
  2. Klicken Sie dann auf den Dropdown-Pfeil bei „Anzahl von Namen“ und wählen Sie „Wert Feld-Einstellungen“, siehe Screenshot:
    Option „Wertfeldeinstellungen“ anklicken
  3. Anschließend öffnet sich das Dialogfeld „Wert Feld-Einstellungen“. Wählen Sie auf der Registerkarte „Werte zusammenfassen nach“ im Listenfeld die Option „Unterschiedliche Anzahl“ aus und klicken Sie auf „OK“ (siehe Screenshot).
    Option „Anzahl unterschiedlicher Werte“ auswählen

Ergebnis:

Die erstellte PivotTable zeigt nun die unterschiedliche Anzahl der Datenliste an, wie im folgenden Screenshot dargestellt:

PivotTable-Ergebnis zum Zählen unterschiedlicher Werte

Tipps:

  1. Wenn Sie Ihre Quelldaten aktualisieren, klicken Sie einfach mit der rechten Maustaste auf die PivotTable und wählen „Aktualisieren“, um stets die aktuellsten Zahlen zu erhalten.
  2. Die Option „Unterschiedliche Anzahl“ steht erst ab Excel 2013 zur Verfügung.

Einzigartige Anzahl zählen Werte in Excel 365/2021 mit Formeln

In Excel 365 oder Excel 2021 können Sie die neue EINDEUTIG-Funktion ideal mit der bewährten ANZAHL2-Funktion kombinieren, um eine besonders einfache Formel zu erstellen.

Bitte kopieren oder geben Sie die folgende Formel in eine leere Zelle ein und drücken Sie die „Enter“-Taste, um das Ergebnis zu erhalten:

=COUNTA(UNIQUE(A2:A12))
Hinweis: In dieser Formel ist „A2:A12“ die Datenliste, für die Sie Einzigartige Anzahl zählen-Werte zählen möchten.

Unterschiedliche Werte in Excel 365/2021 mit Formel zählen

Tipps:

  1. Enthält die Datenliste verschiedene Datentypen wie Text, Zahlen, boolesche Werte oder Fehlerwerte, zählt diese Formel sämtliche unterschiedlichen Werte – unabhängig von ihrem jeweiligen Datentyp.
  2. Die obige Formel zählt die eindeutigen Werte einschließlich leerer Zellen. Möchten Sie leere Zellen ausschließen, wenden Sie bitte die folgende Formel an und drücken Sie die „Enter“-Taste, um das Ergebnis zu erhalten:
    =COUNTA(UNIQUE(FILTER(A2:A12, A2:A12<>"")))

    Unterschiedliche Werte in Excel 365/2021 mit Formel zählen, leere Zellen ausschließen

Verwandte Artikel:

  • Anzahl der eindeutigen Werte in einem Bereich in PivotTable
  • Standardmäßig werden beim Erstellen einer PivotTable auf Basis eines Datenbereichs, der einige Doppelte Werte enthält, alle Datensätze ebenfalls gezählt. Manchmal möchten wir jedoch nur die eindeutigen Werte einer Spalte zählen, um das korrekte Ergebnis zu erhalten. In diesem Artikel erläutere ich, wie Sie eindeutige Werte in PivotTable zählen können.
  • Anzahl der eindeutigen Werte in einem Bereich mit mehreren Kriterien
  • Hier liegt ein Datenbereich vor, der mehrere Namen, Projekte und Standorte enthält. Ihre Aufgabe: Ermitteln Sie diejenigen Namen, die den aufgelisteten Kriterien entsprechen – und zählen Sie jeden übereinstimmenden Namen nur einmal, wie im folgenden Screenshot gezeigt. Kennen Sie eine Methode, um diese Aufgabe zu lösen? In diesem Artikel stelle ich Ihnen passende Tricks vor.
  • Eindeutige Werte verketten
  • Angenommen, Sie haben eine lange Liste mit Werten, die doppelte Datensätze enthält – wie können Sie schnell und einfach nur die eindeutigen Werte ermitteln und diese in einer einzigen Zelle verketten?