Bestimmte Wörter in einem Bereich in Excel zählen

Dieser Artikel erklärt eine Formel, um die Anzahl der Vorkommen eines bestimmten Wortes in einem Zellbereich in Excel zu zählen.

Wie zählt man bestimmte Wörter in einem Zellbereich in Excel?

Allgemeine Formel

=SUMMENPRODUKT((LÄNGE(Bereich)-LÄNGE(WECHSELN(Bereich;Text;"")))/LÄNGE(Text))

Argumente

Wie verwendet man diese Formel?

Angenommen, Sie möchten die Anzahl des Wortes „tool“ im Bereich B5:B8 zählen, können Sie es wie folgt tun.

Wählen Sie eine leere Zelle aus, geben Sie die folgende Formel ein und drücken Sie dann die Eingabetaste.

Tipps: Sie können die Formel direkt in die ausgewählte Zelle kopieren und einfügen.

=SUMMENPRODUKT((LÄNGE(B5:B8)-LÄNGE(WECHSELN(B5:B8;"tool";"")))/LÄNGE("tool"))

Hinweise:

• 1. Bitte ändern Sie den Bereich B5:B8 und das Wort „tool“ entsprechend Ihren Bedürfnissen;
• 2. Wenn das Wort nicht gefunden wird, wird 0 zurückgegeben;
• 3. Die Formel unterscheidet zwischen Groß- und Kleinschreibung;
• 4. Wenn Sie ein bestimmtes Wort in einem Zellbereich zählen und die Groß-/Kleinschreibung ignorieren möchten, verwenden Sie bitte die Funktion GROSS innerhalb von WECHSELN, wie in der folgenden Formel gezeigt:
• =SUMMENPRODUKT((LÄNGE(B5:B8)-LÄNGE(WECHSELN(GROSS(B5:B8);GROSS("tool");"")))/LÄNGE("tool"))
• 

Wie funktioniert diese Formel?

=SUMMENPRODUKT((LÄNGE(B5:B8)-LÄNGE(WECHSELN(B5:B8;"tool";"")))/LÄNGE("tool"))

• 1. LÄNGE(B5:B8): Die LÄNGE-Funktion berechnet die Gesamtstringlänge für jede Zelle im Bereich B5:B8, sie wird als Array-Zahlen {47;23;23;15} zurückgegeben;
• 2. LÄNGE(WECHSELN(B5:B8;"tool";"")): Hier entfernt die WECHSELN-Funktion das spezifische Wort „tool“ aus jeder Zelle im Bereich B5:B8, und dann berechnet die LÄNGE-Funktion die Länge für jede Zelle im Bereich B5:B8 ohne das spezifische Wort „tool“. Sie gibt die Array-Zahlen als {35;19;19;15} zurück;
• 3. (LÄNGE(B5:B8)-LÄNGE(WECHSELN(B5:B8;"tool";"")): Dieser Teil der Formel wird nun zu {47;23;23;15}-{35;19;19;15}. Nach der Subtraktion ist das Ergebnis {12;4;4;0};
• 4. LÄNGE("tool"): Die LÄNGE-Funktion berechnet hier die Länge für „tool“ und gibt das Ergebnis 4 zurück;
• 5. (LÄNGE(B5:B8)-LÄNGE(WECHSELN(B5:B8;"tool";"")))/LÄNGE("tool"): Wie oben erwähnt, wird dieser Teil als {12;4;4;0}/4 angezeigt. Teilen Sie 4 von jeder Zahl des Arrays und erhalten Sie das Ergebnis {3;1;1;0};
• 6. SUMMENPRODUKT({3;1;1;0}): Die SUMMENPRODUKT-Funktion summiert die Zahlen im Array und gibt die Gesamtanzahl von „tool“ im Bereich B5:B8 zurück.

Verwandte Funktionen

Verwandte Formeln