Wie kann man ausgewählte Zellen in Excel vergrößern oder vergrößern?

Wie wir alle wissen, hat Excel eine Zoom-Funktion, die uns hilft, die Größe der Zellwerte im gesamten Arbeitsblatt zu vergrößern. Aber manchmal möchten wir nur die ausgewählten Zellen vergrößern oder vergrößern. Gibt es gute Ideen, wie wir nur die ausgewählten Zellen in einem Arbeitsblatt vergrößern können?

Ausgewählte Zelle mit VBA-Code vergrößern

Ausgewählte Zelle mit VBA-Code vergrößern

Vielleicht gibt es keinen direkten Weg, um die ausgewählten Zellen in Excel zu vergrößern, aber hier kann ich einen VBA-Code vorstellen, der als Workaround für diese Aufgabe dient. Bitte gehen Sie wie folgt vor:

1. Klicken Sie mit der rechten Maustaste auf das Arbeitsblatt-Tab, in dem Sie die ausgewählten Zellen automatisch vergrößern möchten, und wählen Sie dann „Ansicht Code“ aus dem Kontextmenü. Im geöffneten Fenster „Microsoft Visual Basic for Applications“ kopieren und fügen Sie den folgenden Code in das leere Modul ein:

VBA-Code: Ausgewählte Zellen vergrößern:

Private Sub worksheet_selectionchange(ByVal Target As Range)
'Updateby Extendoffice
    Dim xRg As Range
    Dim xCell As Range
    Dim xShape As Variant
    Set xRg = Target.Areas(1)
    For Each xShape In ActiveSheet.Pictures
        If xShape.Name = "zoom_cells" Then
            xShape.Delete
        End If
    Next
    If Application.WorksheetFunction.CountBlank(xRg) = xRg.Count Then Exit Sub
    Application.ScreenUpdating = False
    xRg.CopyPicture appearance:=xlScreen, Format:=xlPicture
    Application.ActiveSheet.Pictures.Paste.Select
    With Selection
        .Name = "zoom_cells"
        With .ShapeRange
            .ScaleWidth 1.5, msoFalse, msoScaleFromTopLeft
            .ScaleHeight 1.5, msoFalse, msoScaleFromTopLeft
            With .Fill
                .ForeColor.SchemeColor = 44
                .Visible = msoTrue
                .Solid
                .Transparency = 0
            End With
        End With
    End With
    xRg.Select
    Application.ScreenUpdating = True
    Set xRg = Nothing
End Sub

2. Speichern Sie dann dieses Codefenster und schließen Sie es. Jetzt werden die Zellen automatisch als Bild vergrößert, wenn Sie einige Datenzellen auswählen oder anklicken, siehe Screenshot:

Hinweis: Die ausgewählten Zellen werden nach der Auswahl anderer Zellen wieder auf ihre ursprüngliche Größe zurückgesetzt.