Outlook: So richten Sie das automatische erneute Senden einer E-Mail ein, falls keine Antwort erfolgt

Wenn Sie eine E-Mail an einen Kollegen, Geschäftspartner oder eine andere Person senden und dringend eine Antwort benötigen, können Sie eine automatische Erinnerung einrichten, die die Nachricht erneut versendet, falls bis zu einem bestimmten Zeitpunkt keine Antwort eingegangen ist.

Verwenden von Erinnerung und VBA, um das automatische erneute Senden bei fehlender Antwort einzurichten

---

Verwenden von Erinnerung und VBA, um das automatische erneute Senden bei fehlender Antwort einzurichten

Teil 1: Legen Sie eine Erinnerung fest, die zu einem bestimmten Zeitpunkt benachrichtigt

1. Klicken Sie mit der rechten Maustaste auf eine E-Mail aus dem Ordner „Gesendete Elemente“, die Sie erneut senden möchten, falls keine Antwort eingeht, und wählen Sie im Kontextmenü „Nachverfolgen“ > „Erinnerung hinzufügen“.

2. Aktivieren Sie im erscheinenden Dialogfeld „Benutzerdefiniert“ das Kontrollkästchen „Erinnerung“ und wählen Sie in den darunterliegenden Dropdown-Feldern ein Datum sowie eine Uhrzeit aus, bis zu der die Antwort eingegangen sein soll. Alternativ geben Sie Datum und Uhrzeit direkt in die Felder ein. Klicken Sie anschließend auf „OK“.

Teil 2: Fügen Sie ein VBA-Skript ein, um E-Mails erneut zu senden, falls innerhalb der festgelegten Zeit keine Antwort erfolgt

3. Drücken Sie „Alt“ + „F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

4. Doppelklicken Sie im Bereich „Projekt – Projekt1“ auf „ThisOutlookSession“, um ein leeres Skript zu öffnen, und fügen Sie den folgenden VBA-Code in dieses Skript ein.

VBA: E-Mail erneut senden, falls keine Antwort erfolgt

Public WithEvents GInboxItems As Outlook.Items
'UpdatebyExtendoffice20220413
Private Sub Application_Startup()
  Dim xInboxFld As Folder
  Set xInboxFld = Application.Session.GetDefaultFolder(olFolderInbox)
  Set GInboxItems = xInboxFld.Items
End Sub

'Judge
Private Sub GInboxItems_ItemAdd(ByVal Item As Object)
  Dim xSentItems As Outlook.Items
  Dim xMail As MailItem
  Dim i As Long
  Dim xSubject As String
  Dim xItemSubject As String
  Dim xSendTime As String
  On Error Resume Next
  Set xSentItems = Application.Session.GetDefaultFolder(olFolderSentMail).Items
  If Item.Class <> olMail Then Exit Sub
  For i = xSentItems.Count To 1 Step -1
    If xSentItems.Item(i).Class = olMail Then
      Set xMail = xSentItems.Item(i)
      xSubject = LCase(xMail.Subject)
      xSendTime = xMail.SentOn
      xItemSubject = LCase(Item.Subject)
      If (xItemSubject = "re: " & xSubject) Or (InStr(xItemSubject, xSubject) > 0) Then
        If Item.SentOn > xSendTime Then
           With xMail
             .ClearTaskFlag
             .ReminderSet = False
             .Save
           End With
        End If
      End If
    End If
  Next i
End Sub

'Reminder
Private Sub Application_Reminder(ByVal Item As Object)
  Dim xPrompt As String
  Dim xResponse As Integer
  Dim xFollowUpMail As Outlook.MailItem
  Dim xRcp As Recipient
  On Error Resume Next
  'Resend
  If (Item.Class <> olMail) Then Exit Sub
  xPrompt = "You haven't yet received the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
  xResponse = MsgBox(xPrompt, vbYesNo + vbQuestion, "Kutools for Outlook")
  If xResponse = vbNo Then Exit Sub
  Set xFollowUpMail = Application.CreateItem(olMailItem)
  With xFollowUpMail
    For Each xRcp In Item.Recipients
      .Recipients.Add (xRcp.Address)
    Next
    .Recipients.ResolveAll
    .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
    .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & " as soon as possible"
    .Attachments.Add Item
    .Display
  End With
End Sub

5. Speichern Sie den Code und kehren Sie zur Hauptoberfläche zurück. Klicken Sie auf „Datei“ > „Optionen“. Wählen Sie im linken Bereich des Fensters „Outlook-Optionen“ den Eintrag „Vertrauensstellungscenter“ und klicken Sie anschließend auf „Einstellungen des Vertrauensstellungscenters“, um das entsprechende Fenster zu öffnen. Wählen Sie links „Makroeinstellungen“ aus und stellen Sie sicher, dass im rechten Bereich die Option „Alle Makros aktivieren (nicht empfohlen; potenziell gefährlicher Code kann ausgeführt werden)“ aktiviert ist. Bestätigen Sie mit „OK“ > „OK“.

6. Sobald die festgelegte Zeit erreicht ist und keine Antwort auf die E-Mail eingegangen ist, für die eine Erinnerung eingerichtet wurde, erscheint ein Dialogfeld, das Sie fragt, ob die E-Mail erneut gesendet werden soll, um eine Benachrichtigung auszulösen.

7. Wenn Sie auf „Ja“ klicken, öffnet sich ein Nachrichtenfenster mit der vorherigen E-Mail als Anhang. Bearbeiten Sie den Textinhalt und klicken Sie anschließend auf „Senden“, um die E-Mail erneut zu versenden.

8. Wenn Sie auf „Nein“ klicken, wird die Erinnerung unwiderruflich gelöscht.

Hinweis: Wurde auf die E-Mail bereits vor Ablauf der festgelegten Frist geantwortet, entfernt das VBA-Skript die Erinnerung automatisch.