Wie erhält man eine Liste der Ordner in Outlook?

Manchmal erleichtert die Baumstruktur aller E-Mail-Ordner – einschließlich der von Ihnen erstellten persönlichen Ordner – die Arbeit in Outlook. Um schnell eine vollständige Übersicht über diese Ordnerstruktur zu erhalten, hilft Ihnen ein VBA-Code weiter. In diesem Tutorial zeigen wir Ihnen, wie Sie mithilfe eines einfachen VBA-Codes eine Liste aller Ordner erstellen.

Liste der Ordner in Outlook mit VBA-Code erhalten

---

Liste der Ordner in Outlook mit VBA-Code erhalten

Führen Sie die folgenden Schritte aus, um mithilfe eines VBA-Codes eine Liste der Ordner in Outlook zu erhalten.

1. Drücken Sie auf Ihrer Tastatur gleichzeitig „Alt“ + „F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

2. Doppelklicken Sie anschließend auf „Project1“ > „Microsoft Outlook-Objekt“ > „ThisOutlookSession“, um das Fenster „Project1 – ThisOutlookSession“ zu öffnen. Siehe Screenshot:

3. Kopieren Sie anschließend den folgenden VBA-Code und fügen Sie ihn in das Fenster „Project1 – ThisOutlookSession“ ein.

VBA: Liste der Ordner in Outlook erhalten

Option Explicit
Sub GetFoldersList()
    On Error GoTo On_Error
    
    Dim Report As String
    Dim Folder As Outlook.Folder
       
    For Each Folder In Application.Session.Folders
        Report = Report & "---------------------------------------------------------------------------" & vbCrLf
        Call RecurseFolders(Folder, "", Report)
    Next
    Call CreateReportEmail("Outlook Folders List", Report)
    
Exiting:
    Exit Sub
On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
End Sub
Sub RecurseFolders(CurrentFolder As Outlook.Folder, TabChars, ByRef Report As String)
    Dim SubFolder As Outlook.Folder
    Dim FolderName, StoreName As String
    
    FolderName = CurrentFolder.Name
    StoreName = CurrentFolder.Store.DisplayName
    
    Report = Report & TabChars & FolderName & " (Store: " & StoreName & ")" & vbCrLf
    
    For Each SubFolder In CurrentFolder.Folders
        Call RecurseFolders(SubFolder, TabChars & vbTab, Report)
    Next SubFolder
End Sub
Sub CreateReportEmail(Title As String, Report As String)
    Dim aMail As MailItem
    
    Set aMail = Application.CreateItem(olMailItem)
        
    aMail.Subject = Title
    aMail.Body = Report
    
    aMail.Display
End Sub

4. Drücken Sie auf Ihrer Tastatur die Taste „F5“, um den VBA-Code auszuführen.

5. Es erscheint nun das Dialogfeld „Makro“. Klicken Sie auf „Ausführen“.

6. Warten Sie, bis das Makro ausgeführt wurde – danach wird die Liste aller Ihrer E-Mail-Ordner sofort in einem neu erstellten Nachrichtenfenster angezeigt und lässt sich problemlos ausdrucken. Siehe Screenshot:

Hinweis: Dieser VBA-Code funktioniert in Outlook 2007, 2010 und 2013.