Wie sucht man in Outlook einen Ordner anhand seines Namens, um den vollständigen Dateipfad zu finden?

Führen Sie die folgenden Schritte aus, um mit VBA in Outlook nach Ordnern anhand ihres Namens zu suchen.

1. Drücken Sie gleichzeitig die Tasten „Alt“ + „F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

2. Klicken Sie auf „Einfügen“ > „Modul“ und fügen Sie den folgenden VBA-Code anschließend in das neue Modulfenster ein.

VBA: Suche und Ordner öffnen anhand von Ordnername in Outlook

Private m_Folder As MAPIFolder
Private m_Find As String
Private m_Wildcard As Boolean

Private Const SpeedUp As Boolean = True
Private Const StopAtFirstMatch As Boolean = True

Public Sub FindFolder()
Dim sName As String
Dim oFolders As Folders

  Set m_Folder = Nothing
m_Find = ""
m_Wildcard = False

  sName = InputBox("Find:", "Search folder")
If Len(Trim(sName)) = 0 Then Exit Sub
m_Find = sName

  m_Find = LCase(m_Find)
m_Find = Replace(m_Find, "%", "*")
m_Wildcard = (InStr(m_Find, "*"))

  Set oFolders = Application.Session.Folders
LoopFolders oFolders

  If Not m_Folder Is Nothing Then
If MsgBox("Activate folder: " & vbCrLf & m_Folder.FolderPath, vbQuestion Or vbYesNo) = vbYes Then
Set Application.ActiveExplorer.CurrentFolder = m_Folder
End If
Else
MsgBox "Not found", vbInformation
End If
End Sub

Private Sub LoopFolders(Folders As Outlook.Folders)
Dim oFolder As MAPIFolder
Dim bFound As Boolean

If SpeedUp = False Then DoEvents

  For Each oFolder In Folders
If m_Wildcard Then
bFound = (LCase(oFolder.Name) Like m_Find)
Else
bFound = (LCase(oFolder.Name) = m_Find)
End If

    If bFound Then
If StopAtFirstMatch = False Then
If MsgBox("Found: " & vbCrLf & oFolder.FolderPath & vbCrLf & vbCrLf & "Continue?", vbQuestion Or vbYesNo) = vbYes Then
bFound = False
End If
End If
End If
If bFound Then
Set m_Folder = oFolder
Exit For
Else
LoopFolders oFolder.Folders
If Not m_Folder Is Nothing Then Exit For
End If
Next
End Sub

3. Drücken Sie die Taste „F5“ oder klicken Sie auf die Schaltfläche „Ausführen“, um das VBA-Skript zu starten.

4. Geben Sie im erscheinenden Dialogfeld „Ordner suchen“ den gewünschten Ordnernamen ein, nach dem gesucht werden soll, und klicken Sie auf „OK“.

Hinweis: Dieses VBA unterstützt den Sternchen-Platzhalter (*). Geben Sie beispielsweise „tes*“ ein, um alle Ordner zu finden, deren Name mit „tes“ beginnt.

5. Es erscheint nun ein Dialogfeld mit dem Dateipfad des gefundenen Ordners. Möchten Sie den gefundenen Ordner öffnen, klicken Sie bitte auf „Ja“.

Der gefundene Ordner wird nun im Navigation geöffnet, wie im folgenden Screenshot dargestellt:

Hinweis: Sollten mehrere Ordner denselben angegebenen Namen tragen, findet und öffnet dieses VBA-Skript nur einen davon.

Wenn Sie „Kutools für Outlook“ installiert haben, nutzen Sie einfach die Funktion „Gehe zu“, um alle Ordner mit einem bestimmten Ordnernamen schnell zu finden und beliebige gefundene Ordner mühelos zu öffnen.

1. Klicken Sie auf „KUTOOLS PLUS“ > „Gehe zu“, um die Funktion zu aktivieren.

2. Geben Sie im Dialogfeld „Gehe zu“ den gewünschten Ordnernamen in das Feld „Suche“ ein, wählen Sie den Ordner aus den Suchergebnissen aus und klicken Sie auf „OK“.

Der angegebene Ordner wird nun sofort anhand des entsprechenden Ordnernamens gefunden und geöffnet.