Wie sendet man einen Kalender individuell an mehrere Empfänger in Outlook?

Normalerweise können Sie einen Kalender mithilfe der Funktion Kalender per E-Mail versenden in Outlook schnell und einfach an einen Empfänger senden. Wenn Sie jedoch einen Kalender als iCalendar-Datei einzeln an mehrere Kontakte versenden möchten, müssen Sie dies nacheinander tun. In diesem Artikel stelle ich Ihnen eine einfache Methode vor, mit der Sie einen Kalender individuell an mehrere Empfänger in Outlook versenden können.

Senden eines Kalenders individuell an mehrere Empfänger mithilfe von VBA-Code

---

Senden eines Kalenders individuell an mehrere Empfänger mithilfe von VBA-Code

Um einen Kalender separat an mehrere Empfänger zu versenden, unterstützt Sie der folgende VBA-Code. Gehen Sie dazu wie folgt vor:

1. Wechseln Sie zum Kontakte-Bereich und wählen Sie die Kontakte aus, an die Sie den Kalender senden möchten.

2. Halten Sie anschließend die Tasten ALT + F11 gedrückt, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

3. Klicken Sie auf Einfügen > Modul, kopieren Sie den folgenden Code und fügen Sie ihn in das geöffnete leere Modul ein (siehe Screenshot):

VBA-Code: Senden eines Kalenders individuell an mehrere Empfänger:

Sub EmailCalendarToMultiplePersonsSeparately()
Dim xSelection As Outlook.Selection
Dim xCalendarFolder As Outlook.Folder
Dim xCalendarExporter As Outlook.CalendarSharing
Dim xStartDate, xEndDate As Date
Dim xCalendarFile As String
Dim xContactItem As Outlook.ContactItem
Dim xDistListItem As Outlook.DistListItem
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xFilePath, xFileName, xEmailAddress As String
Dim xRecipient As Recipient
On Error Resume Next
xFilePath = CreateObject("WScript.Shell").SpecialFolders(16) & "\MyCalendar"
If Dir(xFilePath, vbDirectory) = "" Then MkDir xFilePath
If Outlook.Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olContactItem Then
    MsgBox "Please Select contacts first!", vbExclamation + vbOKOnly, "Kutools for Outlook"
    Exit Sub
End If
Set xSelection = Outlook.Application.ActiveExplorer.Selection
If xSelection Is Nothing Then Exit Sub
Set xCalendarFolder = Outlook.Application.Session.PickFolder
If xCalendarFolder Is Nothing Then Exit Sub
If xCalendarFolder.DefaultItemType <> olAppointmentItem Then Exit Sub
Set xCalendarExporter = xCalendarFolder.GetCalendarExporter
xStartDate = InputBox("Enter the start date:", "Kutools for Outlook", "")
If Len(Trim(xStartDate)) = 0 Then Exit Sub
xEndDate = InputBox("Enter the end date:", "Kutools for Outlook", "")
If Len(Trim(xEndDate)) = 0 Then Exit Sub
If xStartDate = #1/1/4501# Or xEndDate = #1/1/4501# Then Exit Sub
xFileName = "Calendar (" & Format(xStartDate, "YYYYMMDD") & " - " & Format(xEndDate, "YYYYMMDD") & ").ics"
xCalendarFile = xFilePath & "\" & xFileName
With xCalendarExporter
    .IncludeWholeCalendar = False
    .StartDate = xStartDate
    .EndDate = xEndDate
    .CalendarDetail = olFullDetails
    .IncludeAttachments = True
    .IncludePrivateDetails = False
    .RestrictToWorkingHours = False
    .SaveAsICal xCalendarFile
End With
For Each xItem In xSelection
    If xItem.Class = olContact Then
        Set xContactItem = xItem
        Set xMailItem = Outlook.Application.CreateItem(olMailItem)
        With xMailItem
            .To = xContactItem.Email1Address
            .Recipients.ResolveAll
            .Subject = xFileName
            .Attachments.Add xCalendarFile
            .Body = "Dear " & xContactItem.FullName & "," & vbCrLf & "Type body here..."
            .Display
        End With
    End If
    If xItem.Class = olDistributionList Then
        Set xDistListItem = xItem
        For i = 1 To xDistListItem.MemberCount
            Set xRecipient = xDistListItem.GetMember(i)
            Set xMailItem = Outlook.Application.CreateItem(olMailItem)
            With xMailItem
                .To = xRecipient.AddressEntry.Address
                .Recipients.ResolveAll
                .Subject = xFileName
                .Attachments.Add xCalendarFile
                .Body = "Dear " & xRecipient.Name & "," & vbCrLf & "Type body here..."
                .Display
            End With
        Next i
    End If
Next
End Sub

4. Nachdem Sie den Code eingefügt haben, drücken Sie die Taste F5, um ihn auszuführen. Daraufhin öffnet sich das Dialogfeld Ordner auswählen. Wählen Sie bitte einen Kalender aus, den Sie senden möchten (siehe Screenshot):

5.Klicken Sie auf OKund geben Sie anschließend in den folgenden Eingabefeldern den gewünschten Datumsbereich an, über den der Kalender versendet werden soll (siehe Screenshot):

6. Klicken Sie anschließend auf OK. Es wurde nun eine neue E-Mail mit angehängtem Kalender erstellt, wie im folgenden Screenshot dargestellt. Anschließend müssen Sie diese nur noch nacheinander versenden.

---

Verwandte Artikel:

Wie sendet man in Outlook eine individuell gestaltete E-Mail an mehrere Empfänger?

Wie versendet man personalisierte Massen-E-Mails aus einer Excel-Liste über Outlook?

Wie sendet man mehrere Entwürfe in Outlook gleichzeitig?

Wie sendet man in Outlook eine E-Mail an mehrere Empfänger, ohne dass diese voneinander erfahren?