Wie kopieren Sie die Outlook-Ordnerstruktur in den Windows-Explorer (Desktop)?

Wie Sie wissen, können Sie die Archivierungsfunktion nutzen, um die Ordnerstruktur in ein anderes Outlook-Profil zu kopieren. Doch wissen Sie auch, wie Sie die Outlook-Ordnerstruktur in einen bestimmten Windows-Ordner – etwa auf den Desktop – exportieren? In diesem Artikel stellen wir Ihnen ein VBA-Makro vor, mit dem Sie die Outlook-Ordnerstruktur mühelos in den Windows-Explorer übertragen können.

Outlook-Ordnerstruktur auf den Desktop (Windows-Explorer) kopieren

---

Outlook-Ordnerstruktur auf den Desktop (Windows-Explorer) kopieren

Führen Sie die folgenden Schritte aus, um die Outlook-Ordnerstruktur auf den Desktop oder in den Windows-Explorer zu kopieren.

1. Klicken Sie im Navigationsbereich auf den Ordner, dessen Struktur Sie kopieren möchten, um ihn hervorzuheben, und drücken Sie anschließend „Alt“ + „F11“, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf „Extras“ > „Verweise“, um das Dialogfeld „Verweise“ zu öffnen, aktivieren Sie dort die Option „Microsoft Scripting Runtime“ und bestätigen Sie mit „OK“. Siehe Screenshot:

3. Klicken Sie auf „Einfügen“ > „Modul“ und fügen Sie den folgenden VBA-Code in das neu geöffnete Modulfenster ein.

VBA: Outlook-Ordnerstruktur in den Windows-Explorer kopieren

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Drücken Sie die Taste „F5“ oder klicken Sie auf die Schaltfläche „Ausführen“, um das VBA-Makro zu starten.

5. Wählen Sie im erscheinenden Dialogfeld „Ordner durchsuchen“ den gewünschten Zielordner aus, in dem die kopierte Ordnerstruktur gespeichert werden soll, und klicken Sie auf „OK“. Siehe Screenshot:

Gehen Sie nun zum angegebenen Ordner. Dort erkennen Sie, dass die Ordnerstruktur auf die angegebene Festplatte kopiert wurde. Siehe Screenshot:

Hinweis: Ordnerelemente wie E-Mails, Termine, Aufgaben usw. werden ebenfalls in entsprechende Ordner auf der Festplatte kopiert.

---

Verwandte Artikel

Wie überträgt man die Ordnerstruktur in eine neue PST-Datei in Outlook?