Wie lassen sich mehrere Termine in Outlook schnell in Aufgaben umwandeln?

In diesem Artikel zeige ich Ihnen, wie Sie einen oder mehrere Termine in Outlook schnell und einfach in Aufgaben umwandeln können.

Einen Termin per Drag & Drop in eine Aufgabe umwandeln

Mehrere Termine mithilfe von VBA-Code in Aufgaben umwandeln

---

Einen Termin per Drag & Drop in eine Aufgabe umwandeln

Um einen einzelnen Termin in eine Aufgabe umzuwandeln, ziehen Sie ihn einfach per Drag & Drop in den Aufgabenordner. So geht’s:

1. Wählen Sie im Kalenderfenster den Termin aus, den Sie in eine Aufgabe umwandeln möchten, und ziehen Sie ihn per Drag & Drop auf das „Aufgaben“-Symbol am unteren Rand der Navigation – wie im folgenden Screenshot dargestellt:

2. Anschließend öffnet sich das neue Fenster „Aufgabe“. Klicken Sie auf „Speichern und schließen“, um den Termin als Aufgabe zu speichern.

---

Mehrere Termine mithilfe von VBA-Code in Aufgaben umwandeln

Wenn Sie mehrere Termine gleichzeitig in Aufgaben umwandeln möchten, unterstützt Sie der folgende VBA-Code dabei. Gehen Sie dazu wie folgt vor:

1. Drücken Sie gleichzeitig die Tasten „Alt + F11“, um das Fenster „Microsoft Visual Basic for Applications“ zu öffnen.

2. Klicken Sie auf „Einfügen“ > „Modul“ und fügen Sie den folgenden Code in das geöffnete leere Modul ein:

VBA-Code: Mehrere Termine in Aufgaben umwandeln

Sub ConvertAppointmentsToTasks()
Dim xItemCollection As VBA.Collection
Dim xActiveWindow As Object
Dim xItem As Object
Dim xSelection As Outlook.Selection
Dim xTaskFolder As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xTaskItem As Outlook.TaskItem
On Error Resume Next
Set xItemCollection = New VBA.Collection
Set xActiveWindow = Outlook.Application.ActiveWindow
If TypeOf xActiveWindow Is Inspector Then
    Set xItem = xActiveWindow.CurrentItem
    If xItem.Class = olAppointment Then xItemCollection.Add xItem
Else
    Set xSelection = xActiveWindow.Selection
    If xSelection Is Nothing Then Exit Sub
    For Each xItem In xSelection
        If xItem.Class = olAppointment Then xItemCollection.Add xItem
    Next
End If
Set xTaskFolder = Application.Session.PickFolder
If xTaskFolder Is Nothing Then Exit Sub
For Each xAppointmentItem In xItemCollection
    Set xTaskItem = xTaskFolder.Items.Add(olTaskItem)
    With xTaskItem
        .StartDate = Format(xAppointmentItem.Start, "Short Date")
        .DueDate = Format(xAppointmentItem.End, "Short Date")
        .Subject = xAppointmentItem.Subject & " (From Appt)"
        .Categories = xAppointmentItem.Categories
        .Body = xAppointmentItem.Body
        .Save
        .Display
    End With
Next
End Sub

3. Wählen Sie die Termine aus, die Sie in Aufgaben umwandeln möchten, und klicken Sie anschließend auf „Makro ausführen“, um den Code auszuführen.

4. Anschließend öffnet sich das Dialogfeld „Ordner auswählen“. Wählen Sie einen „Aufgaben“-Ordner aus, in dem Sie die umgewandelten Ergebnisse speichern möchten.

5. Klicken Sie auf „OK“. Alle ausgewählten Termine werden nun als Aufgaben erstellt. Anschließend öffnet „Speichern und Schließen“ nacheinander jedes „Aufgabe“-Fenster.

6. Wechseln Sie nun zum „Aufgaben“-Ordner – alle ausgewählten Termine wurden als Aufgaben gespeichert.