Wie erstellt man Termine aus Excel-Daten?

Angenommen, Sie haben eine Tabelle mit Termin-Daten in einem Excel-Arbeitsblatt wie im folgenden Screenshot gezeigt – wie importieren Sie diese Daten schnell in Ihren Outlook-Kalender?

Termine aus Excel-Daten mithilfe von VBA-Code erstellen

---

Termine aus Excel-Daten mithilfe von VBA-Code erstellen

Um Termine aus Excel-Daten zu erstellen, verwenden Sie einfach den folgenden VBA-Code – so geht’s:

1. Starten Sie Outlook und drücken Sie gleichzeitig ALT + F11, um das Fenster Microsoft Visual Basic for Applications zu öffnen.

2. Klicken Sie auf Einfügen > Modul, und fügen Sie den folgenden Code in das Modul-Fenster ein.

VBA-Code: Excel-Daten in Termine importieren:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Bleiben Sie im Fenster Microsoft Visual Basic for Applications, klicken Sie auf Extras > Verweise, um das Dialogfeld Verweise – Projekt1 zu öffnen, und aktivieren Sie in der Liste Verfügbare Verweise die Option Microsoft Excel Object Library. Siehe Screenshot:

4. Klicken Sie dann auf die Schaltfläche OK und drücken Sie anschließend die Taste F5, um diesen Code auszuführen. Daraufhin wird das Fenster Datei auswählen angezeigt. Wählen Sie bitte die Excel-Datei aus, die Sie in Outlook importieren möchten – siehe Screenshot:

5.Klicken Sie anschließend auf OK, woraufhin eine Meldungsbox wie folgt eingeblendet wird:

6. Klicken Sie danach auf OK, und die Excel-Daten wurden wie im folgenden Screenshot gezeigt in den Kalender importiert: