Wie sucht und ersetzt man den Betreff von Terminen im Outlook-Kalender?

Die Funktion „Suchen und Ersetzen“ für Betreffzeilen im Outlook-Kalender ist äußerst hilfreich, wenn Sie feststellen, dass bestimmte Terminbetreffzeilen massenhaft durch denselben Text ersetzt werden müssen – beispielsweise, um das Wort „Copy“ im Betreff nach dem Importieren von Daten in Outlook zu entfernen oder anzupassen. In diesem Artikel stellen wir Ihnen einen praktischen VBA-Code zur Verfügung, mit dem Sie mehrere Terminbetreffzeilen effizient suchen und ersetzen können. Weitere Details erfahren Sie im Folgenden.

Suchen und Ersetzen des Terminbetreffs mit VBA-Code

---

Suchen und Ersetzen des Terminbetreffs mit VBA-Code

In diesem Abschnitt können Sie den Terminbetreff mithilfe des folgenden VBA-Codes suchen und ersetzen.

1. Stellen Sie zunächst die Makroeinstellungen in Ihrem Outlook auf niedrig.

1) Klicken Sie in Outlook 2010 und 2013 auf „Datei“ > „Optionen“. Wählen Sie im Dialogfeld „Outlook-Optionen“ links „Vertrauensstellungscenter“ aus und klicken Sie anschließend auf die Schaltfläche „Einstellungen für das Vertrauensstellungscenter“.

Klicken Sie im Dialogfeld „Vertrauensstellungscenter“ auf der linken Seite auf „Makroeinstellungen“ und wählen Sie im Bereich „Makroeinstellungen“ die Option „Alle Makros aktivieren“ aus. Bestätigen Sie Ihre Auswahl anschließend mit einem Klick auf „OK“. Siehe Screenshot:

2) Klicken Sie in Outlook 2007 auf „Extras“ > „Vertrauensstellungscenter“. Wählen Sie im linken Bereich des Dialogfelds „Vertrauensstellungscenter“ die Option „Makroeinstellungen“ aus, aktivieren Sie „Keine Sicherheitsüberprüfung für Makros“ und bestätigen Sie mit „OK“.

2. Drücken Sie „Alt“ + „F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

3. Doppelklicken Sie im Fenster „Microsoft Visual Basic for Applications“ auf „Projekt1“ > „Microsoft Outlook-Objekte“ > „ThisOutlookSession“, um den VBA-Editor zu öffnen. Siehe Screenshot:

4. Kopieren Sie den folgenden VBA-Code in den VBA-Editor und führen Sie ihn anschließend durch Drücken der Taste „F5“ aus.

VBA: Suchen und Ersetzen-Terminbetreff

Sub FindReplaceAppointment()
    Dim oApp As Outlook.Application
    Dim oCalFolder As Outlook.MAPIFolder
    Dim oAppt As Outlook.AppointmentItem
    Dim sOldText As String
    Dim sNewText As String
    Dim iCalChangedCount As Integer
    Set oApp = Outlook.Application
    MsgBox ("This script will perform a find/replace in the subject line of all appointments in a specified calendar.")
    sOldText = InputBox("What is the text string that you would like to replace?")
    sNewText = InputBox("With what would you like to replace it?")
    ' Check to be sure a Calendar folder was selected
    Do
    If Not (oCalFolder Is Nothing) Then
        If (oCalFolder.DefaultItemType = olAppointmentItem) Then Exit Do
    End If
    MsgBox ("Please select a calendar folder from the following list.")
    Set oCalFolder = Application.Session.PickFolder
    On Error GoTo ErrHandler:
    Loop Until oCalFolder.DefaultItemType = olAppointmentItem
    ' Loop through appointments in calendar, change text where necessary, keep count
    iCalChangedCount = 0
    For Each oAppt In oCalFolder.Items
        If InStr(oAppt.Subject, sOldText) <> 0 Then
            Debug.Print "Changed: " & oAppt.Subject & " - " & oAppt.Start
            oAppt.Subject = Replace(oAppt.Subject, sOldText, sNewText)
            oAppt.Save
            iCalChangedCount = iCalChangedCount + 1
        End If
    Next
    ' Display results and clear table
    MsgBox (iCalChangedCount & " appointments had text in their subjects changed from '" & sOldText & "' to '" & sNewText & "'.")
    Set oAppt = Nothing
    Set oCalFolder = Nothing
Exit Sub
ErrHandler:
    MsgBox ("Macro terminated.")
End Sub

5. Nach Ausführung des Codes erscheint das Dialogfeld „Microsoft Outlook“ – klicken Sie einfach auf „OK“.

6. Geben Sie im zweiten Dialogfeld „Microsoft Outlook“ den Text ein, den Sie ersetzen möchten, und klicken Sie auf „OK“.

7. Geben Sie im dritten Dialogfeld „Microsoft Outlook“ den gewünschten Ersatztext ein und klicken Sie auf „OK“.

Hinweis: Wenn Sie lediglich alle „Copy“-Wörter aus dem Betreff im angegebenen Kalender entfernen möchten, lassen Sie dieses Feld leer.

8. Klicken Sie im folgenden Dialogfeld auf „OK“.

9. Wählen Sie im Dialogfeld „Ordner auswählen“ Ihren Kalender unter dem angegebenen E-Mail-Konto aus und klicken Sie dann auf „OK“. Siehe Screenshot:

10. Anschließend erscheint ein Dialogfeld, das Sie über den erfolgreichen Abschluss der Ersetzung informiert – bitte klicken Sie auf „OK“.

11. Danach wurden alle Texte im Betreff der ausgewählten Kalendereinträge durch den neuen Inhalt ersetzt.