Wie können beim Start von Outlook automatisch alle Ordner erweitert werden?

Normalerweise behält ein Ordner in der Outlook-Navigation seinen Zustand – also ob er beim Beenden des Programms erweitert oder reduziert war – auch beim nächsten Start bei. Doch was, wenn Sie möchten, dass alle Ordner jedes Mal beim Start von Outlook automatisch erweitert werden? Dieser Artikel bietet eine VBA-Lösung dafür.

Automatisch Alle Ordner erweitern beim Starten von Outlook mithilfe von VBA

---

Automatisch Alle Ordner erweitern beim Starten von Outlook mithilfe von VBA

In dieser Anleitung erfahren Sie, wie Sie mithilfe eines VBA-Skripts beim Start von Outlook automatisch alle Ordner in der Navigation erweitern können. Führen Sie diese Schritte aus, um das VBA-Skript zu implementieren:

1. Drücken Sie gleichzeitig die Tasten Alt + F11, um das Fenster Microsoft Visual Basic für Applikationen zu öffnen.
2. Erweitern Sie im Projekt 1und Microsoft Outlook-Objekteim Projekt-Bereich, doppelklicken Sie auf ThisOutlookSession, um das entsprechende Fenster zu öffnen, und fügen Sie anschließend den folgenden VBA-Code dort ein.

   

   VBA: Automatisch Alle Ordner erweitern in Outlook

   Public WithEvents GEx As Explorer
   Public GFlag As Boolean
   Private Sub Application_Startup()
     'Update by ExtendOffice 2023/12/08
     Set GEx = Application.ActiveExplorer
     GFlag = False
   End Sub
   
   Private Sub GEx_SelectionChange()
     If GFlag = False Then
       ExpandAllFolders
     End If
     GFlag = True
   End Sub
   
   Public Sub ExpandAllFolders()
     Dim xNameSpace As Outlook.NameSpace
     Dim xFlds As Outlook.Folders
     Dim xCurrFld As Outlook.MAPIFolder
     Dim xFld As Outlook.MAPIFolder
     Dim xExpandDefaultStoreOnly As Boolean
     Dim xModule As NavigationModule
     On Error Resume Next
     xExpandDefaultStoreOnly = False
     Set xNameSpace = Application.Session
     Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
     Set xCurrFld = Application.ActiveExplorer.CurrentFolder
     If xExpandDefaultStoreOnly = True Then
       Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
       Set xFld = xFld.Parent
       Set xFlds = xFld.Folders
       LoopFolders xFlds, True
     Else
       LoopFolders xNameSpace.Folders, True
       LoopFolders xNameSpace.Folders, False
     End If
     DoEvents
     Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
     Set Application.ActiveExplorer.CurrentFolder = xCurrFld
     Set xNameSpace = Nothing
     Set xModule = Nothing
     Set xCurrFld = Nothing
   End Sub
   
   Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
     Dim xFld As Outlook.MAPIFolder
     On Error Resume Next
     For Each xFld In Flds
       Select Case All
         Case True
           If xFld.DefaultItemType = olMailItem Then
             Set Application.ActiveExplorer.CurrentFolder = xFld
             DoEvents
             If xFld.Folders.Count > 0 Then
               LoopFolders xFld.Folders, All
             End If
           End If
         Case False
           Set Application.ActiveExplorer.CurrentFolder = xFld
           DoEvents
           If xFld.Folders.Count > 0 Then
             LoopFolders xFld.Folders, All
           End If
       End Select
     Next
   End Sub

3. Speichern Sie den Code und schließen Sie das Fenster Microsoft Visual Basic für Applikationen.

Ab sofort werden beim Neustart von Outlook alle Ordner automatisch ausgeklappt.

---

Verwandte Artikel