KutoolsforOffice — Eine Lösung, fünf leistungsstarke Tools.Mehr erreichen mit weniger Aufwand.März-Aktion: 20 % Rabatt

Verschachtelte WENN-Anweisungen in Excel meistern – Eine Schritt-für-Schritt-Anleitung

AutorSiluvia Änderungsdatum

In Excel ist die WENN-Funktion zwar unverzichtbar für grundlegende logische Prüfungen, doch komplexe Bedingungen erfordern oft verschachtelte WENN-Anweisungen, um anspruchsvolle Datenverarbeitungsaufgaben zu meistern. In diesem umfassenden Leitfaden erläutern wir detailliert die Grundlagen verschachtelter WENN-Funktionen – von der korrekten Syntax bis hin zu praxisnahen Anwendungsbeispielen, einschließlich der Kombination mit UND- und ODER-Bedingungen. Zudem zeigen wir Ihnen, wie Sie die Lesbarkeit verschachtelter WENN-Konstrukte gezielt verbessern, liefern wertvolle Tipps dazu und stellen leistungsstarke Alternativen wie SVERWEIS, WENNS und weitere Funktionen vor, um komplexe logische Operationen einfacher, übersichtlicher und effizienter zu gestalten.

Ein Screenshot der verschachtelten WENN-Funktionen in Excel

Excel-WENN-Funktion im Vergleich zu verschachtelten WENN-Anweisungen

Die WENN-Funktion und verschachtelte WENN-Anweisungen in Excel verfolgen ähnliche Ziele, unterscheiden sich jedoch deutlich in Komplexität und Anwendung.

IF Function: Die WENN-Funktion prüft eine Bedingung und gibt einen Wert zurück, wenn die Bedingung wahr ist, und einen anderen Wert, wenn sie falsch ist.
  • Die Syntax lautet:
    =IF (logical_test, [value_if_true], [value_if_false])
  • Einschränkung: Kann jeweils nur eine Bedingung verarbeiten und eignet sich daher weniger für komplexe Entscheidungsszenarien, in denen mehrere Kriterien gleichzeitig berücksichtigt werden müssen.
Verschachtelte WENN-Anweisungen: Verschachtelte WENN-Funktionen – also eine WENN-Funktion innerhalb einer anderen – ermöglichen es Ihnen, mehrere Kriterien zu prüfen und erhöhen die Anzahl möglicher Ergebnisse.
  • Die Syntax lautet:
    =IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 ))
  • Komplexität: Kann mehrere Bedingungen verarbeiten, wird aber bei zu vielen Verschachtelungsebenen schnell unübersichtlich und schwer lesbar.

Verwendung von verschachteltem WENN

Dieser Abschnitt zeigt die grundlegende Anwendung verschachtelter WENN-Funktionen in Excel – inklusive Syntax, praxisnaher Beispiele sowie deren Kombination mit UND- oder ODER-Bedingungen.

Syntax von verschachteltem WENN

Das Verständnis der Syntax einer Funktion bildet die Grundlage für ihre korrekte und effektive Anwendung in Excel. Beginnen wir daher mit der Syntax verschachtelter WENN-Funktionen.

Syntax:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Argumente:

  • Bedingung1, Bedingung2, Bedingung3: Dies sind die zu prüfenden Bedingungen. Jede Bedingung wird nacheinander ausgewertet – beginnend mit Bedingung1.
  • Ergebnis 1: Dies ist der Wert, der zurückgegeben wird, wenn Bedingung 1 WAHR ist.
  • Ergebnis2: Dieser Wert wird zurückgegeben, wenn Bedingung1 FALSCH und Bedingung2 WAHR ist. Wichtig: Ergebnis2 wird nur dann ausgewertet, wenn Bedingung1 FALSCH ist.
  • Ergebnis3: Dieser Wert wird zurückgegeben, wenn sowohl Bedingung1 als auch Bedingung2 FALSCH und Bedingung3 WAHR ist. Damit Ergebnis3 ausgewertet wird, müssen die vorherigen Bedingungen – Bedingung1 und Bedingung2 – beide FALSCH sein.
  • Ergebnis4: Dieses Ergebnis wird zurückgegeben, wenn alle Bedingungen (Bedingung1, Bedingung2 und Bedingung3) FALSCH sind.
    Kurz gesagt lässt sich dieser Ausdruck wie folgt interpretieren:
    Test condition1, if TRUE, return result1, if FALSE,
    test condition2, if TRUE, return result2, if FALSE,
    test condition3, if TRUE, return result3, if FALSE,
    return result4

