Wie behält man beim Antworten oder Weiterleiten einer E-Mail in Outlook die Kategorie bei?

Normalerweise wird die Kategorie automatisch aus der gesendeten E-Mail entfernt, sobald Sie auf eine von Ihnen kategorisierte Nachricht antworten oder sie weiterleiten. Möchten Sie die Kategorie bei ausgehenden E-Mails beim Antworten oder Weiterleiten jedoch beibehalten, zeigt Ihnen dieser Artikel eine dafür geeignete Methode.

Kategorie beim Antworten oder Weiterleiten einer E-Mail mithilfe von VBA-Code beibehalten

---

Kategorie beim Antworten oder Weiterleiten einer E-Mail mithilfe von VBA-Code beibehalten

1. Halten Sie die ALT + F11-Tasten gedrückt, um das Microsoft Visual Basic for Applications-Fenster zu öffnen.

2. Doppelklicken Sie im Microsoft Visual Basic for Applications-Fenster auf ThisOutlookSession im Bereich Project1 (VbaProject.OTM), um das Modul zu öffnen, und fügen Sie anschließend den folgenden Code in das leere Modul ein.

VBA-Code: Kategorie beim Antworten oder Weiterleiten einer E-Mail beibehalten:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Schließen Sie anschließend das Code-Fenster, beenden und starten Sie Outlook neu. Ab sofort wird die Kategorie beim Antworten auf oder Weiterleiten einer kategorisierten E-Mail in der ausgehenden Nachricht im Ordner Gesendete Elemente beibehalten (siehe Screenshot):