Wie exportiert und druckt man eine Liste aller Ordner und Unterordner in Outlook?

Im Allgemeinen können Sie mit der Tastenkombination „Strg“ + „6“ die vollständige Ordnerliste im Navigationsbereich von Outlook anzeigen. Allerdings lässt sich diese Ordnerliste nicht direkt drucken. In diesem Artikel stellen wir Ihnen zwei VBA-Skripte vor, mit denen Sie alle Ordner samt deren Unterordnern aus Outlook exportieren und anschließend drucken können.

• Exportieren und drucken Sie die Liste aller Outlook-Ordner und deren Unterordner in Neue Email
• Exportieren und drucken Sie die Liste aller Outlook-Ordner und deren Unterordner in Notepad

---

Exportieren und drucken Sie die Liste aller Outlook-Ordner und deren Unterordner in Neue Email

Diese Methode stellt ein VBA-Skript vor, das die Liste aller Ordner und deren Unterordner eines bestimmten E-Mail-Kontos in eine neue E-Mail in Outlook exportiert – so können Sie die Ordnerliste mühelos drucken.

1. Drücken Sie „Alt“ + „F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

2. Klicken Sie auf „Einfügen“ > „Modul“ und fügen Sie den folgenden VBA-Code in das neu geöffnete Modulfenster ein.

VBA: Exportieren der Liste von Ordnern und Unterordnern in einem Neue Email in Outlook

Public gFolders As String

Public Sub GetFolderNames()
Dim oSession As Outlook.NameSpace
Dim oFolder As Outlook.MAPIFolder
Dim oNewMail As Outlook.MailItem

Set oSession = Outlook.Application.GetNamespace("MAPI")
Set oFolder = oSession.PickFolder

If (oFolder Is Nothing) Then Exit Sub

ProcessFolder oFolder

Set oNewMail = Application.CreateItem(olMailItem)
oNewMail.Body = gFolders
oNewMail.Display

gFolders = ""
End Sub

Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
Dim i As Long
Dim oSubFolder As Outlook.MAPIFolder
Dim oFolder As Outlook.MAPIFolder
Dim sFolderPaths As String

For i = CurrentFolder.Folders.Count To 1 Step -1
    Set oFolder = CurrentFolder.Folders(i)
    sFolderPaths = oFolder.FolderPath
    gFolders = gFolders & vbCrLf & sFolderPaths & " " & oFolder.Items.Count
Next

For Each oSubFolder In CurrentFolder.Folders
    If oSubFolder.Name <> "Deleted Items" Then
        ProcessFolder oSubFolder
    End If
Next
End Sub

3. Drücken Sie „F5“, um das VBA-Skript auszuführen.

4. Wählen Sie im erscheinenden Dialogfeld „Ordner auswählen“ das E-Mail-Konto aus, dessen Ordnerliste Sie drucken möchten, und klicken Sie auf „OK“.

5. Die Ordnerliste des ausgewählten Kontos wird wie unten dargestellt in eine neue E-Mail kopiert. Klicken Sie auf „Datei“ > „Drucken“, um die Ordnerliste auszudrucken.

6. Schließen Sie die neue E-Mail nach dem Drucken ohne Speichern.

---

Exportieren und drucken Sie die Liste aller Outlook-Ordner und deren Unterordner in Notepad

Diese Methode stellt ein VBA-Skript vor, das die Liste aller Ordner und deren Unterordner eines bestimmten E-Mail-Kontos aus Outlook direkt in Notepad exportiert – so können Sie Ihre Ordnerstruktur im Handumdrehen drucken.

1. Drücken Sie „Alt“ + „F11“, um das Microsoft Visual Basic for Applications-Fenster zu öffnen.

2. Klicken Sie auf „Einfügen“ > „Modul“ und fügen Sie anschließend den folgenden VBA-Code in das neue Modulfenster ein.

VBA: Exportieren der Liste aller Outlook-Ordner und Unterordner aus Outlook in Notepad

Dim gFileName, gCreateTree, gBase

Public Sub ExportFolderTree()
Dim objOutlook
Dim F, Folders
Dim Result

Set objOutlook = CreateObject("Outlook.Application")
Set F = objOutlook.Session.PickFolder

If Not F Is Nothing Then
    Set Folders = F.Folders
    Result = MsgBox("Do you want to create tree?", vbYesNo + vbDefaultButton2 + vbApplicationModal, "Output Folder Tree")
    If Result = 6 Then
        gCreateTree = True
    Else
        gCreateTree = False
    End If

    gFileName = GetDesktopFolder() & "\Outlook-Folders.txt"
    gBase = Len(F.FolderPath) - Len(Replace(F.FolderPath, "\", "")) + 1

    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders Folders

    Set F = Nothing
    Set Folders = Nothing
    Set objOutlook = Nothing
End If
End Sub

Private Function GetDesktopFolder()
Dim objShell
Set objShell = CreateObject("WScript.Shell")
GetDesktopFolder = objShell.SpecialFolders("Desktop")
Set objShell = Nothing
End Function

Private Sub LoopFolders(Folders)
Dim F
For Each F In Folders
    WriteToATextFile (CreateFolderTree(F.FolderPath, F.Name))
    LoopFolders F.Folders
Next
End Sub

Private Sub WriteToATextFile(OLKfoldername)
Dim objFSO, objTextFile
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.OpenTextFile(gFileName, 8, True)
objTextFile.WriteLine (OLKfoldername)
objTextFile.Close
Set objFSO = Nothing
Set objTextFile = Nothing
End Sub

Private Function CreateFolderTree(OLKfolderpath, OLKfoldername)
If gCreateTree = False Then
    CreateFolderTree = Mid(OLKfolderpath, 3)
Else
    Dim i, x, OLKprefix
    i = Len(OLKfolderpath) - Len(Replace(OLKfolderpath, "\", ""))
    For x = gBase To i
        OLKprefix = OLKprefix & "-"
    Next
    CreateFolderTree = OLKprefix & OLKfoldername
End If
End Function

3. Drücken Sie „F5“, um das VBA-Skript auszuführen. Wählen Sie im erscheinenden Dialogfeld „Ordner auswählen“ das gewünschte E-Mail-Konto aus, dessen Ordnerliste Sie exportieren und drucken möchten, und klicken Sie auf „OK“.

4. Das Dialogfeld „Ausgabe-Ordnerstruktur“ wird angezeigt. Klicken Sie auf „Ja“, wenn Sie die Struktur mit Einrückungen anzeigen möchten, oder auf „Nein“, wenn nicht.

Nun wird eine Textdatei mit dem Namen „Outlook-Folders“ erstellt und wie unten gezeigt auf Ihrem Desktop gespeichert:

5. Doppelklicken Sie, um die neue Textdatei zu öffnen, und wählen Sie anschließend „Datei“ > „Drucken“, um die exportierte Liste Ihrer Outlook-Ordner auszudrucken.

Verwandte Artikel

Ordnerlistenansicht in Outlook ein- oder ausblenden