Wie exportiert man Kontaktdaten inklusive Fotos aus Outlook?

Wenn Sie Kontakte aus Outlook in eine Datei exportieren, können nur die Textinformationen der Kontakte exportiert werden. Manchmal benötigen Sie jedoch auch die Fotos zusätzlich zu den Textinformationen der Kontakte. Wie können Sie diese Aufgabe in Outlook bewältigen?

Exportieren Sie Kontaktdaten mit zugehörigen Fotos mithilfe von VBA-Code

---

Exportieren Sie Kontaktdaten mit zugehörigen Fotos mithilfe von VBA-Code

Der folgende VBA-Code unterstützt Sie dabei, alle Kontakte aus einem bestimmten Kontaktordner einzeln – jeweils mit Foto – in Textdateien zu exportieren. Gehen Sie dazu wie folgt vor:

1. Wählen Sie einen Kontaktordner aus, dessen Kontakte Sie gemeinsam mit ihren Fotos exportieren möchten.

2. Halten Sie anschließend die Tasten „ALT“ + „F11“ gedrückt, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

3. Klicken Sie anschließend auf „Einfügen“ > „Modul“, kopieren Sie den folgenden Code und fügen Sie ihn in das geöffnete leere Modul ein (siehe Screenshot):

VBA-Code: Exportieren von Kontaktdaten mit Fotos

Sub BatchExportContactPhotosandInformation()
Dim xContactItems As Outlook.Items
Dim xItem As Object
Dim xContactItem As ContactItem
Dim xContactInfo As String
Dim xShell As Object
Dim xFSO As Scripting.FileSystemObject
Dim xTextFile As Scripting.TextStream
Dim xAttachments As Attachments
Dim xAttachment As Attachment
Dim xSavePath, xEmailAddress As String
Dim xFolder As Outlook.Folder
On Error Resume Next
Set xFSO = CreateObject("Scripting.FileSystemObject")
Set xShell = CreateObject("Shell.application").BrowseforFolder(0, "Select a Folder", 0, 16)
If xShell Is Nothing Then Exit Sub
xSavePath = xShell.Items.Item.Path & "\"
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    Set xFolder = Outlook.Application.Session.GetDefaultFolder(olFolderContacts)
Else
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
End If
Set xContactItems = xFolder.Items
For i = xContactItems.Count To 1 Step -1
    Set xItem = xContactItems.Item(i)
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        With xContactItem
            xEmailAddress = .Email1Address
            If Len(Trim(.Email2Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email2Address
            End If
            If Len(Trim(.Email3Address)) <> 0 Then
                xEmailAddress = xEmailAddress & ";" & .Email3Address
            End If
            xContactInfo = "Name: " & .FullName & vbCrLf & "Email: " & _
                           xEmailAddress & vbCrLf & "Company: " & .CompanyName & _
                           vbCrLf & "Department: " & .Department & _
                           vbCrLf & "Job Title: " & .JobTitle & _
                           vbCrLf & "IM: " & .IMAddress & _
                           vbCrLf & "Business Phone: " & .BusinessTelephoneNumber & _
                           vbCrLf & "Home Phone: " & .HomeTelephoneNumber & _
                           vbCrLf & "BusinessFax Phone: " & .BusinessFaxNumber & _
                           vbCrLf & "Mobile Phone: " & .MobileTelephoneNumber & _
                           vbCrLf & "Business Address: " & .BusinessAddress
            Set xTextFile = xFSO.CreateTextFile(xSavePath & .FullName & ".txt", True)
            xTextFile.WriteLine xContactInfo
            If .Attachments.Count > 0 Then
                Set xAttachments = .Attachments
                For Each xAttachment In xAttachments
                    If InStr(LCase(xAttachment.FileName), "contactpicture.jpg") > 0 Then
                        xAttachment.SaveAsFile (xSavePath & .FullName & ".jpg")
                    End If
                Next
            End If
        End With
    End If
Next i
End Sub

4. Nachdem Sie den Code in das Modul eingefügt haben, klicken Sie im Fenster „Microsoft Visual Basic for Applications“ auf „Extras“ > „Verweise“. Aktivieren Sie im erscheinenden Dialogfeld „Verweise – Projekt1“ die Option „Microsoft Scripting Runtime“ in der Liste der verfügbaren Verweise (siehe Screenshot):

5. Klicken Sie auf „OK“, um das Dialogfeld zu schließen, und drücken Sie anschließend „F5“, um den Code auszuführen. Geben Sie im erscheinenden Dialogfeld „Ordner suchen“ den Ordner an, in dem die exportierten Kontakte gespeichert werden sollen (siehe Screenshot):

6. Klicken Sie dann auf „OK“. Alle Informationen – einschließlich der Fotos Ihrer Kontakte – wurden einzeln in den von Ihnen angegebenen Ordner exportiert (siehe Screenshot):