Wie kann man in Outlook normalerweise im Ordner „Gesendete Elemente“ auf eine E-Mail antworten?

Normalerweise erscheint Ihre eigene E-Mail-Adresse im An-Feld, wenn Sie im Ordner „Gesendete Elemente“ auf „Antworten“ klicken, um eine weitere Nachricht an dieselben Empfänger zu senden – wie im folgenden Screenshot gezeigt. Das kann lästig sein, da Sie die Adresse jedes Mal manuell ändern müssen. Wie können Sie Outlook dazu bringen, stattdessen die ursprüngliche Empfängeradresse zu verwenden?

Normal im Gesendete Elemente-Ordner aus Outlook mit der Funktion „Allen antworten“ antworten

Normal im Gesendete Elemente-Ordner aus Outlook mit VBA-Code antworten

---

Normal im Gesendete Elemente-Ordner aus Outlook mit der Funktion „Allen antworten“ antworten

In Outlook kann die Funktion „Allen antworten“ Ihnen helfen, dieses Problem zu lösen. Gehen Sie dazu wie folgt vor:

Wenn Sie die gesendete E-Mail erneut beantworten möchten, um die ursprüngliche Empfängeradresse beizubehalten, klicken Sie bitte auf die Schaltfläche „Allen antworten“, und die ursprüngliche Empfängeradresse befindet sich im An-Feld, wie im folgenden Screenshot gezeigt:

---

Normal im Gesendete Elemente-Ordner aus Outlook mit VBA-Code antworten

Manchmal übersehen Sie möglicherweise die Funktion „Allen antworten“, wenn Sie auf eine gesendete Nachricht antworten. Mit dem folgenden VBA-Code können Sie im Ordner „Gesendete Elemente“ ganz einfach und korrekt über die normale Antwortfunktion antworten. Gehen Sie dazu wie folgt vor:

1. Halten Sie die Tasten ALT + F11 gedrückt, um das Fenster Microsoft Visual Basic für Applikationen zu öffnen.

2. Doppelklicken Sie im Fenster Microsoft Visual Basic für Applikationen im Bereich ThisOutlookSession unter Projekt1 (VbaProject.OTM), um das Modul zu öffnen, und fügen Sie anschließend den folgenden Code in das leere Modul ein.

VBA-Code: Normal im Gesendete Elemente-Ordner aus Outlook antworten:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Speichern Sie anschließend den Code und starten Sie Outlook neu, damit der Code wirksam wird. Wenn Sie nun im Ordner „Antworten“ auf eine erneute Zusendung einer E-Mail klicken, wird die ursprüngliche Empfängeradresse wie gewünscht im An-Feld angezeigt.Gesendete Elemente