Wie exportiert man die Ordnerstruktur aus Outlook nach Excel?

In diesem Artikel erfahren Sie, wie Sie die Ordnerstruktur eines Kontos aus Outlook in eine Excel-Datei exportieren – einfach Schritt für Schritt nach den detaillierten Anweisungen in diesem Beitrag vorgehen.

Exportieren Sie Ordnerstruktur eines Kontos aus Outlook in Excel mithilfe von VBA-Code

---

Exportieren Sie Ordnerstruktur eines Kontos aus Outlook in Excel mithilfe von VBA-Code

Der folgende VBA-Code unterstützt Sie dabei. Gehen Sie bitte wie folgt vor:

1. Öffnen Sie Excel und halten Sie die ALT + F11-Tasten gedrückt, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf Einfügen > Modul, und fügen Sie den folgenden Code in das Modul-Fenster ein.

VBA-Code: Exportieren Sie Ordnerstruktur eines Kontos aus Outlook in Excel:

Dim xExcelApp As Excel.Application
Dim xWb As Excel.Workbook
Dim xWs As Excel.Worksheet
Dim xMainFolderCount As Long
Sub OutlookExportFolderStructureToExcel()
    Dim xFolder As Folder
    Dim xExcelFile As String
    Dim xFileDialog As FileDialog
    On Error Resume Next
    Set xFolder = Outlook.Application.Session.PickFolder
    If xFolder Is Nothing Then Exit Sub
    Set xExcelApp = New Excel.Application
    Set xWb = xExcelApp.Workbooks.Add
    Set xWs = xWb.Sheets(1)
    With xWs.Range("A1", "A1")
         .Value = "Folder Structure"
         .Font.Size = 14
         .Font.Bold = True
    End With
    xMainFolderCount = Len(xFolder.FolderPath) - Len(Replace(xFolder.FolderPath, "\", "")) + 1
    Call ExportToExcel(xFolder.FolderPath, xFolder.Name)
    Call ProcessFolders(xFolder.Folders)
    xWs.Columns("A").AutoFit
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogSaveAs)
    With xFileDialog
        .AllowMultiSelect = False
        .FilterIndex = 1
        If .Show = 0 Then
            xWb.Close False
            xExcelApp.Quit
            Set xExcelApp = Nothing
            Exit Sub
        End If
        xExcelFile = .SelectedItems.Item(1)
    End With
    xWb.Close True, xExcelFile
    MsgBox "Export complete!", vbExclamation, "Kutools for Outlook"
End Sub

Sub ProcessFolders(ByVal xFlds As Folders)
    Dim xSubFolder As Folder
    For Each xSubFolder In xFlds
        If xSubFolder.Name <> "Conversation Action Settings" And xSubFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(xSubFolder.FolderPath, xSubFolder.Name)
           Call ProcessFolders(xSubFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef xFolderPath As String, xFolderName As String)
    Dim i, n As Long
    Dim xPrefix As String
    Dim xLastRow As Integer
    i = Len(xFolderPath) - Len(Replace(xFolderPath, "\", "")) - xMainFolderCount
    For n = 0 To i
        xPrefix = xPrefix & "-"
    Next
    xFolderName = xPrefix & xFolderName
    xLastRow = xWs.UsedRange.Rows.Count + 1
    xWs.Range("A" & xLastRow) = xFolderName
End Sub

3.Bleiben Sie im Fenster Microsoft Visual Basic for Applications, klicken Sie auf Extras>Verweise, um das Dialogfeld Verweise – Projekt1zu öffnen, und aktivieren Sie die Option Microsoft Excel Object Libraryin der Liste Verfügbare Verweise, siehe Screenshot:

4. Klicken Sie anschließend auf die Schaltfläche OK und drücken Sie die Taste F5, um diesen Code auszuführen. Daraufhin wird das Dialogfeld Ordner auswählen geöffnet. Wählen Sie das E-Mail-Konto aus, dessen Ordnerstruktur Sie exportieren möchten (siehe Screenshot):

5. Klicken Sie danach auf die Schaltfläche OK, woraufhin ein Speichern unter-Fenster angezeigt wird. Geben Sie bitte einen Speicherort und einen Dateinamen für die exportierte Datei an – siehe Screenshot:

6. Klicken Sie abschließend auf die Schaltfläche Speichern, und navigieren Sie zu der von Ihnen angegebenen Excel-Arbeitsmappe, um die exportierte Ordnerstruktur anzuzeigen – siehe Screenshot: