Wie erstellt man Outlook-Erinnerungen aus einer Excel-Tabelle?

Dieser Artikel zeigt Ihnen, wie Sie Outlook-Erinnerungen basierend auf Daten aus einer Excel-Tabelle erstellen.

Erstellen Sie Outlook-Erinnerungen aus einer Excel-Tabelle mithilfe von VBA-Code

---

Erstellen Sie Outlook-Erinnerungen aus einer Excel-Tabelle mithilfe von VBA-Code

Möchten Sie Outlook-Erinnerungen direkt aus Excel erstellen, gehen Sie folgendermaßen vor:

1. Erstellen Sie ein Arbeitsblatt mit den Spaltenüberschriften und den zugehörigen Erinnerungsfeldern, wie in der folgenden Abbildung dargestellt.

Hinweis: In der Spalte „Beschäftigungsstatus“ steht die Zahl „2“ dafür, dass die Erinnerung in Ihrem Outlook-Kalender als „Beschäftigt“ angezeigt wird. Bei Bedarf können Sie diesen Status in „1 (Vorläufig)“, „3 (Abwesend)“, „4 (Arbeitet woanders)“ oder „5 (Frei)“ ändern.

2. Drücken Sie „Alt“ + „F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

3. Klicken Sie im Fenster „Microsoft Visual Basic for Applications“ auf „Einfügen“ > „Modul“ und fügen Sie anschließend den folgenden VBA-Code in das Code-Fenster ein.

VBA-Code: Erstellen Sie Outlook-Erinnerungen aus einer Excel-Tabelle

Sub AddAppointments()
'Update by Extendoffice 20180608
    Dim I As Long
    Dim xRg As Range
    Dim xOutApp As Object
    Dim xOutItem As Object
    Set xOutApp = CreateObject("Outlook.Application")
    Set xRg = Range("A2:G2")
    For I = 1 To xRg.Rows.Count
        Set xOutItem = xOutApp.CreateItem(1)
        Debug.Print xRg.Cells(I, 1).Value
        xOutItem.Subject = xRg.Cells(I, 1).Value
        xOutItem.Location = xRg.Cells(I, 2).Value
        xOutItem.Start = xRg.Cells(I, 3).Value
        xOutItem.Duration = xRg.Cells(I, 4).Value
        If Trim(xRg.Cells(I, 5).Value) = "" Then
            xOutItem.BusyStatus = 2
        Else
            xOutItem.BusyStatus = xRg.Cells(I, 5).Value
        End If
        If xRg.Cells(I, 6).Value > 0 Then
            xOutItem.ReminderSet = True
            xOutItem.ReminderMinutesBeforeStart = xRg.Cells(I, 6).Value
        Else
            xOutItem.ReminderSet = False
        End If
        xOutItem.Body = xRg.Cells(I, 7).Value
        xOutItem.Save
        Set xOutItem = Nothing
    Next
    Set xOutApp = Nothing
End Sub

Hinweis: Im obigen Code steht „A2:G2“ für den Datenbereich, auf dessen Grundlage Sie Termine erstellen möchten.

4. Drücken Sie „F5“ oder klicken Sie auf die Schaltfläche „Ausführen“, um den Code zu starten – anschließend werden alle Termine mit den angegebenen Feldern auf einen Schlag in Ihren Outlook-Kalender eingefügt.

Anschließend können Sie die Ergebnisse direkt in Ihrem Outlook-Kalender anzeigen. Siehe Abbildung: