Outlook: So extrahieren Sie alle URLs aus einer E-Mail

Wenn eine E-Mail Hunderte von URLs enthält, die in eine Textdatei extrahiert werden müssen, ist manuelles Kopieren und Einfügen äußerst zeitaufwendig. In diesem Tutorial stellen wir Ihnen effiziente VBA-Skripte vor, mit denen Sie im Handumdrehen alle URLs aus einer E-Mail extrahieren können.

VBA zum Extrahieren von URLs aus einer E-Mail in eine Textdatei

VBA zum Extrahieren von URLs aus mehreren E-Mails in eine Excel-Datei

VBA zum Extrahieren von URLs aus einer E-Mail in eine Textdatei

1. Wählen Sie eine E-Mail aus, aus der Sie die URLs extrahieren möchten, und drücken Sie die Tasten Alt+F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf Einfügen > Modul, um ein neues leeres Modul zu erstellen, und fügen Sie dann den folgenden Code in das Modul ein.

VBA: Alle URLs aus einer E-Mail in eine Textdatei extrahieren.

Sub ExportUrlToTextFileFromEmail()
'UpdatebyExtendoffice20220413
  Dim xMail As Outlook.MailItem
  Dim xRegExp As RegExp
  Dim xMatchCollection As MatchCollection
  Dim xMatch As Match
  Dim xUrl As String, xSubject As String, xFileName As String
  Dim xFs As FileSystemObject
  Dim xTextFile As Object
  Dim i As Integer
  Dim InvalidArr
  On Error Resume Next
  If Application.ActiveWindow.Class = olInspector Then
    Set xMail = ActiveInspector.CurrentItem
  ElseIf Application.ActiveWindow.Class = olExplorer Then
    Set xMail = ActiveExplorer.Selection.Item(1)
  End If
  Set xRegExp = New RegExp
  With xRegExp
    .Pattern = "(https?[:]//([0-9a-z=\?:/\.&-^!#$;_])*)"
    .Global = True
    .IgnoreCase = True
  End With
  If xRegExp.test(xMail.Body) Then
    InvalidArr = Array("/", "\", "*", ":", Chr(34), "?", "<", ">", "|")
    xSubject = xMail.Subject
    For i = 0 To UBound(InvalidArr)
      xSubject = VBA.Replace(xSubject, InvalidArr(i), "")
    Next i
    xFileName = "C:\Users\Public\Downloads\" & xSubject & ".txt"
    Set xFs = CreateObject("Scripting.FileSystemObject")
    Set xTextFile = xFs.CreateTextFile(xFileName, True)
    xTextFile.WriteLine ("Export URLs:" & vbCrLf)
    Set xMatchCollection = xRegExp.Execute(xMail.Body)
    i = 0
    For Each xMatch In xMatchCollection
      xUrl = xMatch.SubMatches(0)
      i = i + 1
      xTextFile.WriteLine (i & ". " & xUrl & vbCrLf)
    Next
    xTextFile.Close
    Set xTextFile = Nothing
    Set xMatchCollection = Nothing
    Set xFs = Nothing
    Set xFolderItem = CreateObject("Shell.Application").NameSpace(0).ParseName(xFileName)
    xFolderItem.InvokeVerbEx ("open")
    Set xFolderItem = Nothing
  End If
  Set xRegExp = Nothing
End Sub

In diesem Code wird eine neue Textdatei erstellt, die nach dem E-Mail-Betreff benannt und im Pfad C:\Users\Public\Downloads gespeichert wird. Sie können diesen Pfad bei Bedarf anpassen.

3. Klicken Sie auf Extras > Verweise, um das Dialogfeld Verweise – Projekt 1 zu öffnen, und aktivieren Sie das Kontrollkästchen Microsoft VBScript Regular Expressions 5,5. Klicken Sie anschließend auf OK.

4. Drücken Sie die Taste F5 oder klicken Sie auf die Schaltfläche Ausführen, um den Code auszuführen. Anschließend öffnet sich eine Textdatei mit allen extrahierten URLs.

Hinweis: Wenn Sie Outlook 2010 und Outlook 365 verwenden, aktivieren Sie in Schritt 3 zusätzlich das Kontrollkästchen „Windows Script Host Object Model“ und klicken Sie anschließend auf „OK“.

VBA zum Extrahieren von URLs aus mehreren E-Mails in eine Excel-Datei

Möchten Sie URLs aus mehreren ausgewählten E-Mails in eine Excel-Datei extrahieren? Der folgende VBA-Code unterstützt Sie dabei.

1. Wählen Sie eine E-Mail aus, aus der Sie die URLs extrahieren möchten, und drücken Sie die Tasten Alt+F11, um das Fenster Microsoft Visual Basic for Applicationszu öffnen.

2. Klicken Sie auf Einfügen>Modul, um ein neues leeres Modul zu erstellen, und kopieren Sie den folgenden Code anschließend in das Modul.

VBA: Alle URLs aus mehreren E-Mails in eine Excel-Datei extrahieren

'UpdatebyExtendoffice20220414
Dim xExcel As Excel.Application
Dim xExcelWb As Excel.Workbook
Dim xExcelWs As Excel.Worksheet

Sub ExportAllUrlsToExcelFromMultipleEmails()
  Dim xMail As MailItem
  Dim xSelection As Selection
  Dim xWordDoc As Word.Document
  Dim xHyperlink As Word.Hyperlink
  On Error Resume Next
  Set xSelection = Outlook.Application.ActiveExplorer.Selection
  If (xSelection Is Nothing) Then Exit Sub
  Set xExcel = CreateObject("Excel.Application")
  Set xExcelWb = xExcel.Workbooks.Add
  Set xExcelWs = xExcelWb.Sheets(1)
  xExcelWb.Activate
  With xExcelWs
    .Range("A1") = "Subject"
    .Range("B1") = "DisplayText"
    .Range("C1") = "Link"
  End With
  With xExcelWs.Range("A1", "C1").Font
    .Bold = True
    .Size = 12
  End With
  For Each xMail In xSelection
    Set xWordDoc = xMail.GetInspector.WordEditor
    If xWordDoc.Hyperlinks.Count > 0 Then
      For Each xHyperlink In xWordDoc.Hyperlinks
          Call ExportToExcelFile(xMail, xHyperlink)
      Next
    End If
  Next
  xExcelWs.Columns("A:C").AutoFit
  xExcel.Visible = True
End Sub

Sub ExportToExcelFile(curMail As MailItem, curHyperlink As Word.Hyperlink)
  Dim xRow As Integer
  xRow = xExcelWs.Range("A" & xExcelWs.Rows.Count).End(xlUp).Row + 1
  With xExcelWs
    .Cells(xRow, 1) = curMail.Subject
    .Cells(xRow, 2) = curHyperlink.TextToDisplay
    .Cells(xRow, 3) = curHyperlink.Address
  End With
End Sub

In diesem Code werden alle Hyperlinks samt zugehörigem Anzeigetext und E-Mail-Betreff extrahiert.

3. Klicken Sie auf Extras > Verweise, um das Dialogfeld Verweise – Projekt 1 zu öffnen, und aktivieren Sie die Kontrollkästchen Microsoft Excel 16,0 Object Library und Microsoft Word 16,0 Object Library. Klicken Sie anschließend auf OK.

4. Platzieren Sie anschließend den Cursor innerhalb des VBA-Codes, drücken Sie die Taste F5 oder klicken Sie auf die Schaltfläche Ausführen, um den Code auszuführen. Es öffnet sich nun eine Arbeitsmappe mit allen extrahierten URLs, die Sie anschließend in einem Ordner speichern können.

Hinweis: Alle oben genannten VBA-Skripte extrahieren sämtliche Arten von Hyperlinks.

---

Beste Office-Produktivitätswerkzeuge

Erleben Sie das komplett neue Kutools für Outlook mit 100+ unglaublichen Funktionen!Jetzt zum Download klicken!

🤖KUTOOLS AI:Nutzt fortschrittliche KI-Technologie, um E-Mails mühelos zu verwalten – einschließlich Beantworten, Zusammenfassen, Optimieren, Erweitern, Übersetzen und Verfassen von E-Mails.

📧E-Mail-Automatisierung: Automatische Antworten (verfügbar für POP und IMAP) / E-Mails zeitgesteuert versenden / Beim Senden automatisch CC/BCC basierend auf Regeln hinzufügen / Automatische Weiterleitung (Erweiterte Regeln) / Automatische Grußformel einfügen / Mehrfachadressierte E-Mails automatisch in Einzelnachrichten aufteilen …

📨E-Mail-Verwaltung: E-Mails zurückrufen, Betrugs-E-Mails anhand von Betreffzeilen und weiteren Kriterien blockieren, doppelte E-Mails löschen, Erweiterte Suche, Ordner organisieren …

📁Anhänge Pro: Stapelweise speichern / Stapelweise lösen / Stapelweise komprimieren / Automatisch speichern / Automatisch abtrennen / Automatische Komprimierung …

🌟Oberflächenzauber:😊Noch mehr hübsche und coole Emojis/Benachrichtigung bei wichtigen eingehenden E-Mails/Outlook minimieren statt schließen...

👍Ein-Klick-Wunder: Allen mit Anhängen antworten / Anti-Phishing-E-Mails / 🕘Aktuelle Uhrzeit der Absender-Zeitzone anzeigen...

👩🏼‍🤝‍👩🏻Kontakte & Kalender:Stapelweise Kontakte aus ausgewählten E-Mails hinzufügen/Eine Kontaktgruppe in einzelne Kontakte aufteilen/Geburtstagserinnerung entfernen...

Nutzen Sie Kutools in Ihrer bevorzugten Sprache – mit Unterstützung für Englisch, Spanisch, Deutsch, Französisch, Chinesisch und über 40 weitere Sprachen!

Kutools für Outlook mit nur einem Klick sofort freischalten! Warten Sie nicht – laden Sie jetzt herunter und steigern Sie Ihre Effizienz!

Funktionsliste von Kutools für Outlook      Jetzt herunterladen      Zum Kauf gehen

🚀 Ein-Klick-Download – Holen Sie sich alle Office-Add-Ins

Stark empfohlen: Kutools for Office (5-in-1)

Mit einem Klick fünf Installationsprogrammegleichzeitig herunterladen –Kutools für Excel, Outlook, Word, PowerPointund Office Tab Pro.Jetzt zum Download klicken!

• ✅Ein-Klick-Komfort: Laden Sie alle fünf Installationspakete mit nur einem Klick herunter.
• 🚀Bereit für jede Office-Aufgabe: Installieren Sie die Add-Ins, die Sie brauchen – genau dann, wenn Sie sie benötigen.
• 🧰Enthalten: Kutools für Excel / Kutools für Outlook / Kutools für Word / Office Tab Pro / Kutools for PowerPoint

Über das Paket⬇ Das Paket herunterladen💳 Das Paket kaufen