Wie druckt man Aufgaben in Outlook basierend auf Kategorien?

Angenommen, Ihre Outlook-Aufgaben sind verschiedenen Farbkategorien zugeordnet, und Sie möchten die Aufgabenliste nach Kategorien sortiert auf separaten Seiten ausdrucken – wie lässt sich das in Outlook umsetzen?

Aufgaben nach Kategorien manuell einzeln auf verschiedenen Seiten drucken

Aufgaben nach Kategorien mit VBA-Code auf verschiedenen Seiten drucken

---

Aufgaben nach Kategorien manuell einzeln auf verschiedenen Seiten drucken

In Outlook können Sie Aufgaben manuell nach verschiedenen Kategorien sortiert und einzeln auf separaten Seiten drucken. Gehen Sie dazu wie folgt vor:

1. Starten Sie Outlook, wechseln Sie zum Aufgabenbereich, wählen Sie den gewünschten Aufgabenordner aus und drücken Sie anschließend Strg + E, um das Suchfeld zu aktivieren. Klicken Sie dann unter der Registerkarte Suche auf das Symbol Kategorisiert und wählen Sie eine Farbkategorie aus, die Sie drucken möchten (siehe Screenshot):

2. Anschließend werden alle Aufgaben mit der ausgewählten Farbkategorie angezeigt (siehe Screenshot):

3. Klicken Sie dann auf Datei > Drucken, um diese Aufgabenliste wie im folgenden Screenshot gezeigt auszudrucken:

4. Wiederholen Sie die oben beschriebenen Schritte, um die Aufgabenlisten der übrigen Farbkategorien nacheinander manuell auszudrucken.

---

Aufgaben nach Kategorien mit VBA-Code auf verschiedenen Seiten drucken

Hier ist ein VBA-Code, mit dem Sie Ihre Aufgaben sofort nach Kategorien sortiert auf separaten Seiten drucken können. Gehen Sie dazu wie folgt vor:

1. Wechseln Sie zum Aufgaben-Bereich, und wählen Sie den Aufgabenordner aus, den Sie drucken möchten.

2. Drücken Sie anschließend die Tastenkombination ALT + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

3. Klicken Sie dann auf Einfügen > Modul, und fügen Sie den folgenden Code in das geöffnete leere Modul ein:

VBA-Code: Aufgaben nach Kategorien auf verschiedenen Seiten drucken:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Klicken Sie anschließend im Fenster Extras > Verweise auf Microsoft Visual Basic for Applications. Aktivieren Sie im erscheinenden Dialogfeld Verweise – Projekt1 die Optionen Microsoft Excel Object Library und Microsoft Scripting Runtime in der Liste Verfügbare Verweise (siehe Screenshot):

5. Klicken Sie anschließend auf die Schaltfläche OK und drücken Sie dann die Taste F5, um diesen Code auszuführen. Sobald der Code ausgeführt wurde, werden die Aufgabenlisten mit den verschiedenen Kategorien auf separaten Seiten gedruckt.