Beachten Sie: In einer verschachtelten WENN-Struktur wird jede nachfolgende Bedingung nur dann geprüft, wenn alle vorherigen Bedingungen FALSCH ergeben haben. Diese sequenzielle Auswertung ist entscheidend, um die Funktionsweise verschachtelter WENN-Anweisungen richtig zu verstehen.

Praktische Beispiele für verschachteltes WENN

Nun betrachten wir anhand zweier praktischer Beispiele, wie verschachtelte WENN-Funktionen eingesetzt werden.

Beispiel 1: Notensystem

Wie in der folgenden Abbildung dargestellt, gehen wir davon aus, dass Sie eine Liste mit Schülerpunktzahlen haben und auf Basis dieser Punktzahlen Noten vergeben möchten. Dies lässt sich mithilfe einer verschachtelten WENN-Funktion realisieren.

Hinweis: Die Notenstufen und die entsprechenden Punktebereiche sind im Bereich E2:F6 aufgeführt.

Ein Screenshot, der das Notensystem-Beispiel für verschachtelte WENN-Funktionen in Excel zeigt

Wählen Sie eine leere Zelle (hier: C2), geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um das Ergebnis zu erhalten. Ziehen Sie anschließend das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))
Hinweise:
  • Sie können die Notenstufe direkt in der Formel angeben, sodass die Formel wie folgt geändert werden kann:
    =IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
  • Diese Formel weist basierend auf dem Wert in Zelle A2 eine Note (A, B, C, D oder F) gemäß der standardmäßigen Notenskala zu – ein typischer Anwendungsfall für verschachtelte WENN-Anweisungen in akademischen Bewertungssystemen.
  • Erläuterung der Formel:
    1. A2>=90: Dies ist die erste Bedingung, die die Formel prüft. Wenn der Wert in Zelle A2 größer oder gleich 90 ist, gibt die Formel „A“ zurück.
    2. A2>=80: Wenn die erste Bedingung nicht erfüllt ist (der Wert liegt unter 90), prüft sie, ob A2 größer oder gleich 80 ist. In diesem Fall gibt die Formel „B“ zurück.
    3. A2>=70: Die Formel prüft außerdem, ob der Wert – sofern er unter 80 liegt – größer oder gleich 70 ist. Trifft dies zu, gibt sie „C“ zurück.
    4. A2>=60: Liegt der Wert unter 70, prüft die Formel, ob er größer oder gleich 60 ist. Ist dies der Fall, gibt sie „D“ zurück.
    5. "F": Schließlich gibt die Formel „F“ zurück, wenn keine der oben genannten Bedingungen erfüllt ist – das heißt, wenn der Wert unter 60 liegt.
Beispiel 2: Berechnung der Verkaufsprovision

Stellen Sie sich ein Szenario vor, in dem Vertriebsmitarbeiter je nach ihren Verkaufsergebnissen unterschiedliche Provisionssätze erhalten. Wie in der folgenden Abbildung dargestellt, können Sie die Provision eines Verkäufers anhand verschiedener Umsatzschwellen mithilfe verschachtelter WENN-Anweisungen berechnen.

Hinweis: Die Provisionsraten und die entsprechenden Umsatzbereiche sind im Bereich E2:F4 aufgeführt.
  • Stufe 1 ($20,000+): 20 %
  • Stufe 2 ($10,000–$19,999): 15 %
  • Stufe 3 (<$10,000): 10 %

Ein Screenshot, der das Beispiel zur Berechnung der Verkaufsprovision mit verschachtelten WENN-Funktionen in Excel zeigt

Wählen Sie eine leere Zelle (hier: C2), geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um das Ergebnis zu erhalten. Ziehen Sie anschließend das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Ein Screenshot, der die Ergebnisse der Verkaufsprovisionsberechnung mithilfe von verschachtelten WENN-Formeln anzeigt

