Wie importiert man Geburtstage aus Excel in den Outlook-Kalender?

Wenn Sie eine lange Liste mit Geburtstagsinformationen in einem Arbeitsblatt haben und diese schnell als Termine in Ihren Outlook-Kalender importieren möchten – wie gelingt Ihnen das auf effiziente Weise?

---

Geburtstage aus Excel in den Outlook-Kalender mit VBA-Code importieren

Normalerweise lässt sich Outlook nicht direkt dazu bringen, Geburtstage in den Kalender zu importieren – doch mit einem maßgeschneiderten VBA-Code wird’s möglich! So geht’s:

1. Öffnen Sie das Arbeitsblatt mit den Geburtstagen, die Sie in Outlook importieren möchten, und drücken Sie anschließend gleichzeitig die Tasten ALT + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf Einfügen > Modul, und fügen Sie den folgenden Code in das Modulfenster ein.

VBA-Code: Geburtstage in den Outlook-Kalender importieren

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Bleiben Sie im Fenster Microsoft Visual Basic for Applications, klicken Sie auf Extras > Verweise. Aktivieren Sie im erscheinenden Dialogfeld Verweise – VBAProject das Kontrollkästchen Microsoft Outlook 16,0 Object Library in der Liste Verfügbare Verweise – siehe Screenshot:

4. Klicken Sie anschließend auf OK, um dieses Dialogfeld zu schließen. Drücken Sie nun die F5-Taste, um diesen Code auszuführen. Es erscheint ein Eingabefeld, in dem Sie die Spalten für Name und Geburtstag auswählen – bitte beachten Sie den Screenshot:

5. Klicken Sie danach auf die Schaltfläche OK, und die Geburtstage werden sofort in Ihren Outlook-Kalender importiert. Starten Sie Outlook, um das Ergebnis anzuzeigen – siehe Screenshot: