Outlook: Wie behält man als Organisator abgesagte Besprechungen im Kalender?

In Outlook wird eine Besprechung automatisch aus Ihrem Kalender gelöscht, sobald Sie sie als Organisator absagen. In bestimmten Fällen möchten Sie abgesagte Besprechungen jedoch im Kalender behalten, um beispielsweise spezielle Markierungen vorzunehmen – doch Outlook bietet hierfür keine integrierte Funktion. Dieses Tutorial stellt zwei VBA-Codes bereit, mit denen die Besprechung beim Absagen automatisch als regulärer Termin erhalten bleibt.

VBA-Codes zum Kopieren abgesagter Besprechungen als Termine

---

VBA-Codes zum Kopieren abgesagter Besprechungen als Termine

Im Folgenden finden Sie zwei Codes, mit denen Sie eine Besprechung absagen und gleichzeitig als Termin kopieren und einfügen können.

Hinweis: Bevor Sie den Code aktivieren, stellen Sie sicher, dass die folgenden beiden Optionen aktiviert sind:

Starten Sie Outlook und klicken Sie auf Datei > Optionen. Klicken Sie im Fenster „Outlook-Optionen“ auf Vertrauensstellungscenter und anschließend auf Einstellungen des Vertrauensstellungscenters. Klicken Sie im Fenster „Vertrauensstellungscenter“ auf Makroeinstellungen, aktivieren Sie die Option Alle Makros aktivieren (nicht empfohlen; potenziell gefährlicher Code kann ausgeführt werden) sowie Makrosicherheitseinstellungen auf installierte Add-Ins anwenden. Klicken Sie auf OK > OK, um dieses Fenster zu schließen. Starten Sie Outlook neu.

1. Wechseln Sie zur Outlook-Kalenderansicht und wählen Sie die Besprechung aus, die Sie absagen möchten. Drücken Sie Alt+F11, um das Fenster „Microsoft Visual Basic für Applikationen“ zu öffnen.

2. Klicken Sie auf Einfügen > Modul, um ein neues leeres Modul einzufügen. Anschließend kopieren Sie einfach den folgenden Code und fügen ihn ein.

Code: Besprechung als Termin kopieren und absagen

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. Klicken Sie auf die Schaltfläche Ausführen oder drücken Sie die Taste F5. Die ausgewählte Besprechung wurde nun abgesagt, und es wurde ein Termin mit dem Namen „Abgesagt & Betreff“ erstellt.

Wenn Sie die Besprechung als Termin in einen anderen Kalender kopieren und anschließend absagen möchten, verwenden Sie den folgenden Code:

Code: Besprechung als Termin in einem anderen Kalender kopieren und absagen

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

Klicken Sie auf die Schaltfläche Ausführen oder drücken Sie die Taste F5. Anschließend öffnet sich das Dialogfeld „Ordner auswählen“, in dem Sie einen Kalenderordner zum Einfügen des Termins auswählen können. Klicken Sie danach auf „OK“.

Die Besprechung wurde abgesagt und stattdessen als Termin in den von Ihnen gewählten Kalenderordner kopiert und eingefügt.