Hinweise:
  • Sie können den Provisionsprozentsatz direkt in der Formel angeben, sodass die Formel wie folgt geändert werden kann:
    =B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%))
  • Die bereitgestellte Formel berechnet die Provision eines Verkäufers auf Basis seines Umsatzes – mit unterschiedlichen Provisionsraten je nach erreichter Umsatzschwelle.
  • Erläuterung der Formel:
    1. B2: Dies stellt den Umsatz des Verkäufers dar, der als Grundlage für die Provisionsberechnung dient.
    2. WENN(B2>20000; „20%"; ...): Dies ist die erste geprüfte Bedingung. Sie prüft, ob der Umsatz in B2 größer als 20.000 ist. Wenn ja, wendet die Formel einen Provisions­satz von 20 % an.
    3. WENN(B2>=10000; "15 %"; „10%"): Ist die erste Bedingung falsch (Umsatz nicht größer als 20.000), prüft die Formel, ob der Umsatz mindestens 10.000 beträgt. Trifft dies zu, wird ein Provisions­satz von 15 % angewendet. Liegt der Umsatz unter 10.000, greift standardmäßig ein Provisions­satz von 10 %.

Verschachteltes WENN mit UND- / ODER-Bedingungen

In diesem Abschnitt passe ich das erste obige Beispiel „Notensystem“ an, um zu zeigen, wie man verschachtelte WENN-Funktionen in Excel mit UND- oder ODER-Bedingungen kombiniert. Im überarbeiteten Notenbeispiel füge ich eine zusätzliche Bedingung basierend auf der „Anwesenheitsquote“ hinzu.

Ein Screenshot, der das Notenbeispiel mit Anwesenheitskriterien in Excel veranschaulicht

Verwendung verschachtelter WENN-Funktionen mit einer UND-Bedingung

Ein Schüler erhält eine Notenverbesserung, wenn sowohl die Punktzahl als auch die Anwesenheit die festgelegten Kriterien erfüllen. So wird beispielsweise die Note eines Schülers, dessen Punktzahl mindestens 60 beträgt und dessen Anwesenheitsquote bei 95 % oder mehr liegt, um eine Stufe angehoben – etwa von A auf A+, von B auf B+ usw. Liegt die Anwesenheitsquote hingegen unter 95 %, erfolgt die Benotung ausschließlich auf Grundlage der ursprünglichen, punktebasierten Kriterien. In solchen Fällen verwenden Sie eine verschachtelte WENN-Anweisung mit einer UND-Bedingung.

Wählen Sie eine leere Zelle (hier: D2), geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um das Ergebnis zu erhalten. Ziehen Sie anschließend das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Ein Screenshot, der verschachtelte WENN-Funktionen mit der UND-Bedingung für die Notenvergabe in Excel zeigt

Hinweise: Hier ist eine Erläuterung, wie diese Formel funktioniert:
  1. UND-Bedingungsprüfung:
    AND(B2>=60, C2>=95 %): Die UND-Bedingung prüft zunächst, ob beide Bedingungen erfüllt sind – die Punktzahl des Schülers beträgt mindestens 60 und seine Anwesenheitsquote liegt bei mindestens 95 %.
  2. New grade assignment:
    WENN(B2>=[[PH_131]], „A+", IF(B2>=[[PH_130]], „B+", IF(B2>=[[PH_129]], "C+", „D+"))): Wenn beide Bedingungen in der UND-Anweisung wahr sind, prüft die Formel anschließend die Punktzahl des Schülers und hebt seine Note um eine Stufe an.
    • B2>=90: Bei einem Wert von 90 oder höher lautet die Note „A +“. Neue Notenvergabe:
    • B2>=80: Bei einem Wert von 80 oder höher (jedoch unter 90) lautet die Note „B +“.
    • B2>=70: Bei einem Wert von 70 oder höher (jedoch unter 80) lautet die Note „C+“.
    • B2>=60: Bei einem Wert von 60 oder höher (jedoch unter 70) erhalten Sie die Note „D+“.
  3. Regular Grade Assignment:
    WENN(B2>=[[PH_146]], „A", IF(B2>=[[PH_145]], „B", IF(B2>=[[PH_144]], „C", IF(B2>=[[PH_143]], "D", „F")))): Wenn die UND-Bedingung nicht erfüllt ist (entweder liegt die Punktzahl unter 80 oder die Anwesenheit unter 95 %), weist die Formel Standardnoten zu.
    • B2>=90: Ein Wert von 90 oder höher erhält die Note „A“.
    • B2>=80: Ein Wert von 80 oder höher (jedoch unter 90) erhält die Note „B“.
    • B2>=70: Ein Wert von 70 oder höher (jedoch unter 80) erhält die Note „C“.
    • B2>=60: Ein Wert von 60 oder höher (jedoch unter 70) erhält die Note „D“.
    • Werte unter 60 erhalten die Note „F“.
Verwendung verschachtelter WENN-Funktionen mit einer ODER-Bedingung

In diesem Fall wird die Note eines Schülers um eine Stufe angehoben, wenn seine Punktzahl mindestens 95 beträgt oder seine Anwesenheitsquote bei 95 % oder mehr liegt. So setzen Sie dies mithilfe verschachtelter WENN- und ODER-Bedingungen um:

Wählen Sie eine leere Zelle (hier: D2), geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um das Ergebnis zu erhalten. Ziehen Sie anschließend das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Ein Screenshot, der verschachtelte WENN-Funktionen mit der ODER-Bedingung für die Notenvergabe in Excel zeigt

Hinweise: Hier ist eine Aufschlüsselung, wie die Formel funktioniert:
  1. ODER-Bedingungsprüfung:
    OR(B2>=95, C2>=95 %): Die Formel prüft zunächst, ob mindestens eine der beiden Bedingungen wahr ist – entweder die Punktzahl des Schülers beträgt mindestens 95 oder seine Anwesenheitsquote liegt bei mindestens 95 %.
  2. Grade Assignment with Bonus:
    WENN(B2>=[[PH_168]], „A+", IF(B2>=[[PH_167]], „B+", IF(B2>=[[PH_166]], „C+", IF(B2>=[[PH_165]], "D+", „F+")))): Wenn mindestens eine der ODER-Bedingungen wahr ist, wird die Note des Schülers um eine Stufe erhöht.
    • B2>=90: Bei einem Wert von 90 oder höher lautet die Note „A+“.
    • B2>=80: Bei einem Wert von 80 oder höher (jedoch unter 90) lautet die Note „B+“.
    • B2>=70: Bei einem Wert von 70 oder höher (jedoch unter 80) lautet die Note „C+“.
    • B2>=60: Bei einem Wert von 60 oder höher (jedoch unter 70) lautet die Note „D+“.
    • Andernfalls wird die Note „F+“ vergeben.
  3. Regular Grade Assignment:
    WENN(B2>=[[PH_182]], „B", IF(B2>=[[PH_181]], „C", IF(B2>=[[PH_180]], "D", „F")))): Wenn keine der ODER-Bedingungen erfüllt ist (die Punktzahl liegt unter 95 und die Anwesenheit unter 95 %), weist die Formel Standardnoten zu.
    • B2>=90: Ein Wert von 90 oder höher erhält die Note „A“.
    • B2>=80: Ein Wert von 80 oder höher (jedoch unter 90) erhält die Note „B“.
    • B2>=70: Ein Wert von 70 oder höher (jedoch unter 80) erhält die Note „C“.
    • B2>=60: Ein Wert von 60 oder höher (jedoch unter 70) erhält die Note „D“.
    • Werte unter 60 erhalten die Note „F“.

Tipps und Tricks für verschachteltes WENN

Dieser Abschnitt bietet vier praktische Tipps und Tricks für den Einsatz verschachtelter WENN-Funktionen.

Verschachteltes WENN leicht lesbar gestalten

Eine typische verschachtelte WENN-Anweisung mag zwar kompakt wirken, ist jedoch oft schwer lesbar.

In der folgenden Formel ist es auf den ersten Blick schwer zu erkennen, wo eine Bedingung endet und die nächste beginnt – besonders, wenn die Komplexität zunimmt.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
Lösung: Zeilenumbrüche und Einrückungen hinzufügen

Um verschachtelte WENN-Formeln besser lesbar zu machen, können Sie die Formel über mehrere Zeilen verteilen, sodass jede verschachtelte WENN-Funktion in einer eigenen Zeile steht. Platzieren Sie dazu den Cursor in der Formel direkt vor dem „WENN“ und drücken Sie Alt + Enter.

Nach dem Umbruch der obigen Formel wird diese wie folgt dargestellt:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Diese Darstellung zeigt klar, wo sich jede Bedingung und ihre zugehörige Ausgabe befinden – und steigert so die Lesbarkeit der Formel erheblich.

Reihenfolge der verschachtelten WENN-Funktionen

Die Reihenfolge der logischen Bedingungen in einer verschachtelten WENN-Formel ist entscheidend, denn sie legt fest, wie Excel die Bedingungen auswertet – und beeinflusst so direkt das Endergebnis der Formel.

Korrekte Formel

Im Beispiel „Notensystem“ verwenden wir die folgende Formel, um Noten anhand der erreichten Punktzahlen zuzuordnen.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Ein Screenshot, der die korrekte Reihenfolge der Bedingungen in einer verschachtelten WENN-Formel für die Notenvergabe anzeigt

Excel wertet die Bedingungen in einer verschachtelten WENN-Formel nacheinander aus – beginnend mit der ersten und endend mit der letzten. Dabei prüft die Formel zunächst die höchste Punkteschwelle (≥90 für eine „A“-Note) und arbeitet sich anschließend zu den niedrigeren Schwellen vor. So wird sichergestellt, dass jede Punktzahl stets mit der bestmöglichen Note verglichen wird, für die sie qualifiziert ist. Sobald die erste Bedingung zutrifft (A2 ≥ 90), gibt die Formel „A“ zurück und bricht die weitere Auswertung ab.

Falsch geordnete Formel

Würde die Reihenfolge der Bedingungen umgekehrt und mit der niedrigsten Schwelle begonnen, käme es zu falschen Ergebnissen.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

Ein Screenshot, der eine falsche Reihenfolge in einer verschachtelten WENN-Formel veranschaulicht

In dieser fehlerhaften Formel würde eine Punktzahl von 95 bereits die erste Bedingung B2>=60 erfüllen und fälschlicherweise die Note „D“ erhalten.

Zahlen und Text müssen unterschiedlich behandelt werden

Dieser Abschnitt zeigt, wie Zahlen und Text in verschachtelten WENN-Anweisungen unterschiedlich verarbeitet werden.

Zahlen

Zahlen kommen bei arithmetischen Vergleichen und Berechnungen zum Einsatz. In verschachtelten WENN-Anweisungen können Sie Zahlen direkt mit Operatoren wie >, = und <= vergleichen.

Text

In verschachtelten WENN-Anweisungen muss Text in doppelte Anführungszeichen gesetzt werden – siehe dazu die Beispiele A, B, C, D und F in der folgenden Formel:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Einschränkungen von verschachteltem WENN

Dieser Abschnitt nennt mehrere Einschränkungen und Nachteile verschachtelter WENN-Funktionen.

Komplexität und Lesbarkeit:

Obwohl Excel bis zu 64 WENN-Funktionen verschachteln kann, ist das keineswegs empfehlenswert: Je tiefer die Verschachtelung, desto komplexer wird die Formel – und umso schwerer lesbar, verständlich und wartbar ist sie.

Fehleranfälligkeit:

Darüber hinaus sind komplexe, verschachtelte WENN-Anweisungen fehleranfällig und lassen sich nur schwer debuggen oder anpassen.

Schwierige Erweiterbarkeit oder Skalierbarkeit:

Bei Änderungen der Logik oder beim Hinzufügen weiterer Bedingungen sind stark verschachtelte WENN-Funktionen nur schwer zu modifizieren oder zu erweitern.

Ein klares Verständnis dieser Einschränkungen ist entscheidend, um verschachtelte WENN-Anweisungen in Excel effektiv einzusetzen. Oft führen die Kombination mit anderen Funktionen oder der Einsatz alternativer Ansätze zu effizienteren und besser wartbaren Lösungen.

Alternativen zu verschachteltem WENN

Dieser Abschnitt stellt mehrere Excel-Funktionen vor, die Sie als Alternative zu verschachtelten WENN-Anweisungen nutzen können.

Verwendung von VLOOKUP

Sie können die SVERWEIS-Funktion statt verschachtelter WENN-Anweisungen nutzen, um die beiden oben genannten Praxisbeispiele zu lösen – und so geht’s:

Beispiel 1: Notensystem mit SVERWEIS

Hier zeige ich Ihnen, wie Sie mit SVERWEIS Noten basierend auf Punktzahlen zuweisen können.

Schritt 1: Erstellen einer Nachschlagetabelle für Noten

Erstellen Sie zunächst eine Nachschlagetabelle (beispielsweise E1:F6) für die Punktebereiche und die entsprechenden Noten.Hinweis:Die Punktzahlen in der ersten Spalte der Tabelle müssen in aufsteigender Reihenfolge sortiert sein.

Ein Screenshot, der eine Nachschlagetabelle für Noten zur Verwendung mit SVERWEIS in Excel zeigt

Schritt 2: Anwenden der SVERWEIS-Funktion zur Notenvergabe

Wählen Sie eine leere Zelle (hier: C2), geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um die erste Note zu erhalten. Markieren Sie anschließend die Formelzelle und ziehen Sie das Ausfüllkästchen nach unten, um die übrigen Noten zu generieren.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Ein Screenshot, der die Verwendung von SVERWEIS für die Notenvergabe in Excel demonstriert

Hinweise:
  • Der Wert 95 in Zelle B2 ist der Suchwert, nach dem VLOOKUP in der ersten Spalte der Nachschlagetabelle ($E$2:$F$6) sucht. Wird er gefunden, gibt die Funktion die zugehörige Note aus der zweiten Spalte derselben Zeile zurück.
  • Denken Sie daran, den Bezug auf die Nachschlagetabelle absolut zu setzen (indem Sie Dollarzeichen ($) vor die Bezüge einfügen), damit sich der Bezug beim Kopieren der Formel in eine andere Zelle nicht ändert.
  • Weitere Informationen zur VLOOKUP-Funktion finden Sie auf dieser Seite.
Beispiel 2: Berechnung der Verkaufsprovision mit SVERWEIS

Sie können SVERWEIS auch zur Berechnung der Verkaufsprovision in Excel nutzen – so geht’s:

Schritt 1: Erstellen Sie eine Nachschlagetabelle für Noten

Erstellen Sie zunächst eine Nachschlagetabelle für Umsätze und die entsprechenden Provisionssätze, beispielsweise E2:F4. Hinweis: Die Umsätze in der ersten Spalte der Tabelle müssen in aufsteigender Reihenfolge sortiert sein.

Ein Screenshot, der eine Nachschlagetabelle für Verkaufsprovisionsraten zur Verwendung mit SVERWEIS in Excel zeigt

Schritt 2: Wenden Sie die VLOOKUP-Funktion zur Zuordnung der Noten an

Wählen Sie eine leere Zelle (in diesem Fall C2) aus, geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um die erste Provision zu berechnen. Markieren Sie anschließend die Formelzelle und ziehen Sie das Ausfüllkästchen nach unten, um die übrigen Ergebnisse automatisch zu generieren.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Ein Screenshot, der die Verwendung von SVERWEIS für die Berechnung der Verkaufsprovision in Excel demonstriert

Hinweise:
  • In beiden Beispielen wird VLOOKUP genutzt, um anhand eines Suchwerts – etwa einer Punktzahl oder eines Umsatzes – in einer Tabelle nachzuschlagen und den zugehörigen Wert aus einer festgelegten Spalte (beispielsweise Note oder Provisionsrate) derselben Zeile zurückzugeben. Der vierte Parameter „WAHR“ aktiviert die ungefähre Übereinstimmung, was für diese Szenarien ideal ist, da der exakte Suchwert möglicherweise nicht in der Tabelle enthalten ist.
  • Weitere Informationen zur VLOOKUP-Funktion finden Sie auf dieser Seite.

Verwendung von WENNS

Die IFS-Funktion vereinfacht den Prozess, indem sie das Verschachteln überflüssig macht und Formeln so lesbarer und leichter verwaltbar gestaltet. Sie erhöht die Übersichtlichkeit und erleichtert die Handhabung mehrerer bedingter Prüfungen. Um die IFS-Funktion nutzen zu können, stellen Sie sicher, dass Sie Excel 2019 oder eine neuere Version verwenden oder über ein Office-365-Abonnement verfügen. Sehen wir uns an, wie sie sich in praktischen Beispielen einsetzen lässt.

Beispiel 1: Notensystem mit IFS

Unter der Annahme derselben Notenbewertungskriterien wie zuvor kann die IFS-Funktion wie folgt verwendet werden:

Wählen Sie eine leere Zelle wie C2 aus, geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um das erste Ergebnis zu erhalten. Markieren Sie diese Ergebniszelle und ziehen Sie ihr Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Ein Screenshot, der die Verwendung der WENNS-Funktion für die Notenvergabe in Excel zeigt

Hinweise:
  • Jede Bedingung wird nacheinander geprüft. Sobald eine Bedingung erfüllt ist, wird das zugehörige Ergebnis zurückgegeben und die Prüfung weiterer Bedingungen abgebrochen. In diesem Fall weist die Formel basierend auf dem Wert in B2 Noten gemäß einer üblichen Notenskala zu, bei der eine höhere Punktzahl einer besseren Note entspricht.
  • Weitere Informationen zur WENNS-Funktion finden Sie auf dieser Seite.
Beispiel 2: Berechnung der Verkaufsprovision mit IFS

Für das Szenario der Berechnung der Verkaufsprovision wird die IFS-Funktion wie folgt angewendet:

Wählen Sie eine leere Zelle wie C2 aus, geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um das erste Ergebnis zu erhalten. Markieren Sie diese Ergebniszelle und ziehen Sie das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Ein Screenshot, der die Verwendung der WENNS-Funktion für die Berechnung der Verkaufsprovision in Excel zeigt

Verwendung von WAHL und VERGLEICH

Der Ansatz mit CHOOSE und MATCH ist oft effizienter und einfacher zu verwalten als verschachtelte WENN-Anweisungen. Diese Methode vereinfacht die Formel und macht Aktualisierungen oder Anpassungen unkomplizierter. Im Folgenden zeige ich, wie Sie die Funktionen CHOOSE und MATCH für die beiden praktischen Beispiele in diesem Artikel kombinieren können.

Beispiel 1: Notensystem mit CHOOSE und MATCH

Kombinieren Sie die Funktionen CHOOSE und MATCH, um Noten automatisch basierend auf verschiedenen Punktzahlen zuzuordnen.

Schritt 1: Erstellen Sie ein Sucharray mit Suchwert

Erstellen Sie zunächst einen Zellbereich, der die Schwellenwerte enthält, nach denen MATCH sucht, beispielsweise $E$2:$E$6 in diesem Fall.Hinweis:Die Zahlen in diesem Bereich müssen in aufsteigender Reihenfolge sortiert sein, damit die MATCH-Funktion bei Verwendung eines ungefähren Übereinstimmungstyps korrekt funktioniert.

Ein Screenshot, der ein Nachschlage-Array für Noten mithilfe von WAHL und VERGLEICH in Excel zeigt

Schritt 2: Verwenden Sie CHOOSE und MATCH zur Zuordnung der Noten

Wählen Sie eine leere Zelle (hier: C2) aus, geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um die erste Note zu erhalten. Markieren Sie anschließend diese Formelzelle und ziehen Sie das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Ein Screenshot, der WAHL und VERGLEICH für die Notenvergabe in Excel demonstriert

Hinweise:
  • MATCH(B2, $E$2:$E$6, 1)Dieser Teil der Formel sucht die Punktzahl (95) aus Zelle B2 im Bereich $E$2:$E$6. Die 1 gibt an, dass VERGLEICH eine ungefähre Übereinstimmung finden soll – das heißt, es wird der größte Wert im Bereich gesucht, der kleiner als oder gleich dem Wert in B2 ist.
  • CHOOSE(..., "F", "D", "C", "B", „A")Basierend auf der von der VERGLEICH-Funktion zurückgegebenen Position wählt die WAHL-Funktion die entsprechende Note aus.
  • Weitere Informationen zur VERGLEICH-Funktion finden Sie auf dieser Seite.
  • Weitere Informationen zur WAHL-Funktion finden Sie auf dieser Seite.
Beispiel 2: Berechnung der Verkaufsprovision mit IFS

Die Kombination aus CHOOSE und MATCH eignet sich ebenfalls hervorragend zur Berechnung der Verkaufsprovision – besonders dann, wenn die Provisionsraten auf festgelegten Umsatzschwellen basieren. Sehen wir uns an, wie sich das umsetzen lässt.

Schritt 1: Erstellen Sie ein Sucharray mit Suchwert

Erstellen Sie zunächst einen Zellbereich, der die Schwellenwerte enthält, nach denen MATCH sucht, beispielsweise $E$2:$E$4 in diesem Fall.Hinweis:Die Zahlen in diesem Bereich müssen in aufsteigender Reihenfolge sortiert sein, damit die MATCH-Funktion bei Verwendung eines ungefähren Übereinstimmungstyps korrekt funktioniert.

Ein Screenshot, der ein Nachschlage-Array für Verkaufsprovisionsraten mithilfe von WAHL und VERGLEICH in Excel zeigt

Schritt 2: Verwenden Sie CHOOSE und MATCH, um die Ergebnisse zu erhalten

Wählen Sie eine leere Zelle (hier: C2) aus, geben Sie die folgende Formel ein und drücken Sie die Eingabetaste, um die erste Note zu erhalten. Markieren Sie anschließend diese Formelzelle und ziehen Sie das Ausfüllkästchen nach unten, um die übrigen Ergebnisse zu generieren.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Ein Screenshot, der WAHL und VERGLEICH für die Berechnung der Verkaufsprovision in Excel demonstriert

Hinweise:

Zusammenfassend ist die Beherrschung verschachtelter WENN-Anweisungen in Excel eine wertvolle Fähigkeit, die Ihnen hilft, komplexe logische Szenarien in der Datenanalyse und bei Entscheidungsprozessen souverän zu meistern. Zwar sind verschachtelte WENN-Funktionen für anspruchsvolle logische Operationen äußerst leistungsstark – doch sollten Sie ihre Grenzen stets im Blick behalten. In vielen Fällen bieten einfachere Alternativen wie VLOOKUP, IFS oder auch CHOOSE in Kombination mit MATCH deutlich schlankere und übersichtlichere Lösungen. Mit diesem Wissen können Sie ab sofort gezielt die passendsten Excel-Techniken für Ihre Datenanalyse-Aufgaben auswählen und so mehr Klarheit, Genauigkeit und Effizienz in Ihre Tabellenkalkulationen bringen. Für alle, die noch tiefer in die Möglichkeiten von Excel eintauchen möchten, hält unsere Website eine Fülle praktischer Anleitungen bereit.Entdecken Sie hier weitere Excel-Tipps und -Tricks.

Die besten Office-Produktivitätswerkzeuge

🤖KUTOOLS AI Assistent: Revolutionieren Sie Datenanalyse basierend auf:Intelligente Ausführung   |  Code generieren|  benutzerdefinierte Formeln erstellen  |  Daten analysieren und Diagramme erstellen|  Erweiterte Funktionen aufrufen…
Beliebte Funktionen:Suchen, Hervorheben oder Doppelte markieren   |  Leere Zeilen löschen   |  Spalten kombinieren oder Zellen ohne Datenverlust   |   Runden ohne Formel...
Erweiterte SVERWEIS:Mehrfachkriterien-SVERWEIS  |  Mehrfachwert-SVERWEIS  |   SVERWEIS über mehrere Arbeitsblätter hinweg   |   Fuzzy Match....
Erweiterte Dropdown-Liste:Schnell eine Dropdown-Liste erstellen   |  Abhängige Dropdown-Liste   |  Mehrfachauswahl-Dropdown-Liste....
Spalten-Manager:Bestimmte Anzahl an Spalten hinzufügen|Spalten verschieben|Sichtbarkeitsstatus ausgeblendeter Spalten umschalten|Bereiche & Spalten vergleichen...
Hervorgehobene Funktionen:Gitterfokus   |  Entwurf   |Erweiterte Formelleiste   | Arbeitsmappe- und Blatt-Manager   |  Ressourcenbibliothek(AutoText)|  Datumsauswahl   |  Arbeitsblätter konsolidieren  |  Verschlüsseln/Zellen entschlüsseln   | E-Mails per Liste versenden   |  Super Filter   |   Spezialfilter(Zellen mit fettgedruckter Schrift filtern/Kursiv/Durchgestrichen...) ...
Top-15-Toolsets:12 Text-Tools(Text hinzufügen,Bestimmte Zeichen löschen, ...)|   50+Diagramm-Typen(Gantt-Diagramm, ...)|   40+ Praktische Formeln(Alter basierend auf dem Geburtstag berechnen, ...)|   19 Einfüge-Tools(QR-Code einfügen,Bild aus Pfad einfügen, ...)|   12 Konvertierungs-Tools(In Wörter umwandeln,Wechselkursumrechnung, ...)|   7 Vereinigen/Aufteilen-Tools(Erweiterte Zeilen zusammenführen,Zellen aufteilen, ...)|... und mehr
Verwenden Sie Kutools in Ihrer bevorzugten Sprache – unterstützt Englisch, Spanisch, Deutsch, Französisch, Chinesisch und 40+ weitere Sprachen!

Verleihen Sie Ihren Excel-Kenntnissen mit Kutools für Excel neuen Schwung und erleben Sie Effizienz wie nie zuvor.Kutools für Excel bietet über 300 erweiterte Funktionen zur Steigerung der Produktivität und Zeit sparen.Klicken Sie hier, um die Funktion zu erhalten, die Sie am dringendsten benötigen...

Office Tab Bringt eine tabbasierte Benutzeroberfläche in Office und erleichtert Ihre Arbeit erheblich

  • Aktivieren Sie die tabbasierte Bearbeitung und Lektüre in Word, Excel, PowerPoint, Publisher, Access, Visio und Project.
  • Öffnen und erstellen Sie mehrere Dokumente in neuen Registerkarten ein und desselben Fensters – statt in separaten Fenstern.
  • Steigert Ihre Produktivität um 50 % und erspart Ihnen täglich Hunderte von Mausklicks!

Alle Kutools-Add-Ins – ein Installationsprogramm

Kutools for Office Das Paket bündelt Add-Ins für Excel, Word, Outlook & PowerPoint sowie Office Tab Pro – ideal für Teams, die übergreifend mit Office-Anwendungen arbeiten.

ExcelWordOutlookTabsPowerPoint
  • Alles-in-einem-Paket— Add-Ins für Excel, Word, Outlook & PowerPoint + Office Tab Pro
  • Ein Installationsprogramm, eine Lizenz— Einrichtung in wenigen Minuten (MSI-fähig)
  • Besser zusammen— optimierte Produktivität über alle Office-Anwendungen hinweg
  • 30-tägige Testversion mit vollem Funktionsumfang— keine Registrierung, keine Kreditkarte erforderlich
  • Bestes Preis-Leistungs-Verhältnis— sparen Sie gegenüber dem Kauf einzelner Add-Ins