Wie kann man in Outlook Meeting-Einladungen automatisch an eine bestimmte Person weiterleiten?

In Outlook können Sie eine Meeting-Einladung direkt über die Weiterleiten-Funktion manuell an eine bestimmte Person weiterleiten. Manchmal möchten Sie Meeting-Einladungen jedoch automatisch an eine bestimmte Person weiterleiten, sobald Sie das Meeting akzeptieren. In diesem Artikel erläutere ich, wie Sie eine Meeting-Einladung so schnell wie möglich automatisch an eine Person weiterleiten.

Meeting-Einladungen in Outlook mithilfe von VBA-Code automatisch an eine bestimmte Person weiterleiten

---

Meeting-Einladungen in Outlook mithilfe von VBA-Code automatisch an eine bestimmte Person weiterleiten

Hier finden Sie einen nützlichen VBA-Code, mit dem Sie Meeting-Einladungen nach deren Annahme automatisch an eine bestimmte Person weiterleiten können. Gehen Sie dazu wie folgt vor:

1. Halten Sie die ALT + F11-Tasten gedrückt, um das Microsoft Visual Basic for Applications-Fenster zu öffnen.

2. Doppelklicken Sie im Microsoft Visual Basic for Applications-Fenster auf ThisOutlookSession im Bereich Project1 (VbaProject.OTM), um das Modul zu öffnen, und fügen Sie anschließend den folgenden Code in das leere Modul ein.

VBA-Code: Meeting-Einladungen an eine bestimmte Person Automatische Weiterleitung:

Public WithEvents ReceivedItems As Outlook.Items
Private Sub Application_Startup()
    Set ReceivedItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub ReceivedItems_ItemAdd(ByVal Item As Object)
Dim xMeetingItem As MeetingItem
Dim xMeetingResponse As MeetingItem
Dim xForwardMeeting As MeetingItem
Dim xAppointmentItem As AppointmentItem
On Error Resume Next
If TypeOf Item Is MeetingItem Then
    Set xMeetingItem = Item
    Set xAppointmentItem = xMeetingItem.GetAssociatedAppointment(True)
    Set xMeetingResponse = xAppointmentItem.Respond(olMeetingAccepted, True)
    xMeetingResponse.Send
    Set xForwardMeeting = xMeetingItem.Forward
    With xForwardMeeting
        With .Recipients
            .Add "skyyang@addin88.com" 'change address to your own
            .ResolveAll
        End With
        .Send
    End With
End If
End Sub

Hinweis: Im obigen Code müssen Sie die Empfängeradresse durch Ihre eigene ersetzen.

3. Speichern Sie den Code anschließend und starten Sie Outlook neu, damit der Code wirksam wird.

4. Sobald Sie eine Meeting-Einladung erhalten, wird das Meeting automatisch akzeptiert und unverzüglich an Ihre festgelegte Person weitergeleitet.

Hinweis: Dieser Code ist ausschließlich für Standardkonten verfügbar.