Wie fügt man einer Outlook-Besprechungsanfrage automatisch eine Signatur hinzu?

In Outlook können Sie Ihre Signatur problemlos automatisch in E-Mails einfügen. Möchten Sie sie jedoch auch automatisch in Besprechungseinladungen verwenden, bietet Outlook hierfür keine direkte Funktion. In diesem Artikel stelle ich Ihnen einige nützliche Methoden vor, mit denen Sie Ihre Signatur automatisch in Outlook-Besprechungsanfragen einfügen können.

Automatisches Einfügen einer Signatur in Outlook-Besprechungsanfragen mithilfe eines benutzerdefinierten Formulars

Automatisches Einfügen einer Signatur in Outlook-Besprechungsanfragen mithilfe von VBA-Code

---

Automatisches Einfügen einer Signatur in Outlook-Besprechungsanfragen mithilfe eines benutzerdefinierten Formulars

In Outlook können Sie ein benutzerdefiniertes Formular erstellen, um Ihre Signatur automatisch in Besprechungsanfragen einzufügen. Gehen Sie dazu wie folgt vor:

1. Navigieren Sie zum Kalender-Fenster und klicken Sie auf Start > Besprechung, um das neue Besprechung-Fenster zu öffnen.

2.Klicken Sie anschließend auf Einfügen>Signaturund wählen Sie die gewünschte Signatur aus (siehe Screenshot):

3. Nachdem Sie die Signatur eingefügt haben, klicken Sie im neuen Entwickler-Dieses Formular entwerfen-Fenster auf Besprechung (siehe Screenshot):

4. Klicken Sie im neuen Fenster auf Entwickler > Veröffentlichen > Formular speichern unter (siehe Screenshot):

5.Geben Sie im erscheinenden Dialogfeld Formular speichern untereinen Namen in das Textfeld Anzeigenameein und klicken Sie dann auf die Schaltfläche Veröffentlichen(siehe Screenshot):

6. Schließen Sie danach das aktuelle Besprechungsfenster, ohne es zu speichern.

7. Ab sofort können Sie beim Erstellen einer Besprechung mit Signatur auf Start > Neue Elemente > Benutzerdefinierte Formulare klicken und das soeben erstellte Formular auswählen. Die Signatur wird dann automatisch in den Besprechungstext eingefügt (siehe Screenshot):

---

Automatisches Einfügen einer Signatur in Outlook-Besprechungsanfragen mithilfe von VBA-Code

Der folgende VBA-Code hilft Ihnen ebenfalls, automatisch eine Signatur in Besprechungsanfragen einzufügen. Gehen Sie dazu wie folgt vor:

1. Halten Sie die Tasten ALT + F11 gedrückt, um das Fenster Microsoft Visual Basic für Applikationen zu öffnen.

2. Doppelklicken Sie im Fenster Microsoft Visual Basic für Applikationen im Bereich ThisOutlookSession des Projekts Project1 (VbaProject.OTM), um das Modul zu öffnen, und fügen Sie anschließend den folgenden Code in das leere Modul ein.

VBA-Code: Automatisches Einfügen einer Signatur in Besprechungsanfragen:

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
Dim xMeetingItem As Outlook.MeetingItem
Dim xFSO As Scripting.FileSystemObject
Dim xSignStream, xWriteStream, xReadStream As Scripting.TextStream
Dim xSignFld, xSignSubFld As Scripting.Folder
Dim xSignFile As Scripting.File
Dim xSignText, xSignPath As String
Dim xMailRTFText, xMeetingRTFText, xAllRTFText As String
Dim xByte() As Byte
Dim xPos As Integer
Dim xFilePath, xFldPath, xFldName As String
Dim xMailItem As MailItem
On Error Resume Next
If Item.Class = olMeetingRequest Then
    Set xMeetingItem = Item
    Set xFSO = CreateObject("scripting.FileSystemObject")
    xSignPath = CStr(Environ("USERPROFILE")) & "\AppData\Roaming\Microsoft\Signatures\"
    Set xSignFld = xFSO.GetFolder(xSignPath)
    If xSignFld.SubFolders.Count <> 0 Then
        For Each xSignSubFld In xSignFld.SubFolders
            xFldName = xSignSubFld.Name
            xFldPath = xSignSubFld.Path
        Next
    End If
    For Each xSignFile In xSignFld.Files
        If xFSO.GetExtensionName(xSignFile.Path) = "htm" Then
            Set xSignStream = xFSO.OpenTextFile(xSignFile.Path)
            xSignText = xSignStream.ReadAll
            If InStr(xSignText, xFldName) <> 0 Then
                xSignText = Replace(xSignText, xFldName, xFldPath)
            End If
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            xMailItem.HTMLBody = xSignText
            xMailRTFText = StrConv(xMailItem.RTFBody, vbUnicode)
            xMeetingRTFText = StrConv(xMeetingItem.RTFBody, vbUnicode)
            xPos = InStrRev(xMeetingRTFText, "{\*\htmltag104 </div>}\htmlrtf }\htmlrtf0")
            xFilePath = CreateObject("WScript.Shell").SpecialFolders(16)
            xFilePath = xFilePath & "\MeetingText.txt"
            If xFSO.FileExists(xFilePath) Then
                xFSO.DeleteFile xFilePath
            End If
            Set xWriteStream = xFSO.OpenTextFile(xFilePath, 8, True)
            xMeetingRTFText = Mid(xMeetingRTFText, 1, xPos - 1) & "{\*\htmltag72 </p>}{\*\htmltag0 \par }{\*\htmltag0 \par }" _
            & "{\*\htmltag64 <p class=MsoNormal>}\htmlrtf {\htmlrtf0 {\*\htmltag148 <span lang=EN-US style='color:#00B050'>}\htmlrtf {\htmlrtf0" _
            & "{\*\htmltag244 <o:p>}{\*\htmltag84 &nbsp;}\htmlrtf \'a0\htmlrtf0{\*\htmltag252 </o:p>}" _
            & "{\*\htmltag156 </span>}\htmlrtf }\htmlrtf0 \htmlrtf\par}\htmlrtf0" _
            & vbCrLf & xMailRTFText & vbCrLf & Mid(xMeetingRTFText, xPos, Len(xMeetingRTFText) - xPos + 1)
            xWriteStream.WriteLine xMeetingRTFText
            Set xReadStream = xFSO.OpenTextFile(xFilePath)
            xAllRTFText = xReadStream.ReadAll
            PackBytes xByte, xAllRTFText
            xMeetingItem.RTFBody = xByte
            xMeetingItem.Save
            xMailItem.Close olDiscard
        End If
    Next
End If
End Sub
Private Sub PackBytes(ByteArray() As Byte, ByVal PostData As String)
    ByteArray() = StrConv(PostData, vbFromUnicode)
End Sub

3. Schließen Sie anschließend das Code-Fenster. Ab sofort wird beim Senden einer ausgehenden Besprechungseinladung die festgelegte Signatur automatisch eingefügt. Sie können das Ergebnis im Ordner Gesendete Elemente überprüfen: