Wie blenden Sie die Faxnummer in der „Namensliste“ in Outlook aus?

In Outlook haben Sie möglicherweise bemerkt, dass in der Liste „Namen auswählen“ oder im Adressbuch die Spalte „E-Mail-Adresse“ nicht nur E-Mail-Adressen, sondern auch Faxeinträge anzeigt – was störend sein kann. In diesem Artikel zeige ich Ihnen einige Möglichkeiten, um Faxnummern auszublenden.

Faxnummer in „Namensliste“ mit VBA ausblenden

---

Faxnummer in „Namensliste“ mit VBA ausblenden

Wenn Sie bereits vorhandene Faxnummern in „Namensliste“ ausblenden möchten, gehen Sie wie folgt vor:

1. Drücken Sie die Tasten Alt + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf Einfügen > Modul, um ein neues leeres Modul einzufügen, und fügen Sie den folgenden Code in das Skript ein.

VBA: Vorhandene Faxnummer in „Namen auswählen“ ausblenden

Sub HideFaxNumbers_ExistingContacts()
'UpdatebyExtendoffice2018-5-23
Dim xStores As Outlook.Stores
Dim xStore As Outlook.Store
Dim xRootFolder As Outlook.Folder
Dim xFolder As Folder
On Error Resume Next
Set xStores = Outlook.Application.Session.Stores
For Each xStore In xStores
    Set xRootFolder = xStore.GetRootFolder
    For Each xFolder In xRootFolder.Folders
        Call ProcessFolders(xFolder)
    Next
Next
End Sub
Sub ProcessFolders(ByVal CurrentFolder As Outlook.Folder)
Dim xContactItem As Outlook.ContactItem
Dim xSubFolder As Outlook.Folder
Dim xFax As String
Dim I As Integer
On Error Resume Next
If CurrentFolder.DefaultItemType <> olContactItem Then Exit Sub
xFax = "Fax: "
For I = CurrentFolder.Items.Count To 1 Step -1
    Set xContactItem = CurrentFolder.Items.Item(I)
    With xContactItem
        If (Len(.BusinessFaxNumber) <> 0) And InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
            .BusinessFaxNumber = xFax & .BusinessFaxNumber
        End If
        If (Len(.HomeFaxNumber) <> 0) And InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
            .HomeFaxNumber = xFax & .HomeFaxNumber
        End If
        If (Len(.OtherFaxNumber) <> 0) And InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
            .OtherFaxNumber = xFax & .OtherFaxNumber
        End If
        .Save
    End With
Next I
If CurrentFolder.Folders.Count <> 0 Then
    For I = CurrentFolder.Folders.Count To 1 Step -1
        Set xSubFolder = CurrentFolder.Folders.Item(I)
        Call ProcessFolders(xSubFolder)
    Next I
End If
End Sub

3. Drücken Sie die Taste F5, um den Code auszuführen. Die Faxnummern sind jetzt ausgeblendet.

Wenn Sie die Faxnummer in Kontakt ausblenden möchten, gehen Sie wie folgt vor:

1. Drücken Sie Alt + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Doppelklicken Sie im Bereich Projekt-1 auf ThisOutlookSession, und fügen Sie dann den folgenden Code in das Skript ein.

VBA: Faxnummer in neuem Kontakt hinzufügen ausblenden

Public WithEvents xInspectors As Outlook.Inspectors
Public WithEvents xContactItem As Outlook.ContactItem
Private Sub Application_Startup()
'UpdatebyExtendoffice2018-5-23
    Set xInspectors = Outlook.Application.Inspectors
End Sub
Private Sub xInspectors_NewInspector(ByVal Inspector As Inspector)
If TypeName(Inspector.CurrentItem) = "ContactItem" Then
    Set xContactItem = Inspector.CurrentItem
End If
End Sub
Private Sub xContactItem_PropertyChange(ByVal Name As String)
Dim xArr() As Variant
Dim xFax As String
On Error Resume Next
xArr = Array("BusinessFaxNumber", "HomeFaxNumber", "OtherFaxNumber")
xFax = "Fax: "
With xContactItem
    Select Case Name
        Case xArr(0)
            If InStrRev(.BusinessFaxNumber, Trim(xFax)) = 0 Then
                .BusinessFaxNumber = xFax & .BusinessFaxNumber
            End If
        Case xArr(1)
            If InStrRev(.HomeFaxNumber, Trim(xFax)) = 0 Then
                .HomeFaxNumber = xFax & .HomeFaxNumber
            End If
        Case xArr(2)
            If InStrRev(.OtherFaxNumber, Trim(xFax)) = 0 Then
                .OtherFaxNumber = xFax & .OtherFaxNumber
            End If
    End Select
End With
End Sub

3. Speichern Sie den Code und starten Sie Outlook neu, damit die Änderungen wirksam werden.

Ab sofort werden Faxnummern neu erstellter Kontakte im Fenster „Namen auswählen: Kontakte“ ausgeblendet.