Wie deaktivieren Sie die Warnung bei fehlendem Betreff in Outlook?

Wenn Sie Outlook 2010 und 2013 verwenden und E-Mail-Nachrichten ohne Betreff versenden, erscheint jedes Mal ein Hinweisfenster, das Sie daran erinnert. Falls Sie den Betreff wirklich nicht ausfüllen möchten, kann diese Warnung eine große Störung für Sie darstellen. Um Outlook-Nutzern dabei zu helfen, diese Warnung loszuwerden, stellen wir im folgenden Tutorial eine Methode vor.

Warnung bei fehlendem Betreff in Outlook deaktivieren

---

Warnung bei fehlendem Betreff in Outlook deaktivieren

In Outlook 2007 erhalten Sie keine Warnung, wenn Sie eine E-Mail ohne Betreff versenden – diese Funktion ist erst in Outlook 2010 und 2013 standardmäßig aktiviert. Allerdings gibt es keine integrierte Option, um die Warnung direkt zu deaktivieren. In diesem Tutorial zeigen wir Ihnen einen VBA-Code, mit dem Sie dies dennoch erreichen können.

1. Drücken Sie „Alt“ + „F11“, um das Dialogfeld „Microsoft Visual Basic for Applications“ zu öffnen.

2. Erweitern Sie „Project1“ > „Microsoft Outlook-Objekte“, indem Sie doppelt darauf klicken, und öffnen Sie anschließend durch Doppelklick auf „ThisOutlookSession“ das Fenster „VbaProject.OTM“.

3. Kopieren Sie den folgenden VBA-Code und fügen Sie ihn in das Fenster ein.

VBA: Warnung bei fehlendem Betreff deaktivieren

Option Explicit
Private WithEvents oInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set oInspectors = Outlook.Inspectors
End Sub

Private Sub oInspectors_NewInspector(ByVal Inspector As Inspector)
    Dim oItem As Object
    On Error GoTo ExitProc
    Set oItem = Inspector.CurrentItem
    If oItem.Sent = False Then
        If oItem.Subject = "" Then oItem.Subject = " "
    End If
ExitProc:
    Set oItem = Nothing
    Set Inspector = Nothing
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    On Error Resume Next
    Item.Subject = Trim(Item.Subject)
End Sub

Private Sub Application_Quit()
    Set oInspectors = Nothing
End Sub

4. Klicken Sie auf die Schaltfläche „Speichern“, um Ihren VBA-Code sicher zu speichern.

5. Starten Sie die Outlook-Anwendung neu.

Danach wird der VBA-Code aktiv: Wenn Sie eine Nachricht ohne Betreff versenden, erscheint das Warnfenster nicht mehr.

Hinweis: Stellen Sie sicher, dass die Option „Alle Makros aktivieren“ ausgewählt ist. (Überprüfen Sie dies, indem Sie nacheinander auf „Datei“ > „Optionen“ > „Vertrauensstellungscenter“ > „Vertrauensstellungscenter-Einstellungen“ klicken und im Dialogfeld „Vertrauensstellungscenter“ unter „Makroeinstellungen“ die Option „Alle Makros aktivieren“ aktivieren.) Siehe Screenshot: