Wie kann man die Signatur in Outlook basierend auf den Empfängern automatisch ändern?

Author: Siluvia Last Modified: 2025-08-06

Standardmäßig verfügt Outlook über eine integrierte Funktion, mit der Benutzer die Signatur beim Senden von E-Mails über verschiedene E-Mail-Konten automatisch ändern können. Darüber hinaus zeige ich Ihnen hier eine Methode, um die Signatur basierend auf verschiedenen Empfängern im 'An'-Feld in Outlook automatisch zu ändern.

Signatur basierend auf Empfängern mit VBA-Code automatisch ändern

Signatur basierend auf Empfängern mit VBA-Code automatisch ändern

Bitte folgen Sie den unten stehenden Schritten, um beim Senden von E-Mails in Outlook unterschiedliche Signaturen für entsprechende Empfänger anzuwenden.

1. Deaktivieren Sie zunächst die Funktion zur automatischen Anlage von Signaturen in Outlook. Klicken Sie dazu auf Datei > Optionen, um das Outlook-Optionen-Fenster zu öffnen.

2. Wählen Sie im Outlook-Optionen-Fenster die Option Mail im linken Bereich aus, und klicken Sie dann auf die Schaltfläche Signaturen im Abschnitt Nachrichten verfassen. Siehe Screenshot:

using vba to change signature based on recipients automatically with code

3. Gehen Sie im Dialogfeld Signaturen und Briefpapier zum Abschnitt Standard-Signatur unter dem Registerreiter E-Mail-Signatur, wählen Sie ein E-Mail-Konto aus der Dropdown-Liste E-Mail-Konto aus, und wählen Sie dann (keine) aus den Dropdown-Listen Neue Nachrichten und Antworten/Weiterleitungen aus. Wiederholen Sie diese Schritte, bis alle E-Mail-Konten auf (keine) eingestellt sind. Klicken Sie anschließend auf die Schaltfläche OK.

using vba to change signature based on recipients automatically with VBA code

Hinweis: Sie können auch Ihre benötigten Signaturen in diesem Dialogfeld Signaturen und Briefpapier erstellen.

4. Klicken Sie auf die Schaltfläche OK, wenn Sie zurück zum Outlook-Optionen-Fenster gelangen.

5. Drücken Sie die Tasten Alt + F11, um das Microsoft Visual Basic for Applications-Fenster zu öffnen.

6. Doppelklicken Sie im Microsoft Visual Basic for Applications-Fenster im linken Bereich auf ThisOutlookSession, um das Codefenster zu öffnen, und kopieren Sie den folgenden VBA-Code in das Fenster. Siehe Screenshot:

VBA-Code: Automatisches Ändern der Signatur basierend auf Empfängern in Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Hinweise:

1). Ersetzen Sie im VBA-Code "E-Mail-Adresse 1/2/3/4" durch die jeweiligen E-Mail-Adressen der Empfänger.
2). "aaa.htm", "bbb.htm" und "ccc.htm" sind die spezifischen Signaturen, die Sie an die entsprechenden Empfänger senden werden.
3). In diesem Fall wird die Signatur "aaa" an "E-Mail-Adresse 1" gesendet, die Signatur "bbb" an "E-Mail-Adresse 2" und "E-Mail-Adresse 3", und "E-Mail-Adresse 4" erhält die E-Mail mit der Signatur "ccc". Bitte passen Sie diese je nach Bedarf an.
4). Wenn es mehrere Empfänger in einer E-Mail gibt, berücksichtigt der Code nur den ersten Empfänger. In diesem Fall erhalten andere Empfänger die E-Mails mit derselben Signatur wie der erste Empfänger.

7. Klicken Sie dann auf Extras > Verweise, um zum Dialogfeld Verweise - Projekt zu gelangen. Aktivieren Sie im Dialogfeld sowohl die Optionen Microsoft Word Object Library als auch Microsoft Scripting Runtime, und klicken Sie dann auf die Schaltfläche OK. Siehe Screenshot:

8. Drücken Sie die Tasten Alt + Q, um das Microsoft Visual Basic for Applications-Fenster zu schließen.

Ab sofort wird nach dem Verfassen einer E-Mail und dem Klicken auf die Schaltfläche Senden die entsprechende Signatur basierend auf der E-Mail-Adresse des Empfängers im 'An'-Feld automatisch am Ende des E-Mail-Textes eingefügt.

Wenn Sie beim Erstellen/Antworten/Weiterleiten neuer E-Mails in Ihrem Outlook einen Zeitstempel als Signatur in den E-Mail-Text einfügen möchten, können Sie die Datumssignatur beim Erstellen, Antworten und Weiterleiten von E-Mails hinzufügen Option von Kutools für Outlook aktivieren, um dies zu erreichen. Siehe Screenshot:
Jetzt herunterladen und ausprobieren (30-Tage kostenlose Testversion)

using vba to change signature based on recipients automatically with VBA code