Textzeichenfolge an einem bestimmten Zeichen in einer Zelle in Excel aufteilen

Dieses Tutorial zeigt Ihnen, wie Sie eine Textzeichenfolge an einem bestimmten Trennzeichen mithilfe einer Formel in Excel in separate Spalten aufteilen.

Wie teilt man eine Textzeichenfolge in einer Excel-Zelle an einem bestimmten Zeichen auf?

Angenommen, Sie haben eine Liste mit Textzeichenfolgen in Spalte B, wie im folgenden Screenshot dargestellt, und möchten den Text am Zeichen „–“ aufteilen, um das Ergebnis in drei separaten Spalten anzuzeigen – dann helfen Ihnen die folgenden Formeln weiter.

Allgemeine Formeln

Allgemeine Formel zum Aufteilen des linken Textteils

=LEFT(text_string,FIND(„Char", text_string)-1)

Allgemeine Formel zum Aufteilen des mittleren Textteils

=MID(text_string, FIND(„Char", text_string) + 1, FIND(„Char", text_string,FIND(„Char", text_string)+1) - FIND(„Char", text_string) - 1)

Allgemeine Formel zum Aufteilen des rechten Textteils

=RIGHT(text_string,LEN(text_string) - FIND(„Char", text_string, FIND(„Char", text_string) + 1))

Argumente der obigen Formeln

Wie wendet man diese Formeln an?

Teilen Sie zunächst die erste Textzeichenfolge anhand eines bestimmten Zeichens auf

1. Wählen Sie eine leere Zelle für die Ausgabe des Ergebnisses aus – hier beispielsweise C3.

2. Geben Sie die folgende Formel ein und drücken Sie die Eingabetaste. Ziehen Sie anschließend die Zelle mit Ihrer LINKS-Formel nach unten, um sie auf weitere Zellen anzuwenden.

=LEFT(B3,FIND("-",B3)-1)

Teilen Sie anschließend die mittlere Textzeichenfolge anhand eines bestimmten Zeichens auf

1. Wählen Sie eine leere Zelle – beispielsweise D3 – aus, um das Ergebnis anzuzeigen.

2. Geben Sie die folgende Formel ein und drücken Sie die Eingabetaste. Wählen Sie die Ergebniszelle aus, und ziehen Sie das Ausfüllkästchen nach unten, um die Formel auf weitere Zellen anzuwenden.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

Teilen Sie abschließend die letzte Textzeichenfolge anhand eines bestimmten Zeichens auf

1. Wählen Sie eine leere Zelle – beispielsweise E3 – aus, um das Ergebnis anzuzeigen.

2. Geben Sie die folgende Formel ein und drücken Sie die Eingabetaste. Wählen Sie die Ergebniszelle aus und ziehen Sie den Ausfüllkästchen nach unten, um die Formel auf andere Zellen anzuwenden.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

Die Textzeichenfolge in jeder Zelle der Spalte B wurde nun in drei Teile aufgeteilt.

Tipp: Wenn Sie die Textzeichenfolge nur anhand eines bestimmten Zeichens in zwei Teile aufteilen möchten, verwenden Sie nach der Extraktion des ersten Teils mit der obigen LINKS-Formel die folgende RECHTS-Formel, um den zweiten Teil zu erhalten – wie im folgenden Screenshot gezeigt.

=RIGHT(B3,LEN(B3)-FIND("-",B3))

Wie funktionieren diese Formeln?

=LEFT(B3,FIND("-",B3)-1)

• FIND("-",B3)Die FINDEN-Funktion gibt die Startposition des Zeichens „-“ in der Textzeichenfolge „KTE-Jan-359“ zurück – das Ergebnis lautet 4.
• LEFT(B3,4-1): Die LINKS-Funktion extrahiert 3 Zeichen (4 − 1 = 3) von links aus der Textzeichenfolge „KTE-Jan-359“. Das Ergebnis lautet hier „KTE“.
  Hinweis: Da sich das erste „-“ an der vierten Position der Textzeichenfolge befindet, müssen Sie 1 subtrahieren, um es beim Extrahieren auszuschließen.

=MID(B3, FIND("-",B3) + 1, FIND("-",B3,FIND("-",B3)+1) - FIND("-",B3) - 1)

• FIND("-",B3) + 1: Die FINDEN-Funktion gibt die Startposition des Zeichens „-“ in der Textzeichenfolge KTE-Jan-359 zurück. Das Ergebnis lautet hier 4.
  Hinweis: Da sich das erste Zeichen „-“ an der 4. Position der Textzeichenfolge befindet, müssen Sie 1 zu 4 addieren, um den Text danach zu extrahieren, und erhalten schließlich 4+1=5.
• FIND("-",B3,FIND("-",B3)+1)hier dargestellt als FINDEN("-";"KTE-Jan-359";4+1): Die FINDEN-Funktion ermittelt die Position des Zeichens „-“, beginnend beim 5. Zeichen in „KTE-Jan-359“, und gibt das Ergebnis 8 zurück.
• MID(B3, 5, 8 - 4 - 1): MITTE(KTE-Jan-359;5;3) bedeutet, dass die MITTE-Funktion ab dem 5. Zeichen der Textzeichenfolge „KTE-Jan-359“ drei Zeichen extrahiert – das Ergebnis lautet „Jan“.

=RIGHT(B3,LEN(B3) - FIND("-", B3, FIND("-", B3) + 1))

• LEN(B3)Die LÄNGE-Funktion ermittelt die Gesamtlänge der Textzeichenfolge „KTE-Jan-359“ und liefert das Ergebnis 11 zurück.
• FIND("-",B3,FIND("-",B3)+1)Die FINDEN-Funktion ermittelt die Position des Zeichens „–“, beginnend beim 5. Zeichen in „KTE-Jan-359“, und gibt das Ergebnis als 8 zurück.
• RIGHT(B3,11 - 8))Die RECHTS-Funktion extrahiert 3 Zeichen (11 – 8) von der rechten Seite des Textes „KTE-Jan-359“. Das Ergebnis lautet hier „359“.

Verwandte Funktionen

Verwandte Formeln