Leerzeichen zwischen Zahl und Text in einer Zelle in Excel hinzufügen

In diesem Artikel lernen wir, wie man mit Formeln Leerzeichen zwischen Zahlen und Text in Excel hinzufügt.

Fall 1: Leerzeichen zwischen Zahl und Text hinzufügen – der Text steht immer zuerst
Fall 2: Leerzeichen zwischen Zahl und Text hinzufügen – die Zahl steht immer zuerst

Leerzeichen zwischen Zahl und Text hinzufügen – der Text steht immer zuerst

Angenommen, es gibt eine Liste von Zeichenketten, die Zahlen und Text enthalten, wobei der Text immer zuerst erscheint, wie im folgenden Screenshot gezeigt. Sie können mit der folgenden Formel ein Leerzeichen zwischen der Zahl und dem Text hinzufügen.

Allgemeine Formel

=GLÄTTEN(ERSETZEN(text_string;MIN(FINDEN({1;2;3;4;5;6;7;8;9;0};text_string&"1234567890"));0;" "))

Argumente

Wie verwendet man diese Formel?

1. Wählen Sie eine leere Zelle aus, um das Ergebnis auszugeben. In diesem Fall wähle ich D3.

2. Geben Sie die folgende Formel ein und drücken Sie die Eingabetaste. Ziehen Sie dann diese Ergebniszelle nach unten, um die Formel auf andere Zellen anzuwenden.

=GLÄTTEN(ERSETZEN(B3;MIN(FINDEN({1;2;3;4;5;6;7;8;9;0};B3&"1234567890"));0;" "))

Hinweise:

• In der Formel ist B3 die Zelle mit der Zeichenkette, in der Sie ein Leerzeichen zwischen Text und Zahl hinzufügen möchten;
• Diese Formel fügt nur ein Leerzeichen vor der ersten Zahl ein. Zum Beispiel ändert diese Formel B34C12G45 in B 34C12G45.

Wie funktioniert diese Formel?

=GLÄTTEN(ERSETZEN(B3;MIN(FINDEN({1;2;3;4;5;6;7;8;9;0};B3&"1234567890"));0;" "))

1. FINDEN({1;2;3;4;5;6;7;8;9;0};B3&"1234567890")

• B3&"1234567890": Gibt das Ergebnis zurück als: "KutoolsforExcel634211234567890";
• FINDEN({1;2;3;4;5;6;7;8;9;0}; "KutoolsforExcel634211234567890")Die FINDEN-Funktion findet die Position der Ziffern "1-0" in KutoolsforExcel634211234567890 und gibt das Ergebnis als {20;19;17;18;25;16;27;28;29;30} zurück.
  HinweisDas Ergebnis {20;19;17;18;25;16;27;28;29;30} bedeutet, dass die Zahl 1 an der 20. Stelle in KutoolsforExcel634211234567890 steht, die Zahl 2 an der 19. Stelle in KutoolsforExcel634211234567890…

2. MIN({20;19;17;18;25;16;27;28;29;30})

• Die MIN-Funktion erhält den kleinsten Wert des Arrays. Hier ist das Ergebnis 16.

3. ERSETZEN(KutoolsforExcel63421;16;0;" ")

• Hier verwenden wir die ERSETZEN-Funktion, um ein Leerzeichen an der 16. Stelle in KutoolsforExcel63421 hinzuzufügen und das Ergebnis als KutoolsforExcel 63421 zurückzugeben.

4. =GLÄTTEN("KutoolsforExcel 63421")

• Die GLÄTTEN-Funktion entfernt alle Leerzeichen aus dem Text, außer den einzelnen Leerzeichen zwischen den Wörtern. Außerdem werden keine führenden oder nachgestellten Leerzeichen im Text belassen.

Leerzeichen zwischen Zahl und Text hinzufügen – die Zahl steht immer zuerst

Ein weiterer Fall, wie im folgenden Screenshot gezeigt, es gibt eine Liste von Zeichenketten, die Zahlen und Text enthalten, wobei die Zahl immer zuerst steht. Sie können die folgende Array-Formel anwenden, um ein Leerzeichen zwischen der Zahl und dem Text hinzuzufügen.

Allgemeine Formel

=GLÄTTEN(ERSETZEN(text_string;MAX(WENNFEHLER(FINDEN({0;1;2;3;4;5;6;7;8;9};text_string;ZEILE(INDIREKT("1:"&LÄNGE(text_string))));0))+1;0;" ")) + Strg + Umschalt + Enter

Argumente

Wie verwendet man diese Formel?

1. Wählen Sie eine leere Zelle (D3 in diesem Fall) aus, um das Ergebnis auszugeben.

2. Geben Sie die folgende Formel ein und drücken Sie gleichzeitig die Tasten Strg + Umschalt + Enter.

=GLÄTTEN(ERSETZEN(B3;MAX(WENNFEHLER(FINDEN({0;1;2;3;4;5;6;7;8;9};B3;ZEILE(INDIREKT("1:"&LÄNGE(B3))));0))+1;0;" "))

3. Wählen Sie die Ergebniszelle aus und ziehen Sie sie nach unten, um die Formel auf andere Zellen anzuwenden, wie im folgenden Screenshot gezeigt.

Hinweise:

• In der Formel ist B3 die Zelle mit der Zeichenkette, in der Sie ein Leerzeichen zwischen Text und Zahl hinzufügen möchten;
• Diese Array-Formel fügt nur ein Leerzeichen nach der letzten Zahl ein. Zum Beispiel ändert diese Formel 34C12GHH in 34C12 GHH.

Verwandte Funktionen

Verwandte Formeln