Längsten Text mit Kriterien finden

In diesem Tutorial werden wir darüber sprechen, wie man den längsten Text in einer Spalte oder Zeile mit bestimmten Kriterien in Excel mithilfe der Funktionen INDEX, VERGLEICH, LÄNGE und MAX findet.

Wie findet man die längste Textzeichenfolge mit Kriterien in Excel?

Um schnell die Person zu finden, die aus Amerika stammt und den längsten Namen in dem oben genannten Namensbereich hat, hilft Ihnen eine Formel, die die Funktionen INDEX, VERGLEICH, LÄNGE und MAX kombiniert: Die MAX-Funktion wird den größten Wert im Bereich der durch die LÄNGE-Funktion bereitgestellten Zeichenlängen abrufen. Anschließend wird VERGLEICH die Position des ersten längsten Werts im Bereich finden und INDEX wird den Wert an der entsprechenden Position abrufen.

Allgemeine Syntax

=INDEX(Rückgabebereich;VERGLEICH(MAX(LÄNGE(Rückgabebereich)*(Kriterienbereich=Kriterienwert));LÄNGE(Rückgabebereich)*(Kriterienbereich=Kriterienwert);0))

√ Hinweis: Dies ist eine Array-Formel, die Sie mit Strg + Umschalt + Enter eingeben müssen.

Um die Person zu finden, die aus Amerika stammt und den längsten Namen hat, kopieren Sie bitte die folgenden Formeln in die Zelle F6, und drücken Sie Strg + Umschalt + Enter, um das Ergebnis zu erhalten:

=INDEX(B5:B11;VERGLEICH(MAX(LÄNGE(B5:B11)*(C5:C11="Amerika"));LÄNGE(B5:B11)*(C5:C11="Amerika");0))

Oder verwenden Sie einen Zellbezug, um die Formel dynamisch zu gestalten:

=INDEX(B5:B11;VERGLEICH(MAX(LÄNGE(B5:B11)*(C5:C11=F5));LÄNGE(B5:B11)*(C5:C11=F5);0))

Erklärung der Formel

=INDEX(B5:B11;VERGLEICH(MAX(LÄNGE(B5:B11)*(C5:C11=F5));LÄNGE(B5:B11)*(C5:C11=F5);0))

• LÄNGE(B5:B11)*(C5:C11=F5): Die LÄNGE-Funktion gibt ein Array der Längen jedes Namens in B5:B11 zurück, wie dieses: {5;5;6;3;4;8;5}; Der Teil (C5:C11=F5) überprüft jeden Wert im Bereich C5:C11, ob sie gleich dem Wert in F5 sind, und generiert ein Array wie dieses: {FALSCH;FALSCH;WAHR;FALSCH;WAHR;FALSCH;WAHR}, welches sich in {0;0;1;0;1;0;1} ändert, da es multipliziert wird. Und dies ist das Ergebnis nach der Multiplikation: {0;0;6;0;4;0;5}.
• MAX(MAX(LÄNGE(B5:B11)*(C5:C11=F5))) = MAX(MAX({0;0;6;0;4;0;5})): Die MAX-Funktion gibt dann den größten Wert aus dem Array {0;0;6;0;4;0;5} zurück, welcher 6 ist.
• VERGLEICH(MAX(LÄNGE(B5:B11)*(C5:C11=F5));LÄNGE(B5:B11)*(C5:C11=F5);0) = VERGLEICH(6;{0;0;6;0;4;0;5};0): Der match_type 0 zwingt die VERGLEICH-Funktion, die Position der ersten exakten Zahl 6 im Array {0;0;6;0;4;0;5} zu finden. Daher gibt sie 3 zurück, da die Zahl an der 3. Position steht.
• INDEX(B5:B11;VERGLEICH(MAX(LÄNGE(B5:B11)*(C5:C11=F5));LÄNGE(B5:B11)*(C5:C11=F5);0)) = INDEX(B5:B11;3): Die INDEX-Funktion gibt den 3. Wert im Namensbereich B5:B11 zurück, welcher Oliver ist.

Verwandte Funktionen

Verwandte Formeln